etc/settings.csh

   1 #----------------------------------*-sh-*--------------------------------------
   2 # =========                 |
   3 # \\      /  F ield         | foam-extend: Open Source CFD
   4 #  \\    /   O peration     | Version:     3.2
   5 #   \\  /    A nd           | Web:         http://www.foam-extend.org
   6 #    \\/     M anipulation  | For copyright notice see file Copyright
   7 #------------------------------------------------------------------------------
   8 # License
   9 #     This file is part of foam-extend.
  10 #
  11 #     foam-extend is free software: you can redistribute it and/or modify it
  12 #     under the terms of the GNU General Public License as published by the
  13 #     Free Software Foundation, either version 3 of the License, or (at your
  14 #     option) any later version.
  15 #
  16 #     foam-extend is distributed in the hope that it will be useful, but
  17 #     WITHOUT ANY WARRANTY; without even the implied warranty of
  18 #     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 #     General Public License for more details.
  20 #
  21 #     You should have received a copy of the GNU General Public License
  22 #     along with foam-extend.  If not, see <http://www.gnu.org/licenses/>.
  23 #
  24 # Script
  25 #     etc/settings.csh
  26 #
  27 # Description
  28 #     Startup file for FOAM
  29 #     Sourced from FOAM-??/etc/cshrc
  30 #
  31 #------------------------------------------------------------------------------
  32
  33 # prefix to PATH
  34 alias _foamAddPath 'set path=(\!* $path)'
  35 # prefix to LD_LIBRARY_PATH
  36 alias _foamAddLib 'setenv LD_LIBRARY_PATH \!*\:${LD_LIBRARY_PATH}'
  37
  38 # location of the jobControl directory
  39 setenv FOAM_JOB_DIR $WM_PROJECT_INST_DIR/jobControl
  40
  41 # wmake configuration
  42 setenv WM_DIR $WM_PROJECT_DIR/wmake
  43 setenv WM_LINK_LANGUAGE c++
  44 setenv WM_OPTIONS $WM_ARCH$WM_COMPILER$WM_PRECISION_OPTION$WM_COMPILE_OPTION
  45 set path=($WM_DIR $path)
  46
  47 # base configuration
  48 setenv FOAM_APP $WM_PROJECT_DIR/applications
  49 setenv FOAM_APPBIN $WM_PROJECT_DIR/applications/bin/$WM_OPTIONS
  50 setenv FOAM_LIB $WM_PROJECT_DIR/lib
  51 setenv FOAM_LIBBIN $WM_PROJECT_DIR/lib/$WM_OPTIONS
  52 setenv FOAM_SRC $WM_PROJECT_DIR/src
  53
  54 # shared site configuration - similar naming convention as ~FOAM expansion
  55 setenv FOAM_SITE_APPBIN $WM_PROJECT_INST_DIR/site/$WM_PROJECT_VERSION/bin/$WM_OPTIONS
  56 setenv FOAM_SITE_LIBBIN $WM_PROJECT_INST_DIR/site/$WM_PROJECT_VERSION/lib/$WM_OPTIONS
  57
  58 # user configuration
  59 setenv FOAM_USER_APPBIN $WM_PROJECT_USER_DIR/applications/bin/$WM_OPTIONS
  60 setenv FOAM_USER_LIBBIN $WM_PROJECT_USER_DIR/lib/$WM_OPTIONS
  61
  62 # convenience
  63 setenv FOAM_TUTORIALS $WM_PROJECT_DIR/tutorials
  64 setenv FOAM_UTILITIES $FOAM_APP/utilities
  65 setenv FOAM_SOLVERS $FOAM_APP/solvers
  66 setenv FOAM_RUN $WM_PROJECT_USER_DIR/run
  67
  68 # add FOAM scripts and wmake to the path
  69 set path=($WM_DIR $WM_PROJECT_DIR/bin $path)
  70
  71 _foamAddPath $FOAM_APPBIN
  72 _foamAddPath $FOAM_SITE_APPBIN
  73 _foamAddPath $FOAM_USER_APPBIN
  74  # Make sure to pick up dummy versions of external libraries last
  75 _foamAddLib  $FOAM_LIBBIN/dummy
  76 _foamAddLib  $FOAM_LIBBIN
  77 _foamAddLib  $FOAM_SITE_LIBBIN
  78 _foamAddLib  $FOAM_USER_LIBBIN
  79
  80
  81 # Select compiler installation
  82 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  83 # compilerInstall = FOAM | System
  84 #set compilerInstall=FOAM
  85 #set compilerInstall=System
  86 if ( ! $?compilerInstall ) then
  87     setenv compilerInstall System
  88 endif
  89
  90 switch ("$compilerInstall")
  91 case FOAM:
  92     switch ("$WM_COMPILER")
  93     case Gcc:
  94         setenv WM_COMPILER_DIR $WM_THIRD_PARTY_DIR/packages/gcc-4.6.4/platforms/$WM_OPTIONS
  95         _foamSource $WM_THIRD_PARTY_DIR/packages/gmp-5.1.2/platforms/$WM_OPTIONS/etc/gmp-5.1.2.csh
  96         _foamSource $WM_THIRD_PARTY_DIR/packages/mpfr-3.1.2/platforms/$WM_OPTIONS/etc/mpfr-3.1.2.csh
  97         _foamSource $WM_THIRD_PARTY_DIR/packages/mpc-1.0.1/platforms/$WM_OPTIONS/etc/mpc-1.0.1.csh
  98         _foamSource $WM_THIRD_PARTY_DIR/packages/gcc-4.6.4/platforms/$WM_OPTIONS/etc/gcc-4.6.4.csh
  99     breaksw
 100     case Gcc49:
 101         setenv WM_COMPILER_DIR $WM_THIRD_PARTY_DIR/packages/gcc-4.9.2/platforms/$WM_OPTIONS
 102         _foamSource $WM_THIRD_PARTY_DIR/packages/gcc-4.9.2/platforms/$WM_OPTIONS/etc/gcc-4.9.2.csh
 103     breaksw
 104     case Gcc47:
 105         setenv WM_COMPILER_DIR $WM_THIRD_PARTY_DIR/packages/gcc-4.7.4/platforms/$WM_OPTIONS
 106         _foamSource $WM_THIRD_PARTY_DIR/packages/gmp-5.1.2/platforms/$WM_OPTIONS/etc/gmp-5.1.2.csh
 107         _foamSource $WM_THIRD_PARTY_DIR/packages/mpfr-3.1.2/platforms/$WM_OPTIONS/etc/mpfr-3.1.2.csh
 108         _foamSource $WM_THIRD_PARTY_DIR/packages/mpc-1.0.1/platforms/$WM_OPTIONS/etc/mpc-1.0.1.csh
 109         _foamSource $WM_THIRD_PARTY_DIR/packages/gcc-4.7.4/platforms/$WM_OPTIONS/etc/gcc-4.7.4.csh
 110     breaksw
 111     case Gcc45:
 112         setenv WM_COMPILER_DIR $WM_THIRD_PARTY_DIR/packages/gcc-4.5.1/platforms/$WM_OPTIONS
 113         _foamSource $WM_THIRD_PARTY_DIR/packages/gmp-5.0.1/platforms/$WM_OPTIONS/etc/gmp-5.0.1.csh
 114         _foamSource $WM_THIRD_PARTY_DIR/packages/mpfr-3.0.1/platforms/$WM_OPTIONS/etc/mpfr-3.0.1.csh
 115         _foamSource $WM_THIRD_PARTY_DIR/packages/mpc-0.8.2/platforms/$WM_OPTIONS/etc/mpc-0.8.2.csh
 116         _foamSource $WM_THIRD_PARTY_DIR/packages/gcc-4.5.1/platforms/$WM_OPTIONS/etc/gcc-4.5.1.csh
 117     breaksw
 118     case Gcc44:
 119         setenv WM_COMPILER_DIR $WM_THIRD_PARTY_DIR/packages/gcc-4.4.5/platforms/$WM_OPTIONS
 120         _foamSource $WM_THIRD_PARTY_DIR/packages/gmp-5.0.1/platforms/$WM_OPTIONS/etc/gmp-5.0.1.csh
 121         _foamSource $WM_THIRD_PARTY_DIR/packages/mpfr-3.0.1/platforms/$WM_OPTIONS/etc/mpfr-3.0.1.csh
 122         _foamSource $WM_THIRD_PARTY_DIR/packages/gcc-4.4.5/platforms/$WM_OPTIONS/etc/gcc-4.4.5.csh
 123     breaksw
 124     endsw
 125
 126     # Check that the compiler directory can be found
 127     if ( ! -d "$WM_COMPILER_DIR" ) then
 128         echo
 129         echo "Warning in $WM_PROJECT_DIR/etc/settings.csh:"
 130         echo "    Cannot find $WM_COMPILER_DIR installation."
 131         echo "    Please install this compiler version or if you wish to use the system compiler,"
 132         echo "    change the 'compilerInstall' setting to 'System' in this file"
 133         echo
 134     endif
 135
 136     _foamAddPath ${WM_COMPILER_DIR}/bin
 137     _foamAddLib  ${WM_COMPILER_DIR}/lib${WM_COMPILER_LIB_ARCH}
 138     _foamAddLib  ${WM_COMPILER_DIR}/lib
 139
 140     breaksw
 141 endsw
 142
 143
 144 switch ("$WM_COMPILER")
 145 case Gcc*:
 146     setenv WM_CC 'gcc'
 147     setenv WM_CXX 'g++'
 148     breaksw
 149 case Icc:
 150     setenv WM_CC 'icc'
 151     setenv WM_CXX 'icpc'
 152     breaksw
 153 endsw
 154
 155 # Communications library
 156 # ~~~~~~~~~~~~~~~~~~~~~~
 157
 158 unset MPI_ARCH_PATH
 159
 160 set mpi_version=unknown
 161
 162 switch ("$WM_MPLIB")
 163 case OPENMPI:
 164     if ($?WM_THIRD_PARTY_USE_OPENMPI_188 != 0 && -d $WM_THIRD_PARTY_DIR/packages/openmpi-1.8.8/platforms/$WM_OPTIONS ) then
 165         set mpi_version=openmpi-1.8.8
 166
 167         if ($?FOAM_VERBOSE && $?prompt) then
 168             echo "Using openmpi-1.8.8 from the ThirdParty package: $WM_THIRD_PARTY_DIR/packages/$mpi_version"
 169         endif
 170         _foamSource  $WM_THIRD_PARTY_DIR/packages/$mpi_version/platforms/$WM_OPTIONS/etc/$mpi_version.csh
 171
 172     else if ($?WM_THIRD_PARTY_USE_OPENMPI_165 != 0 && -d $WM_THIRD_PARTY_DIR/packages/openmpi-1.6.5/platforms/$WM_OPTIONS ) then
 173         set mpi_version=openmpi-1.6.5
 174
 175         if ($?FOAM_VERBOSE && $?prompt) then
 176             echo "Using openmpi-1.6.5 from the ThirdParty package: $WM_THIRD_PARTY_DIR/packages/$mpi_version"
 177         endif
 178         _foamSource  $WM_THIRD_PARTY_DIR/packages/$mpi_version/platforms/$WM_OPTIONS/etc/$mpi_version.csh
 179
 180     else if ($?WM_THIRD_PARTY_USE_OPENMPI_143 != 0 && -d $WM_THIRD_PARTY_DIR/packages/openmpi-1.4.3/platforms/$WM_OPTIONS ) then
 181         set mpi_version=openmpi-1.4.3
 182
 183         if ($?FOAM_VERBOSE && $?prompt) then
 184             echo "Using openmpi-1.4.3 from the ThirdParty package: $WM_THIRD_PARTY_DIR/packages/$mpi_version"
 185         endif
 186         _foamSource  $WM_THIRD_PARTY_DIR/packages/$mpi_version/platforms/$WM_OPTIONS/etc/$mpi_version.csh
 187
 188     else if ($?WM_THIRD_PARTY_USE_OPENMPI_143 != 0 && -d $WM_THIRD_PARTY_DIR/packages/openmpi-1.5/platforms/$WM_OPTIONS ) then
 189         set mpi_version=openmpi-1.5
 190
 191         if ($?FOAM_VERBOSE && $?prompt) then
 192             echo "Using openmpi-1.5 from the ThirdParty package: $WM_THIRD_PARTY_DIR/packages/$mpi_version"
 193         endif
 194         _foamSource  $WM_THIRD_PARTY_DIR/packages/$mpi_version/platforms/$WM_OPTIONS/etc/$mpi_version.csh
 195     endif
 196
 197     unset mpi_version
 198     breaksw
 199
 200 case SYSTEMOPENMPI:
 201     set mpi_version=openmpi-system
 202
 203     # make sure not the "old" mpi is used
 204     # Not sure if this is necessary anymore.
 205     # export OPAL_PREFIX=
 206
 207     # Make sure OPENMPI_BIN_DIR is set and valid
 208     if ($?OPENMPI_BIN_DIR != 0 ) then
 209         if (-d "${OPENMPI_BIN_DIR}" ) then
 210         # User defined value specified for OPENMPI_BIN_DIR
 211         #
 212         # WARNING:
 213         #          We assume this path specified by $OPENMPI_BIN_DIR is valid
 214         #          We assume the command mpicc is located somewhere under this path
 215         #          We assume the file mpi.h is located somewhere under this path
 216         #
 217             #          Otherwise, please double check your openmpi installation, you are
 218         #          probably missing the openmpi runtime and/or development packages
 219         #          available for your system.
 220         #
 221         _foamAddPath $OPENMPI_BIN_DIR
 222          endif
 223     else
 224     # Here, we assume your environment is already set for running
 225     # and developing with openmpi.
 226     #
 227     # Initialize OPENMPI_BIN_DIR using the path to mpicc
 228         set mpicc_cmd=`which mpicc`
 229         setenv OPENMPI_BIN_DIR `dirname $mpicc_cmd`
 230         unset mpicc_cmd
 231     endif
 232
 233     # Make sure OPENMPI_LIB_DIR is set
 234     if ( $?OPENMPI_LIB_DIR == 0 ) then
 235         # Initialize OPENMPI_LIB_DIR using the path to mpicc
 236         setenv OPENMPI_LIB_DIR "`mpicc --showme:libdirs`"
 237     endif
 238
 239     # Make sure the dynamic libraries are accessible
 240     if( $?OPENMPI_LIB_DIR != 0 ) then
 241         _foamAddLib $OPENMPI_LIB_DIR
 242     endif
 243
 244     setenv MPI_HOME `dirname $OPENMPI_BIN_DIR`
 245     setenv MPI_ARCH_PATH $MPI_HOME
 246     setenv OPAL_PREFIX $MPI_ARCH_PATH
 247
 248     # We initialize the rest of the environment using mpicc --showme:
 249     if ($?OPENMPI_INCLUDE_DIR == 0) then
 250         setenv OPENMPI_INCLUDE_DIR "`mpicc --showme:incdirs`"
 251     endif
 252
 253     if (${?OPENMPI_COMPILE_FLAGS} == 0) then
 254         setenv OPENMPI_COMPILE_FLAGS "`mpicc --showme:compile`"
 255     endif
 256
 257     if (${?OPENMPI_COMPILE_FLAGS} == 0) then
 258         setenv OPENMPI_COMPILE_FLAGS "`mpicc --showme:compile`"
 259     endif
 260
 261     if (${?OPENMPI_LINK_FLAGS} == 0) then
 262         setenv OPENMPI_LINK_FLAGS "`mpicc --showme:link`"
 263     endif
 264
 265     #
 266     # WARNING: We assume the file mpi.h will be available under the directories identified
 267     #          by the variable $OPENMPI_INCLUDE_DIR. Otherwise, please double check your
 268     #          system openmpi installation.
 269
 270     # Set compilation flags here instead of in wmake/rules/../mplibSYSTEMOPENMPI
 271     setenv PINC "$OPENMPI_COMPILE_FLAGS"
 272     setenv PLIBS "$OPENMPI_LINK_FLAGS"
 273
 274     # No longer needed, but we keep this as a reference, just in case...
 275     #libDir `echo "$PLIBS" | sed -e 's/.*-L\([^ ]*\).*/\1/'`
 276     #_foamAddLib $libDir
 277
 278     if ($?FOAM_VERBOSE && $?prompt) then
 279         echo "Using system installed OpenMPI:"
 280         echo "    OPENMPI_BIN_DIR       : $OPENMPI_BIN_DIR"
 281         echo "    OPENMPI_LIB_DIR       : $OPENMPI_LIB_DIR"
 282         echo "    OPENMPI_INCLUDE_DIR   : $OPENMPI_INCLUDE_DIR"
 283         echo "    OPENMPI_COMPILE_FLAGS : $OPENMPI_COMPILE_FLAGS"
 284         echo "    OPENMPI_LINK_FLAGS    : $OPENMPI_LINK_FLAGS"
 285         echo ""
 286         echo "    MPI_HOME              : $MPI_HOME"
 287         echo "    MPI_ARCH_PATH         : $MPI_ARCH_PATH"
 288         echo "    OPAL_PREFIX           : $OPAL_PREFIX"
 289         echo "    PINC                  : $PINC"
 290         echo "    PLIBS                 : $PLIBS"
 291     endif
 292
 293     unset mpi_version
 294     breaksw
 295
 296 case MVAPICH2:
 297     set mpi_version=mvapich2
 298
 299     if ($?MVAPICH2_BIN_DIR != 0) then
 300         if (-d "${MVAPICH2_BIN_DIR}" ) then
 301         _foamAddPath $MVAPICH2_BIN_DIR
 302         endif
 303     else
 304         set mpicc_cmd=`which mpicc`
 305         setenv MVAPICH2_BIN_DIR `dirname $mpicc_cmd`
 306         unset mpicc_cmd
 307     endif
 308
 309     setenv MPI_HOME `dirname $MVAPICH2_BIN_DIR`
 310     setenv MPI_ARCH_PATH $MPI_HOME
 311
 312     setenv  PINC "`mpicc -show -cc= -nativelinking`"
 313     setenv  PLIBS "`mpicc -show -cc= | sed "s%$PINC%%"`"
 314
 315     if ($?FOAM_VERBOSE && $?prompt) then
 316         echo "  Environment variables defined for MVAPICH2:"
 317         echo "    MPI_ARCH_PATH         : $MPI_ARCH_PATH"
 318         echo "    PINC                  : $PINC"
 319         echo "    PLIBS                 : $PLIBS"
 320     endif
 321
 322     unset mpi_version
 323     breaksw
 324
 325 case MPICH:
 326     set mpi_version=mpich-1.2.4
 327     setenv MPI_HOME $WM_THIRD_PARTY_DIR/$mpi_version
 328     setenv MPI_ARCH_PATH $MPI_HOME/platforms/$WM_OPTIONS
 329     setenv MPICH_ROOT $MPI_ARCH_PATH
 330
 331     _foamAddPath $MPI_ARCH_PATH/bin
 332     _foamAddLib  $MPI_ARCH_PATH/lib
 333
 334     unset mpi_version
 335     breaksw
 336
 337 case MPICH-GM:
 338     setenv MPI_ARCH_PATH /opt/mpi
 339     setenv MPICH_PATH $MPI_ARCH_PATH
 340     setenv MPICH_ROOT $MPI_ARCH_PATH
 341     setenv GM_LIB_PATH /opt/gm/lib64
 342
 343     _foamAddPath $MPI_ARCH_PATH/bin
 344     _foamAddLib  $MPI_ARCH_PATH/lib
 345     _foamAddLib  $GM_LIB_PATH
 346     breaksw
 347
 348 case HPMPI:
 349     setenv MPI_HOME /opt/hpmpi
 350     setenv MPI_ARCH_PATH $MPI_HOME
 351     setenv MPICH_ROOT=$MPI_ARCH_PATH
 352
 353     _foamAddPath $MPI_ARCH_PATH/bin
 354
 355     switch (`uname -m`)
 356     case i686:
 357         _foamAddLib $MPI_ARCH_PATH/lib/linux_ia32
 358         breaksw
 359     case x86_64:
 360         _foamAddLib $MPI_ARCH_PATH/lib/linux_amd64
 361         breaksw
 362     case ia64:
 363         _foamAddLib $MPI_ARCH_PATH/lib/linux_ia64
 364         breaksw
 365     default:
 366         echo Unknown processor type `uname -m` for Linux
 367         breaksw
 368     endsw
 369     breaksw
 370
 371 case GAMMA:
 372     setenv MPI_ARCH_PATH /usr
 373     breaksw
 374
 375 case MPI:
 376     setenv MPI_ARCH_PATH /opt/mpi
 377     breaksw
 378
 379 case FJMPI:
 380     setenv MPI_ARCH_PATH /opt/FJSVmpi2
 381     _foamAddPath $MPI_ARCH_PATH/bin
 382     _foamAddLib  $MPI_ARCH_PATH/lib/sparcv9
 383     _foamAddLib  /opt/FSUNf90/lib/sparcv9
 384     _foamAddLib  /opt/FJSVpnidt/lib
 385     breaksw
 386
 387 case QSMPI:
 388     setenv MPI_ARCH_PATH /usr/lib/mpi
 389     _foamAddPath $MPI_ARCH_PATH/bin
 390     _foamAddLib $MPI_ARCH_PATH/lib
 391
 392     breaksw
 393
 394 case SGIMPI:
 395     if ( ! $?MPI_ROOT) setenv MPI_ROOT /dummy
 396
 397     if ( ! -d "$MPI_ROOT" ) then
 398         echo "Warning in $WM_PROJECT_DIR/etc/config/settings.csh:"
 399         echo "    MPI_ROOT not a valid mpt installation directory."
 400         echo "    Please set MPI_ROOT to the mpt installation directory."
 401         echo "    (usually done by loading the mpt module)"
 402         echo "    MPI_ROOT currently set to '$MPI_ROOT'"
 403     endif
 404
 405     if ( "${MPI_ROOT:h}/" == $MPI_ROOT ) then
 406         setenv MPI_ROOT ${MPI_ROOT:h}
 407     endif
 408
 409     setenv FOAM_MPI ${MPI_ROOT:t}
 410     setenv MPI_ARCH_PATH $MPI_ROOT
 411
 412
 413     if ($?FOAM_VERBOSE && $?prompt) then
 414         echo "Using SGI MPT:"
 415         echo "    MPI_ROOT : $MPI_ROOT"
 416         echo "    FOAM_MPI : $FOAM_MPI"
 417     endif
 418
 419
 420     _foamAddPath    $MPI_ARCH_PATH/bin
 421     _foamAddLib     $MPI_ARCH_PATH/lib
 422     breaksw
 423
 424 case INTELMPI:
 425     if ( ! $?MPI_ROOT) setenv MPI_ROOT /dummy
 426
 427     if ( ! -d "$MPI_ROOT" ) then
 428         echo "Warning in $WM_PROJECT_DIR/etc/config/settings.csh:"
 429         echo "    MPI_ROOT not a valid mpt installation directory."
 430         echo "    Please set MPI_ROOT to the mpt installation directory."
 431         echo "    (usually done by loading the mpt module)"
 432         echo "    MPI_ROOT currently set to '$MPI_ROOT'"
 433     endif
 434
 435     if ( "${MPI_ROOT:h}/" == $MPI_ROOT ) then
 436         setenv MPI_ROOT ${MPI_ROOT:h}
 437     endif
 438
 439     setenv FOAM_MPI ${MPI_ROOT:t}
 440     setenv MPI_ARCH_PATH $MPI_ROOT
 441
 442
 443     if ($?FOAM_VERBOSE && $?prompt) then
 444         echo "Using INTEL MPT:"
 445         echo "    MPI_ROOT : $MPI_ROOT"
 446         echo "    FOAM_MPI : $FOAM_MPI"
 447     endif
 448
 449
 450     _foamAddPath    $MPI_ARCH_PATH/bin64
 451     _foamAddLib     $MPI_ARCH_PATH/lib64
 452     breaksw
 453
 454 default:
 455     breaksw
 456 endsw
 457
 458 # Set the minimum MPI buffer size (used by all platforms except SGI MPI)
 459 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 460 set minBufferSize=20000000
 461
 462 if ( $?MPI_BUFFER_SIZE ) then
 463     if ( $MPI_BUFFER_SIZE < $minBufferSize ) then
 464         setenv MPI_BUFFER_SIZE $minBufferSize
 465     endif
 466 else
 467     setenv MPI_BUFFER_SIZE $minBufferSize
 468 endif
 469
 470 # CUDA library
 471 # ~~~~~~~~~~~~
 472 if ( $?CUDA_SYSTEM == 0 && -e /usr/local/cuda-5.5/bin/nvcc ) then
 473     setenv CUDA_DIR /usr/local/cuda-5.5
 474     setenv CUDA_BIN_DIR $CUDA_DIR/bin
 475     setenv CUDA_LIB_DIR $CUDA_DIR/lib64
 476     setenv CUDA_INCLUDE_DIR $CUDA_DIR/include
 477     setenv CUDA_ARCH sm_20
 478 endif
 479
 480 if ( $?CUDA_BIN_DIR ) then
 481     _foamAddPath $CUDA_BIN_DIR
 482 endif
 483
 484 if ( $?CUDA_LIB_DIR ) then
 485     _foamAddLib $CUDA_LIB_DIR
 486 endif
 487
 488 # CGAL library if available
 489 # ~~~~~~~~~~~~~~~~~~~~~~~~~
 490 if ( $?CGAL_LIB_DIR ) then
 491     _foamAddLib $CGAL_LIB_DIR
 492 endif
 493
 494 # Mesquite library if available
 495 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 496 if ( $?MESQUITE_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_MESQUITE_212 != 0 && -e $WM_THIRD_PARTY_DIR/packages/mesquite-2.1.2/platforms/$WM_OPTIONS ) then
 497     _foamSource $WM_THIRD_PARTY_DIR/packages/mesquite-2.1.2/platforms/$WM_OPTIONS/etc/mesquite-2.1.2.csh
 498 endif
 499
 500 # Metis library if available
 501 # ~~~~~~~~~~~~~~~~~~~~~~~~~~
 502 if ( $?METIS_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_METIS_510 != 0 && -e $WM_THIRD_PARTY_DIR/packages/metis-5.1.0/platforms/$WM_OPTIONS ) then
 503     _foamSource $WM_THIRD_PARTY_DIR/packages/metis-5.1.0/platforms/$WM_OPTIONS/etc/metis-5.1.0.csh
 504 endif
 505
 506 # ParMetis library if available
 507 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 508 if ( $?PARMETIS_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_PARMETIS_403 != 0 && -e $WM_THIRD_PARTY_DIR/packages/parmetis-4.0.3/platforms/$WM_OPTIONS ) then
 509     _foamSource $WM_THIRD_PARTY_DIR/packages/parmetis-4.0.3/platforms/$WM_OPTIONS/etc/parmetis-4.0.3.csh
 510 endif
 511
 512 # ParMGridGen library if available
 513 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 514 if ( $?PARMGRIDGEN_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_PARMGRIDGEN_10 != 0 && -e $WM_THIRD_PARTY_DIR/packages/ParMGridGen-1.0/platforms/$WM_OPTIONS ) then
 515     _foamSource $WM_THIRD_PARTY_DIR/packages/ParMGridGen-1.0/platforms/$WM_OPTIONS/etc/ParMGridGen-1.0.csh
 516 endif
 517
 518 # Load Libccmio library
 519 # ~~~~~~~~~~~~~~~~~~~~~
 520 if ( $?LIBCCMIO_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_LIBCCMIO_261 != 0 && -e $WM_THIRD_PARTY_DIR/packages/libccmio-2.6.1/platforms/$WM_OPTIONS ) then
 521     _foamSource $WM_THIRD_PARTY_DIR/packages/libccmio-2.6.1/platforms/$WM_OPTIONS/etc/libccmio-2.6.1.csh
 522 endif
 523
 524
 525 # Scotch library if available
 526 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 527 if ( $?SCOTCH_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_SCOTCH_604 != 0 && -e $WM_THIRD_PARTY_DIR/packages/scotch-6.0.4/platforms/$WM_OPTIONS ) then
 528     _foamSource $WM_THIRD_PARTY_DIR/packages/scotch-6.0.4/platforms/$WM_OPTIONS/etc/scotch-6.0.4.csh
 529 endif
 530
 531 if ( $?SCOTCH_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_SCOTCH_600 != 0 && -e $WM_THIRD_PARTY_DIR/packages/scotch-6.0.0/platforms/$WM_OPTIONS ) then
 532     _foamSource $WM_THIRD_PARTY_DIR/packages/scotch-6.0.0/platforms/$WM_OPTIONS/etc/scotch-6.0.0.csh
 533 endif
 534
 535 # Switch on the hoard memory allocator if available
 536 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 537 #if ( -f $FOAM_LIBBIN/libhoard.so ) then
 538 #    setenv LD_PRELOAD $FOAM_LIBBIN/libhoard.so:${LD_PRELOAD}
 539 #endif
 540
 541 # Third party packages
 542
 543 # cmake
 544 # ~~~~~
 545 if ( $?CMAKE_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_CMAKE_322 != 0 && -e "$WM_THIRD_PARTY_DIR"/packages/cmake-3.2.2/platforms/$WM_OPTIONS ) then
 546     _foamSource $WM_THIRD_PARTY_DIR/packages/cmake-3.2.2/platforms/$WM_OPTIONS/etc/cmake-3.2.2.csh
 547 endif
 548
 549 if ( $?CMAKE_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_CMAKE_2812 != 0 && -e "$WM_THIRD_PARTY_DIR"/packages/cmake-2.8.12/platforms/$WM_OPTIONS ) then
 550     _foamSource $WM_THIRD_PARTY_DIR/packages/cmake-2.8.12/platforms/$WM_OPTIONS/etc/cmake-2.8.12.csh
 551 endif
 552
 553 # m4
 554 # ~~~~~
 555 if ( $?M4_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_M4_1416 != 0 && -e "$WM_THIRD_PARTY_DIR"/packages/m4-1.4.16/platforms/$WM_OPTIONS ) then
 556     _foamSource $WM_THIRD_PARTY_DIR/packages/m4-1.4.16/platforms/$WM_OPTIONS/etc/m4-1.4.16.csh
 557 endif
 558
 559 # bison
 560 # ~~~~~
 561 if ( $?BISON_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_BISON_27 != 0 && -e "$WM_THIRD_PARTY_DIR"/packages/bison-2.7/platforms/$WM_OPTIONS ) then
 562     _foamSource $WM_THIRD_PARTY_DIR/packages/bison-2.7/platforms/$WM_OPTIONS/etc/bison-2.7.csh
 563 endif
 564
 565 # flex
 566 # ~~~~~
 567 if ( $?FLEX_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_FLEX_2535 != 0 && -e "$WM_THIRD_PARTY_DIR"/packages/flex-2.5.35/platforms/$WM_OPTIONS ) then
 568     _foamSource $WM_THIRD_PARTY_DIR/packages/flex-2.5.35/platforms/$WM_OPTIONS/etc/flex-2.5.35.csh
 569 endif
 570
 571 # zoltan
 572 # ~~~~~
 573 if ( $?ZOLTAN_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_ZOLTAN_35 != 0 && -e "$WM_THIRD_PARTY_DIR"/packages/zoltan-3.5/platforms/$WM_OPTIONS ) then
 574     _foamSource $WM_THIRD_PARTY_DIR/packages/zoltan-3.5/platforms/$WM_OPTIONS/etc/zoltan-3.5.csh
 575 endif
 576
 577 # Python
 578 # ~~~~~
 579 if ( $?PYTHON_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_PYTHON_27 != 0 && -e "$WM_THIRD_PARTY_DIR"/packages/Python-2.7/platforms/$WM_OPTIONS ) then
 580     _foamSource $WM_THIRD_PARTY_DIR/packages/Python-2.7/platforms/$WM_OPTIONS/etc/Python-2.7.csh
 581 endif
 582
 583 # PyFoam
 584 # ~~~~~~
 585 if ( $?PYFOAM_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_PYFOAM_063 != 0 && -e "$WM_THIRD_PARTY_DIR"/packages/PyFoam-0.6.3/platforms/noarch ) then
 586     _foamSource $WM_THIRD_PARTY_DIR/packages/PyFoam-0.6.3/platforms/noarch/etc/PyFoam-0.6.3.csh
 587 endif
 588 if ( $?PYFOAM_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_PYFOAM_063 != 0 && -e "$WM_THIRD_PARTY_DIR"/packages/PyFoam-0.6.4/platforms/noarch ) then
 589     _foamSource $WM_THIRD_PARTY_DIR/packages/PyFoam-0.6.4/platforms/noarch/etc/PyFoam-0.6.4.csh
 590 endif
 591
 592 # hwloc
 593 # ~~~~~
 594 if ( $?HWLOC_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_HWLOC_172 != 0 && -e "$WM_THIRD_PARTY_DIR"/packages/hwloc-1.7.2/platforms/$WM_OPTIONS ) then
 595     _foamSource $WM_THIRD_PARTY_DIR/packages/hwloc-1.7.2/platforms/$WM_OPTIONS/etc/hwloc-1.7.2.csh
 596 endif
 597 if ( $?HWLOC_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_HWLOC_1101 != 0 && -e "$WM_THIRD_PARTY_DIR"/packages/hwloc-1.10.1/platforms/$WM_OPTIONS ) then
 598     _foamSource $WM_THIRD_PARTY_DIR/packages/hwloc-1.10.1/platforms/$WM_OPTIONS/etc/hwloc-1.10.1.csh
 599 endif
 600
 601 # QT
 602 # ~~~~~
 603 if ( $?QT_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_QT_486 != 0 && -e "$WM_THIRD_PARTY_DIR"/packages/qt-everywhere-opensource-src-4.8.5/platforms/$WM_OPTIONS )then
 604     _foamSource $WM_THIRD_PARTY_DIR/packages/qt-everywhere-opensource-src-4.8.5/platforms/$WM_OPTIONS/etc/qt-everywhere-opensource-src-4.8.5.csh
 605 endif
 606
 607 # PARAVIEW
 608 # ~~~~~
 609 if ( $?PARAVIEW_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_PARAVIEW_431 != 0 && -e "$WM_THIRD_PARTY_DIR"/packages/ParaView-4.3.1/platforms/$WM_OPTIONS ) then
 610     _foamSource $WM_THIRD_PARTY_DIR/packages/ParaView-4.3.1/platforms/$WM_OPTIONS/etc/ParaView-4.3.1.csh
 611 endif
 612 if ( $?PARAVIEW_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_PARAVIEW_410 != 0 && -e "$WM_THIRD_PARTY_DIR"/packages/ParaView-4.1.0/platforms/$WM_OPTIONS ) then
 613     _foamSource $WM_THIRD_PARTY_DIR/packages/ParaView-4.1.0/platforms/$WM_OPTIONS/etc/ParaView-4.1.0.csh
 614 endif
 615 if ( $?PARAVIEW_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_PARAVIEW_401 != 0 && -e "$WM_THIRD_PARTY_DIR"/packages/ParaView-4.0.1/platforms/$WM_OPTIONS ) then
 616     _foamSource $WM_THIRD_PARTY_DIR/packages/ParaView-4.0.1/platforms/$WM_OPTIONS/etc/ParaView-4.0.1.csh
 617 endif
 618
 619 if ( $?PARAVIEW_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_PARAVIEW_3141 != 0 && -e "$WM_THIRD_PARTY_DIR"/packages/ParaView-3.14.1/platforms/$WM_OPTIONS ) then
 620    _foamSource $WM_THIRD_PARTY_DIR/packages/ParaView-3.14.1/platforms/$WM_OPTIONS/etc/ParaView-3.14.1.csh
 621 endif
 622
 623 if ( $?PARAVIEW_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_PARAVIEW_381 != 0 && -e "$WM_THIRD_PARTY_DIR"/packages/ParaView-3.8.1/platforms/$WM_OPTIONS ) then
 624     _foamSource $WM_THIRD_PARTY_DIR/packages/ParaView-3.8.1/platforms/$WM_OPTIONS/etc/ParaView-3.8.1.csh
 625 endif
 626
 627 # llvm
 628 # ~~~~~
 629 if ( $?LLVM_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_LLVM_360 != 0 && -e "$WM_THIRD_PARTY_DIR"/packages/llvm-3.6.0/platforms/$WM_OPTIONS ) then
 630     _foamSource $WM_THIRD_PARTY_DIR/packages/llvm-3.6.0/platforms/$WM_OPTIONS/etc/llvm-3.6.0.csh
 631 endif
 632
 633 # mesa
 634 # ~~~~~
 635 if ( $?MESA_SYSTEM == 0 && $?WM_THIRD_PARTY_USE_MESA_GIT != 0 && -e "$WM_THIRD_PARTY_DIR"/packages/mesa-git/platforms/$WM_OPTIONS ) then
 636     _foamSource $WM_THIRD_PARTY_DIR/packages/mesa-git/platforms/$WM_OPTIONS/etc/mesa-git.csh
 637 endif
 638
 639
 640 if ( $WM_ARCH == "darwinIntel" || $WM_ARCH == "darwinIntel64" ) then
 641     setenv DYLD_LIBRARY_PATH ${LD_LIBRARY_PATH}
 642 endif
 643
 644 # cleanup environment:
 645 # ~~~~~~~~~~~~~~~~~~~~
 646 unalias _foamAddPath
 647 unalias _foamAddLib
 648 unset minBufferSize
 649
 650 # -----------------------------------------------------------------------------