etc/settings.csh

   1 #----------------------------------*-sh-*--------------------------------------
   2 # =========                 |
   3 # \\      /  F ield         | foam-extend: Open Source CFD
   4 #  \\    /   O peration     |
   5 #   \\  /    A nd           | For copyright notice see file Copyright
   6 #    \\/     M anipulation  |
   7 #------------------------------------------------------------------------------
   8 # License
   9 #     This file is part of foam-extend.
  10 #
  11 #     foam-extend is free software: you can redistribute it and/or modify it
  12 #     under the terms of the GNU General Public License as published by the
  13 #     Free Software Foundation, either version 3 of the License, or (at your
  14 #     option) any later version.
  15 #
  16 #     foam-extend is distributed in the hope that it will be useful, but
  17 #     WITHOUT ANY WARRANTY; without even the implied warranty of
  18 #     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 #     General Public License for more details.
  20 #
  21 #     You should have received a copy of the GNU General Public License
  22 #     along with foam-extend.  If not, see <http://www.gnu.org/licenses/>.
  23 #
  24 # Script
  25 #     etc/settings.csh
  26 #
  27 # Description
  28 #     Startup file for OpenFOAM
  29 #     Sourced from OpenFOAM-??/etc/cshrc
  30 #
  31 #------------------------------------------------------------------------------
  32
  33 # prefix to PATH
  34 alias _foamAddPath 'set path=(\!* $path)'
  35 # prefix to LD_LIBRARY_PATH
  36 alias _foamAddLib 'setenv LD_LIBRARY_PATH \!*\:${LD_LIBRARY_PATH}'
  37
  38 # location of the jobControl directory
  39 setenv FOAM_JOB_DIR $WM_PROJECT_INST_DIR/jobControl
  40
  41 # wmake configuration
  42 setenv WM_DIR $WM_PROJECT_DIR/wmake
  43 setenv WM_LINK_LANGUAGE c++
  44 setenv WM_OPTIONS $WM_ARCH$WM_COMPILER$WM_PRECISION_OPTION$WM_COMPILE_OPTION
  45 set path=($WM_DIR $path)
  46
  47 # base configuration
  48 setenv FOAM_APP $WM_PROJECT_DIR/applications
  49 setenv FOAM_APPBIN $WM_PROJECT_DIR/applications/bin/$WM_OPTIONS
  50 setenv FOAM_LIB $WM_PROJECT_DIR/lib
  51 setenv FOAM_LIBBIN $WM_PROJECT_DIR/lib/$WM_OPTIONS
  52 setenv FOAM_SRC $WM_PROJECT_DIR/src
  53
  54 # shared site configuration - similar naming convention as ~OpenFOAM expansion
  55 setenv FOAM_SITE_APPBIN $WM_PROJECT_INST_DIR/site/$WM_PROJECT_VERSION/bin/$WM_OPTIONS
  56 setenv FOAM_SITE_LIBBIN $WM_PROJECT_INST_DIR/site/$WM_PROJECT_VERSION/lib/$WM_OPTIONS
  57
  58 # user configuration
  59 setenv FOAM_USER_APPBIN $WM_PROJECT_USER_DIR/applications/bin/$WM_OPTIONS
  60 setenv FOAM_USER_LIBBIN $WM_PROJECT_USER_DIR/lib/$WM_OPTIONS
  61
  62 # convenience
  63 setenv FOAM_TUTORIALS $WM_PROJECT_DIR/tutorials
  64 setenv FOAM_UTILITIES $FOAM_APP/utilities
  65 setenv FOAM_SOLVERS $FOAM_APP/solvers
  66 setenv FOAM_RUN $WM_PROJECT_USER_DIR/run
  67
  68 # add OpenFOAM scripts and wmake to the path
  69 set path=($WM_DIR $WM_PROJECT_DIR/bin $path)
  70
  71 _foamAddPath $FOAM_APPBIN
  72 _foamAddPath $FOAM_SITE_APPBIN
  73 _foamAddPath $FOAM_USER_APPBIN
  74  # Make sure to pick up dummy versions of external libraries last
  75 _foamAddLib  $FOAM_LIBBIN/dummy
  76 _foamAddLib  $FOAM_LIBBIN
  77 _foamAddLib  $FOAM_SITE_LIBBIN
  78 _foamAddLib  $FOAM_USER_LIBBIN
  79
  80
  81 # Select compiler installation
  82 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  83 # compilerInstall = OpenFOAM | System
  84 #set compilerInstall=OpenFOAM
  85 #set compilerInstall=System
  86 if ( ! $?compilerInstall ) then
  87     setenv compilerInstall System
  88 endif
  89
  90 switch ("$compilerInstall")
  91 case OpenFOAM:
  92     switch ("$WM_COMPILER")
  93     case Gcc:
  94         setenv WM_COMPILER_DIR $WM_THIRD_PARTY_DIR/gcc-4.3.3/platforms/$WM_ARCH$WM_COMPILER_ARCH
  95         _foamAddLib $WM_THIRD_PARTY_DIR/mpfr-2.4.1/platforms/$WM_ARCH$WM_COMPILER_ARCH/lib
  96         _foamAddLib $WM_THIRD_PARTY_DIR/gmp-4.2.4/platforms/$WM_ARCH$WM_COMPILER_ARCH/lib
  97     breaksw
  98     case Gcc45:
  99         setenv WM_COMPILER_DIR $WM_THIRD_PARTY_DIR/packages/gcc-4.5.1/platforms/$WM_OPTIONS
 100         _foamSource  $WM_THIRD_PARTY_DIR/packages/gmp-5.0.1/platforms/$WM_OPTIONS/etc/gmp-5.0.1.csh
 101         _foamSource  $WM_THIRD_PARTY_DIR/packages/mpfr-3.0.1/platforms/$WM_OPTIONS/etc/mpfr-3.0.1.csh
 102         _foamSource  $WM_THIRD_PARTY_DIR/packages/mpc-0.8.2/platforms/$WM_OPTIONS/etc/mpc-0.8.2.csh
 103         _foamSource  $WM_THIRD_PARTY_DIR/packages/gcc-4.5.1/platforms/$WM_OPTIONS/etc/gcc-4.5.1.csh
 104     breaksw
 105     case Gcc44:
 106         setenv WM_COMPILER_DIR $WM_THIRD_PARTY_DIR/packages/gcc-4.4.5/platforms/$WM_OPTIONS
 107         _foamSource  $WM_THIRD_PARTY_DIR/packages/mpfr-3.0.1/platforms/$WM_OPTIONS/etc/mpfr-3.0.1.csh
 108         _foamSource  $WM_THIRD_PARTY_DIR/packages/gmp-5.0.1/platforms/$WM_OPTIONS/etc/gmp-5.0.1.csh
 109         _foamSource  $WM_THIRD_PARTY_DIR/packages/gcc-4.4.5/platforms/$WM_OPTIONS/etc/gcc-4.4.5.csh
 110     breaksw
 111     case Gcc43:
 112         setenv WM_COMPILER_DIR $WM_THIRD_PARTY_DIR/gcc-4.3.3/platforms/$WM_ARCH$WM_COMPILER_ARCH
 113         _foamAddLib $WM_THIRD_PARTY_DIR/mpfr-2.4.1/platforms/$WM_ARCH$WM_COMPILER_ARCH/lib
 114         _foamAddLib $WM_THIRD_PARTY_DIR/gmp-4.2.4/platforms/$WM_ARCH$WM_COMPILER_ARCH/lib
 115     breaksw
 116     case Gcc42:
 117         setenv WM_COMPILER_DIR $WM_THIRD_PARTY_DIR/gcc-4.2.4/platforms/$WM_ARCH$WM_COMPILER_ARCH
 118     breaksw
 119     endsw
 120
 121     # Check that the compiler directory can be found
 122     if ( ! -d "$WM_COMPILER_DIR" ) then
 123         echo
 124         echo "Warning in $WM_PROJECT_DIR/etc/settings.csh:"
 125         echo "    Cannot find $WM_COMPILER_DIR installation."
 126         echo "    Please install this compiler version or if you wish to use the system compiler,"
 127         echo "    change the 'compilerInstall' setting to 'System' in this file"
 128         echo
 129     endif
 130
 131     _foamAddPath ${WM_COMPILER_DIR}/bin
 132     _foamAddLib  ${WM_COMPILER_DIR}/lib${WM_COMPILER_LIB_ARCH}
 133     _foamAddLib  ${WM_COMPILER_DIR}/lib
 134
 135     breaksw
 136 endsw
 137
 138
 139 switch ("$WM_COMPILER")
 140 case Gcc*:
 141     setenv WM_CC 'gcc'
 142     setenv WM_CXX 'g++'
 143     breaksw
 144 case Icc:
 145     setenv WM_CC 'icc'
 146     setenv WM_CXX 'icpc'
 147     breaksw
 148 endsw
 149
 150 # Communications library
 151 # ~~~~~~~~~~~~~~~~~~~~~~
 152
 153 unset MPI_ARCH_PATH
 154
 155 set mpi_version=unknown
 156
 157 switch ("$WM_MPLIB")
 158 case OPENMPI:
 159     if (-d $WM_THIRD_PARTY_DIR/packages/openmpi-1.6.5/platforms/$WM_OPTIONS ) then
 160         set mpi_version=openmpi-1.6.5
 161
 162         if ($?FOAM_VERBOSE && $?prompt) then
 163             echo "Using openmpi-1.6.5 from the ThirdParty package: $WM_THIRD_PARTY_DIR/packages/$mpi_version"
 164         endif
 165         _foamSource  $WM_THIRD_PARTY_DIR/packages/$mpi_version/platforms/$WM_OPTIONS/etc/$mpi_version.csh
 166
 167     else if (-d $WM_THIRD_PARTY_DIR/packages/openmpi-1.4.3/platforms/$WM_OPTIONS ) then
 168         set mpi_version=openmpi-1.4.3
 169
 170         if ($?FOAM_VERBOSE && $?prompt) then
 171             echo "Using openmpi-1.4.3 from the ThirdParty package: $WM_THIRD_PARTY_DIR/packages/$mpi_version"
 172         endif
 173         _foamSource  $WM_THIRD_PARTY_DIR/packages/$mpi_version/platforms/$WM_OPTIONS/etc/$mpi_version.csh
 174
 175     else if (-d $WM_THIRD_PARTY_DIR/packages/openmpi-1.5/platforms/$WM_OPTIONS ) then
 176         set mpi_version=openmpi-1.5
 177
 178         if ($?FOAM_VERBOSE && $?prompt) then
 179             echo "Using openmpi-1.5 from the ThirdParty package: $WM_THIRD_PARTY_DIR/packages/$mpi_version"
 180         endif
 181         _foamSource  $WM_THIRD_PARTY_DIR/packages/$mpi_version/platforms/$WM_OPTIONS/etc/$mpi_version.csh
 182     endif
 183
 184     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/$mpi_version
 185     unset mpi_version
 186     breaksw
 187
 188 case SYSTEMOPENMPI:
 189     set mpi_version=openmpi-system
 190
 191     # make sure not the "old" mpi is used
 192     # Not sure if this is necessary anymore.
 193     # export OPAL_PREFIX=
 194
 195     # Make sure OPENMPI_BIN_DIR is set and valid
 196     if ($?OPENMPI_BIN_DIR != 0 ) then
 197         if (-d "${OPENMPI_BIN_DIR}" ) then
 198         # User defined value specified for OPENMPI_BIN_DIR
 199         #
 200         # WARNING:
 201         #          We assume this path specified by $OPENMPI_BIN_DIR is valid
 202         #          We assume the command mpicc is located somewhere under this path
 203         #          We assume the file mpi.h is located somewhere under this path
 204         #
 205             #          Otherwise, please double check your openmpi installation, you are
 206         #          probably missing the openmpi runtime and/or development packages
 207         #          available for your system.
 208         #
 209         _foamAddPath $OPENMPI_BIN_DIR
 210          endif
 211     else
 212     # Here, we assume your environment is already set for running
 213     # and developing with openmpi.
 214     #
 215     # Initialize OPENMPI_BIN_DIR using the path to mpicc
 216         set mpicc_cmd=`which mpicc`
 217         setenv OPENMPI_BIN_DIR `dirname $mpicc_cmd`
 218         unset mpicc_cmd
 219     endif
 220
 221     # Make sure OPENMPI_LIB_DIR is set
 222     if ( $?OPENMPI_LIB_DIR == 0 ) then
 223         # Initialize OPENMPI_LIB_DIR using the path to mpicc
 224         setenv OPENMPI_LIB_DIR "`mpicc --showme:libdirs`"
 225     endif
 226
 227     # Make sure the dynamic libraries are accessible
 228     if( $?OPENMPI_LIB_DIR != 0 ) then
 229         _foamAddLib $OPENMPI_LIB_DIR
 230     endif
 231
 232     setenv MPI_HOME `dirname $OPENMPI_BIN_DIR`
 233     setenv MPI_ARCH_PATH $MPI_HOME
 234     setenv OPAL_PREFIX $MPI_ARCH_PATH
 235
 236     # We initialize the rest of the environment using mpicc --showme:
 237     if ($?OPENMPI_INCLUDE_DIR == 0) then
 238         setenv OPENMPI_INCLUDE_DIR "`mpicc --showme:incdirs`"
 239     endif
 240
 241     if (${?OPENMPI_COMPILE_FLAGS} == 0) then
 242         setenv OPENMPI_COMPILE_FLAGS "`mpicc --showme:compile`"
 243     endif
 244
 245     if (${?OPENMPI_COMPILE_FLAGS} == 0) then
 246         setenv OPENMPI_COMPILE_FLAGS "`mpicc --showme:compile`"
 247     endif
 248
 249     if (${?OPENMPI_LINK_FLAGS} == 0) then
 250         setenv OPENMPI_LINK_FLAGS "`mpicc --showme:link`"
 251     endif
 252
 253     #
 254     # WARNING: We assume the file mpi.h will be available under the directories identified
 255     #          by the variable $OPENMPI_INCLUDE_DIR. Otherwise, please double check your
 256     #          system openmpi installation.
 257
 258     # Set compilation flags here instead of in wmake/rules/../mplibSYSTEMOPENMPI
 259     setenv PINC "$OPENMPI_COMPILE_FLAGS"
 260     setenv PLIBS "$OPENMPI_LINK_FLAGS"
 261
 262     # No longer needed, but we keep this as a reference, just in case...
 263     #libDir `echo "$PLIBS" | sed -e 's/.*-L\([^ ]*\).*/\1/'`
 264     #_foamAddLib $libDir
 265
 266     if ($?FOAM_VERBOSE && $?prompt) then
 267         echo "Using system installed OpenMPI:"
 268         echo "    OPENMPI_BIN_DIR       : $OPENMPI_BIN_DIR"
 269         echo "    OPENMPI_LIB_DIR       : $OPENMPI_LIB_DIR"
 270         echo "    OPENMPI_INCLUDE_DIR   : $OPENMPI_INCLUDE_DIR"
 271         echo "    OPENMPI_COMPILE_FLAGS : $OPENMPI_COMPILE_FLAGS"
 272         echo "    OPENMPI_LINK_FLAGS    : $OPENMPI_LINK_FLAGS"
 273         echo ""
 274         echo "    MPI_HOME              : $MPI_HOME"
 275         echo "    MPI_ARCH_PATH         : $MPI_ARCH_PATH"
 276         echo "    OPAL_PREFIX           : $OPAL_PREFIX"
 277         echo "    PINC                  : $PINC"
 278         echo "    PLIBS                 : $PLIBS"
 279     endif
 280
 281     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/$mpi_version
 282     unset mpi_version
 283     breaksw
 284
 285 case MPICH:
 286     set mpi_version=mpich-1.2.4
 287     setenv MPI_HOME $WM_THIRD_PARTY_DIR/$mpi_version
 288     setenv MPI_ARCH_PATH $MPI_HOME/platforms/$WM_OPTIONS
 289     setenv MPICH_ROOT $MPI_ARCH_PATH
 290
 291     _foamAddPath $MPI_ARCH_PATH/bin
 292     _foamAddLib  $MPI_ARCH_PATH/lib
 293
 294     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/$mpi_version
 295     unset mpi_version
 296     breaksw
 297
 298 case MPICH-GM:
 299     setenv MPI_ARCH_PATH /opt/mpi
 300     setenv MPICH_PATH $MPI_ARCH_PATH
 301     setenv MPICH_ROOT $MPI_ARCH_PATH
 302     setenv GM_LIB_PATH /opt/gm/lib64
 303
 304     _foamAddPath $MPI_ARCH_PATH/bin
 305     _foamAddLib  $MPI_ARCH_PATH/lib
 306     _foamAddLib  $GM_LIB_PATH
 307
 308     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/mpich-gm
 309     breaksw
 310
 311 case HPMPI:
 312     setenv MPI_HOME /opt/hpmpi
 313     setenv MPI_ARCH_PATH $MPI_HOME
 314     setenv MPICH_ROOT=$MPI_ARCH_PATH
 315
 316     _foamAddPath $MPI_ARCH_PATH/bin
 317
 318     switch (`uname -m`)
 319     case i686:
 320         _foamAddLib $MPI_ARCH_PATH/lib/linux_ia32
 321         breaksw
 322     case x86_64:
 323         _foamAddLib $MPI_ARCH_PATH/lib/linux_amd64
 324         breaksw
 325     case ia64:
 326         _foamAddLib $MPI_ARCH_PATH/lib/linux_ia64
 327         breaksw
 328     default:
 329         echo Unknown processor type `uname -m` for Linux
 330         breaksw
 331     endsw
 332
 333     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/hpmpi
 334     breaksw
 335
 336 case GAMMA:
 337     setenv MPI_ARCH_PATH /usr
 338     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/gamma
 339     breaksw
 340
 341 case MPI:
 342     setenv MPI_ARCH_PATH /opt/mpi
 343     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/mpi
 344     breaksw
 345
 346 case FJMPI:
 347     setenv MPI_ARCH_PATH /opt/FJSVmpi2
 348     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/mpi
 349     _foamAddPath $MPI_ARCH_PATH/bin
 350     _foamAddLib  $MPI_ARCH_PATH/lib/sparcv9
 351     _foamAddLib  /opt/FSUNf90/lib/sparcv9
 352     _foamAddLib  /opt/FJSVpnidt/lib
 353     breaksw
 354
 355 case QSMPI:
 356     setenv MPI_ARCH_PATH /usr/lib/mpi
 357     setenv FOAM_MPI_LIBBIN FOAM_LIBBIN/qsmpi
 358
 359     _foamAddPath $MPI_ARCH_PATH/bin
 360     _foamAddLib $MPI_ARCH_PATH/lib
 361
 362     breaksw
 363
 364 default:
 365     setenv FOAM_MPI_LIBBIN $FOAM_LIBBIN/dummy
 366     breaksw
 367 endsw
 368
 369 _foamAddLib $FOAM_MPI_LIBBIN
 370
 371
 372 # Set the minimum MPI buffer size (used by all platforms except SGI MPI)
 373 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 374 set minBufferSize=20000000
 375
 376 if ( $?MPI_BUFFER_SIZE ) then
 377     if ( $MPI_BUFFER_SIZE < $minBufferSize ) then
 378         setenv MPI_BUFFER_SIZE $minBufferSize
 379     endif
 380 else
 381     setenv MPI_BUFFER_SIZE $minBufferSize
 382 endif
 383
 384 # CUDA library
 385 # ~~~~~~~~~~~~
 386 if ( $?CUDA_SYSTEM == 0 && -e /usr/local/cuda-5.5/bin/nvcc ) then
 387     setenv CUDA_DIR /usr/local/cuda-5.5
 388     setenv CUDA_BIN_DIR $CUDA_DIR/bin
 389     setenv CUDA_LIB_DIR $CUDA_DIR/lib64
 390     setenv CUDA_INCLUDE_DIR $CUDA_DIR/include
 391     setenv CUDA_ARCH sm_20
 392 endif
 393
 394 if ( $?CUDA_BIN_DIR ) then
 395     _foamAddPath $CUDA_BIN_DIR
 396 endif
 397
 398 if ( $?CUDA_LIB_DIR ) then
 399     _foamAddLib $CUDA_LIB_DIR
 400 endif
 401
 402 # CGAL library if available
 403 # ~~~~~~~~~~~~~~~~~~~~~~~~~
 404 if ( $?CGAL_LIB_DIR ) then
 405     _foamAddLib $CGAL_LIB_DIR
 406 endif
 407
 408 # Mesquite library if available
 409 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 410 if ( $?MESQUITE_SYSTEM == 0 && -e $WM_THIRD_PARTY_DIR/packages/mesquite-2.1.2/platforms/$WM_OPTIONS ) then
 411     _foamSource $WM_THIRD_PARTY_DIR/packages/mesquite-2.1.2/platforms/$WM_OPTIONS/etc/mesquite-2.1.2.csh
 412 endif
 413
 414 # Metis library if available
 415 # ~~~~~~~~~~~~~~~~~~~~~~~~~~
 416 if ( $?METIS_SYSTEM == 0 && -e $WM_THIRD_PARTY_DIR/packages/metis-5.1.0/platforms/$WM_OPTIONS ) then
 417     _foamSource $WM_THIRD_PARTY_DIR/packages/metis-5.1.0/platforms/$WM_OPTIONS/etc/metis-5.1.0.csh
 418 endif
 419
 420 # ParMetis library if available
 421 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 422 if ( $?PARMETIS_SYSTEM == 0 && -e $WM_THIRD_PARTY_DIR/packages/parmetis-4.0.3/platforms/$WM_OPTIONS ) then
 423     _foamSource $WM_THIRD_PARTY_DIR/packages/parmetis-4.0.3/platforms/$WM_OPTIONS/etc/parmetis-4.0.3.csh
 424 endif
 425
 426 # ParMGridGen library if available
 427 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 428 if ( $?PARMGRIDGEN_SYSTEM == 0 && -e $WM_THIRD_PARTY_DIR/packages/ParMGridGen-1.0/platforms/$WM_OPTIONS ) then
 429     _foamSource $WM_THIRD_PARTY_DIR/packages/ParMGridGen-1.0/platforms/$WM_OPTIONS/etc/ParMGridGen-1.0.csh
 430 endif
 431
 432 # Load Libccmio library
 433 # ~~~~~~~~~~~~~~~~~~~~~
 434 if ( $?LIBCCMIO_SYSTEM == 0 && -e $WM_THIRD_PARTY_DIR/packages/libccmio-2.6.1/platforms/$WM_OPTIONS ) then
 435     _foamSource $WM_THIRD_PARTY_DIR/packages/libccmio-2.6.1/platforms/$WM_OPTIONS/etc/libccmio-2.6.1.csh
 436 endif
 437
 438
 439 # Scotch library if available
 440 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 441 if ( $?SCOTCH_SYSTEM == 0 && -e $WM_THIRD_PARTY_DIR/packages/scotch-6.0.0/platforms/$WM_OPTIONS ) then
 442     _foamSource $WM_THIRD_PARTY_DIR/packages/scotch-6.0.0/platforms/$WM_OPTIONS/etc/scotch-6.0.0.csh
 443 endif
 444
 445 # Switch on the hoard memory allocator if available
 446 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 447 #if ( -f $FOAM_LIBBIN/libhoard.so ) then
 448 #    setenv LD_PRELOAD $FOAM_LIBBIN/libhoard.so:${LD_PRELOAD}
 449 #endif
 450
 451 # Third party packages
 452
 453 # cmake
 454 # ~~~~~
 455 if ( $?CMAKE_SYSTEM == 0 && -e "$WM_THIRD_PARTY_DIR"/packages/cmake-2.8.12/platforms/$WM_OPTIONS ) then
 456     _foamSource $WM_THIRD_PARTY_DIR/packages/cmake-2.8.12/platforms/$WM_OPTIONS/etc/cmake-2.8.12.csh
 457 endif
 458
 459 # Python
 460 # ~~~~~
 461 if ( $?PYTHON_SYSTEM == 0 && -e "$WM_THIRD_PARTY_DIR"/packages/Python-2.7/platforms/$WM_OPTIONS ) then
 462     _foamSource $WM_THIRD_PARTY_DIR/packages/Python-2.7/platforms/$WM_OPTIONS/etc/Python-2.7.csh
 463 endif
 464
 465 # PyFoam
 466 # ~~~~~~
 467 if ( $?PYFOAM_SYSTEM == 0 && -e "$WM_THIRD_PARTY_DIR"/packages/PyFoam-0.6.1/platforms/noarch ) then
 468     _foamSource $WM_THIRD_PARTY_DIR/packages/PyFoam-0.6.1/platforms/noarch/etc/PyFoam-0.6.1.csh
 469 endif
 470
 471 # hwloc
 472 # ~~~~~
 473 if ( $?HWLOC_SYSTEM == 0 && -e "$WM_THIRD_PARTY_DIR"/packages/hwloc-1.7.2/platforms/$WM_OPTIONS ) then
 474     _foamSource $WM_THIRD_PARTY_DIR/packages/hwloc-1.7.2/platforms/$WM_OPTIONS/etc/hwloc-1.7.2.csh
 475 endif
 476
 477 # QT
 478 # ~~~~~
 479 if ( $?QT_SYSTEM == 0 && -e "$WM_THIRD_PARTY_DIR"/packages/qt-everywhere-opensource-src-4.8.5/platforms/$WM_OPTIONS )then
 480     _foamSource $WM_THIRD_PARTY_DIR/packages/qt-everywhere-opensource-src-4.8.5/platforms/$WM_OPTIONS/etc/qt-everywhere-opensource-src-4.8.5.csh
 481 endif
 482
 483 # PARAVIEW
 484 # ~~~~~
 485 if ( $?PARAVIEW_SYSTEM == 0 && -e "$WM_THIRD_PARTY_DIR"/packages/ParaView-4.0.1/platforms/$WM_OPTIONS ) then
 486     _foamSource $WM_THIRD_PARTY_DIR/packages/ParaView-4.0.1/platforms/$WM_OPTIONS/etc/ParaView-4.0.1.csh
 487
 488 #if ( $?PARAVIEW_SYSTEM == 0 && -e "$WM_THIRD_PARTY_DIR"/packages/ParaView-3.14.1/platforms/$WM_OPTIONS ) then
 489 #   _foamSource $WM_THIRD_PARTY_DIR/packages/ParaView-3.14.1/platforms/$WM_OPTIONS/etc/ParaView-3.14.1.csh
 490
 491 #if ( $?PARAVIEW_SYSTEM == 0 && -e "$WM_THIRD_PARTY_DIR"/packages/ParaView-3.8.1/platforms/$WM_OPTIONS ) then
 492 #    _foamSource $WM_THIRD_PARTY_DIR/packages/ParaView-3.8.1/platforms/$WM_OPTIONS/etc/ParaView-3.8.1.csh
 493
 494 #if ( $?PARAVIEW_SYSTEM == 0 && -e "$WM_THIRD_PARTY_DIR"/packages/ParaView-3.14.1/platforms/$WM_OPTIONS ) then
 495 #    _foamSource $WM_THIRD_PARTY_DIR/packages/ParaView-3.14.1/platforms/$WM_OPTIONS/etc/ParaView-3.14.1.csh
 496 endif
 497
 498 if ( $WM_ARCH == "darwinIntel" || $WM_ARCH == "darwinIntel64" ) then
 499     setenv DYLD_LIBRARY_PATH ${LD_LIBRARY_PATH}
 500 endif
 501
 502 # cleanup environment:
 503 # ~~~~~~~~~~~~~~~~~~~~
 504 unalias _foamAddPath
 505 unalias _foamAddLib
 506 unset minBufferSize
 507
 508 # -----------------------------------------------------------------------------