libexec/rtld-elf/arm/rtld_start.S

   1 /*      $NetBSD: rtld_start.S,v 1.7 2002/09/12 17:18:38 mycroft Exp $   */
   2
   3 /*-
   4  * Copyright (c) 1998, 2002 The NetBSD Foundation, Inc.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to The NetBSD Foundation
   8  * by Matt Thomas and by Charles M. Hannum.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. All advertising materials mentioning features or use of this software
  19  *    must display the following acknowledgement:
  20  *        This product includes software developed by the NetBSD
  21  *        Foundation, Inc. and its contributors.
  22  * 4. Neither the name of The NetBSD Foundation nor the names of its
  23  *    contributors may be used to endorse or promote products derived
  24  *    from this software without specific prior written permission.
  25  *
  26  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  27  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  28  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  29  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  30  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  31  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  32  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  33  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  34  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  35  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  36  * POSSIBILITY OF SUCH DAMAGE.
  37  */
  38
  39 #include <machine/asm.h>
  40 __FBSDID("$FreeBSD$");
  41
  42         .text
  43         .align  0
  44         .globl  .rtld_start
  45         .type   .rtld_start,%function
  46 .rtld_start:
  47         sub     sp, sp, #8              /* make room for obj_main & exit proc */
  48         mov     r4, r0                  /* save ps_strings */
  49         ldr     sl, .L2
  50         ldr     r5, .L2+4
  51         ldr     r0, .L2+8
  52 .L1:
  53         add     sl, pc, sl
  54         ldr     r5, [sl, r5]
  55         ldr     r0, [sl, r0]
  56
  57         sub     r1, sl, r5              /* relocbase */
  58         add     r0, r1, r0              /* &_DYNAMIC */
  59         bl      _rtld_relocate_nonplt_self
  60         mov     r1, sp
  61         add     r2, sp, #4
  62         add     r0, sp, #8
  63         bl      _rtld                   /* call the shared loader */
  64         mov     r3, r0                  /* save entry point */
  65
  66         ldr     r2, [sp, #0]            /* r2 = cleanup */
  67         ldr     r1, [sp, #4]            /* r1 = obj_main */
  68         add     sp, sp, #8              /* restore stack */
  69         mov     r0, r4                  /* restore ps_strings */
  70         mov     pc, r3                  /* jump to the entry point */
  71 .L2:
  72         .word   _GLOBAL_OFFSET_TABLE_ - (.L1+8)
  73         .word   _GLOBAL_OFFSET_TABLE_(GOT)
  74         .word   _DYNAMIC(GOT)
  75
  76         .align  0
  77         .globl  _rtld_bind_start
  78         .type   _rtld_bind_start,%function
  79 /*
  80  *      stack[0] = RA
  81  *      ip = &GOT[n+3]
  82  *      lr = &GOT[2]
  83  */
  84 _rtld_bind_start:
  85         stmdb   sp!,{r0-r4,sl,fp}
  86
  87         sub     r1, ip, lr              /* r1 = 4 * (n + 1) */
  88         sub     r1, r1, #4              /* r1 = 4 * n */
  89         add     r1, r1, r1              /* r1 = 8 * n */
  90
  91         ldr     r0, [lr, #-4]           /* get obj ptr from GOT[1] */
  92         mov     r4, ip                  /* save GOT location */
  93
  94         bl      _rtld_bind              /* Call the binder */
  95
  96         str     r0, [r4]                /* save address in GOT */
  97         mov     ip, r0                  /* save new address */
  98
  99         ldmia   sp!,{r0-r4,sl,fp,lr}    /* restore the stack */
 100         mov     pc, ip                  /* jump to the new address */
 101