m4/web-client.m4

   1 # Configure checks for freeciv-web
   2
   3 AC_DEFUN([FC_WEB_CLIENT],
   4 [
   5   AM_CONDITIONAL([FREECIV_WEB], [test "x$fcweb" = "xtrue"])
   6
   7   if test "x$fcweb" = "xtrue" ; then
   8     AC_DEFINE([FREECIV_WEB], [1], [Build freeciv-web version instead of regular freeciv])
   9   fi
  10 ])
  11
  12 AC_DEFUN([FC_WEB_OPTIONS],
  13 [
  14 AC_ARG_ENABLE([json],
  15   AS_HELP_STRING([--enable-json], [enable json network protocol]),
  16 [case "${enableval}" in
  17   yes|no) json_enabled=${enableval} ;;
  18   *) AC_MSG_ERROR([bad value ${enableval} for --enable-json]) ;;
  19 esac], [json_enabled=no])
  20
  21 JANSSON_CFLAGS=""
  22 JANSSON_LIBS=""
  23
  24 if test "x$json_enabled" = "xyes" ; then
  25   PKG_CHECK_MODULES([JANSSON], [jansson], [], [
  26     AC_CHECK_LIB([jansson], [json_object_set_new],
  27 [JANSSON_LIBS="-ljansson"],
  28 [AC_MSG_ERROR([cannot find libjansson])])
  29     AC_CHECK_HEADER([jansson.h], [],
  30 [AC_MSG_ERROR([libjansson found but not jansson.h])])])
  31
  32   AC_DEFINE([FREECIV_JSON_CONNECTION], [1], [jansson network protocol in use])
  33
  34   COMMON_LIBS="${COMMON_LIBS} ${JANSSON_LIBS}"
  35 fi
  36 ])