usr.bin/m4/parser.y

   1 %{
   2 /* $OpenBSD: parser.y,v 1.7 2012/04/12 17:00:11 espie Exp $ */
   3 /*
   4  * Copyright (c) 2004 Marc Espie <espie@cvs.openbsd.org>
   5  *
   6  * Permission to use, copy, modify, and distribute this software for any
   7  * purpose with or without fee is hereby granted, provided that the above
   8  * copyright notice and this permission notice appear in all copies.
   9  *
  10  * THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  11  * WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  12  * MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  13  * ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  14  * WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  15  * ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  16  * OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  17  *
  18  * $FreeBSD$
  19  */
  20
  21 #include <math.h>
  22 #include <stdint.h>
  23 #define YYSTYPE int32_t
  24 extern int32_t end_result;
  25 extern int yylex(void);
  26 extern int yyerror(const char *);
  27 %}
  28 %token NUMBER
  29 %token ERROR
  30 %left LOR
  31 %left LAND
  32 %left '|'
  33 %left '^'
  34 %left '&'
  35 %left EQ NE
  36 %left '<' LE '>' GE
  37 %left LSHIFT RSHIFT
  38 %left '+' '-'
  39 %left '*' '/' '%'
  40 %right EXPONENT
  41 %right UMINUS UPLUS '!' '~'
  42
  43 %%
  44
  45 top     : expr { end_result = $1; }
  46         ;
  47 expr    : expr '+' expr { $$ = $1 + $3; }
  48         | expr '-' expr { $$ = $1 - $3; }
  49         | expr EXPONENT expr { $$ = pow($1, $3); }
  50         | expr '*' expr { $$ = $1 * $3; }
  51         | expr '/' expr {
  52                 if ($3 == 0) {
  53                         yyerror("division by zero");
  54                         exit(1);
  55                 }
  56                 $$ = $1 / $3;
  57         }
  58         | expr '%' expr {
  59                 if ($3 == 0) {
  60                         yyerror("modulo zero");
  61                         exit(1);
  62                 }
  63                 $$ = $1 % $3;
  64         }
  65         | expr LSHIFT expr { $$ = $1 << $3; }
  66         | expr RSHIFT expr { $$ = $1 >> $3; }
  67         | expr '<' expr { $$ = $1 < $3; }
  68         | expr '>' expr { $$ = $1 > $3; }
  69         | expr LE expr { $$ = $1 <= $3; }
  70         | expr GE expr { $$ = $1 >= $3; }
  71         | expr EQ expr { $$ = $1 == $3; }
  72         | expr NE expr { $$ = $1 != $3; }
  73         | expr '&' expr { $$ = $1 & $3; }
  74         | expr '^' expr { $$ = $1 ^ $3; }
  75         | expr '|' expr { $$ = $1 | $3; }
  76         | expr LAND expr { $$ = $1 && $3; }
  77         | expr LOR expr { $$ = $1 || $3; }
  78         | '(' expr ')' { $$ = $2; }
  79         | '-' expr %prec UMINUS { $$ = -$2; }
  80         | '+' expr %prec UPLUS  { $$ = $2; }
  81         | '!' expr { $$ = !$2; }
  82         | '~' expr { $$ = ~$2; }
  83         | NUMBER
  84         ;
  85 %%
  86