bin/tools/doxyFilt.awk

   1 # -----------------------------------------------------------------------------
   2 # =========                 |
   3 # \\      /  F ield         | foam-extend: Open Source CFD
   4 #  \\    /   O peration     |
   5 #   \\  /    A nd           | For copyright notice see file Copyright
   6 #    \\/     M anipulation  |
   7 # -----------------------------------------------------------------------------
   8 # License
   9 #     This file is part of foam-extend.
  10 #
  11 #     foam-extend is free software: you can redistribute it and/or modify it
  12 #     under the terms of the GNU General Public License as published by the
  13 #     Free Software Foundation, either version 3 of the License, or (at your
  14 #     option) any later version.
  15 #
  16 #     foam-extend is distributed in the hope that it will be useful, but
  17 #     WITHOUT ANY WARRANTY; without even the implied warranty of
  18 #     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 #     General Public License for more details.
  20 #
  21 #     You should have received a copy of the GNU General Public License
  22 #     along with foam-extend.  If not, see <http://www.gnu.org/licenses/>.
  23 #
  24 # Script
  25 #     doxyFilt.awk
  26 #
  27 # Description
  28 #     Converts cocoon style sentinel strings into doxygen style strings
  29 #
  30 #     Assumes comment strings are formatted as follows
  31 #         //- general description
  32 #         //  more information
  33 #         //  and even more information
  34 #     This should be re-formatted as the following
  35 #         //! general description
  36 #         /*!
  37 #         more information
  38 #         and even more information
  39 #         */
  40 #     The intermediate "/*! ... */" block is left-justified to handle
  41 #     possible verbatim text
  42 # -----------------------------------------------------------------------------
  43
  44 BEGIN {
  45     state = 0
  46 }
  47
  48 /^ *\/\/-/ {
  49     state = 1
  50     sub(/\/\/-/, "//!")
  51     print
  52     next
  53 }
  54
  55
  56 /^ *\/\// {
  57     # start comment block
  58     if (state == 1)
  59     {
  60         printf "/*!\n"
  61         state = 2
  62     }
  63
  64     # inside comment block
  65     if (state == 2)
  66     {
  67         if (!sub(/^ *\/\/  /, ""))
  68         {
  69             sub(/^ *\/\//, "")
  70         }
  71     }
  72
  73     print
  74     next
  75 }
  76
  77
  78 {
  79     # end comment block
  80     if (state == 2)
  81     {
  82         printf "*/\n"
  83     }
  84     state = 0
  85     print
  86     next
  87 }
  88
  89 # -----------------------------------------------------------------------------