m4/sdl.m4

   1 # Configure paths for SDL
   2 # Sam Lantinga 9/21/99
   3 # stolen from Manish Singh
   4 # stolen back from Frank Belew
   5 # stolen from Manish Singh
   6 # Shamelessly stolen from Owen Taylor
   7 # Taken to Freeciv from SDL release 1.2.12
   8
   9 dnl AM_PATH_SDL([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
  10 dnl Test for SDL, and define SDL_CFLAGS and SDL_LIBS
  11 dnl
  12 AC_DEFUN([AM_PATH_SDL],
  13 [dnl
  14 dnl Get the cflags and libraries from the sdl-config script
  15 dnl
  16 AC_ARG_WITH(sdl-prefix,[  --with-sdl-prefix=PFX   Prefix where SDL is installed (optional)],
  17             sdl_prefix="$withval", sdl_prefix="")
  18 AC_ARG_WITH(sdl-exec-prefix,[  --with-sdl-exec-prefix=PFX Exec prefix where SDL is installed (optional)],
  19             sdl_exec_prefix="$withval", sdl_exec_prefix="")
  20 AC_ARG_ENABLE(sdltest, [  --disable-sdltest       Do not try to compile and run a test SDL program],
  21                     , enable_sdltest=yes)
  22
  23   if test x$sdl_exec_prefix != x ; then
  24     sdl_args="$sdl_args --exec-prefix=$sdl_exec_prefix"
  25     if test x${SDL_CONFIG+set} != xset ; then
  26       SDL_CONFIG=$sdl_exec_prefix/bin/sdl-config
  27     fi
  28   fi
  29   if test x$sdl_prefix != x ; then
  30     sdl_args="$sdl_args --prefix=$sdl_prefix"
  31     if test x${SDL_CONFIG+set} != xset ; then
  32       SDL_CONFIG=$sdl_prefix/bin/sdl-config
  33     fi
  34   fi
  35
  36   if test "x$prefix" != xNONE; then
  37     PATH="$prefix/bin:$prefix/usr/bin:$PATH"
  38   fi
  39   AC_PATH_PROG(SDL_CONFIG, sdl-config, no, [$PATH])
  40   min_sdl_version=ifelse([$1], ,0.11.0,$1)
  41   AC_MSG_CHECKING(for SDL - version >= $min_sdl_version)
  42   no_sdl=""
  43   if test "$SDL_CONFIG" = "no" ; then
  44     no_sdl=yes
  45   else
  46     SDL_CFLAGS=`$SDL_CONFIG $sdlconf_args --cflags`
  47     SDL_LIBS=`$SDL_CONFIG $sdlconf_args --libs`
  48
  49     sdl_major_version=`$SDL_CONFIG $sdl_args --version | \
  50            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
  51     sdl_minor_version=`$SDL_CONFIG $sdl_args --version | \
  52            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
  53     sdl_micro_version=`$SDL_CONFIG $sdl_config_args --version | \
  54            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
  55     if test "x$enable_sdltest" = "xyes" ; then
  56       ac_save_CFLAGS="$CFLAGS"
  57       ac_save_CXXFLAGS="$CXXFLAGS"
  58       ac_save_LIBS="$LIBS"
  59       CFLAGS="$CFLAGS $SDL_CFLAGS"
  60       CXXFLAGS="$CXXFLAGS $SDL_CFLAGS"
  61       LIBS="$LIBS $SDL_LIBS"
  62 dnl
  63 dnl Now check if the installed SDL is sufficiently new. (Also sanity
  64 dnl checks the results of sdl-config to some extent
  65 dnl
  66       rm -f conf.sdltest
  67       AC_RUN_IFELSE([AC_LANG_SOURCE([[
  68 #include <stdio.h>
  69 #include <stdlib.h>
  70 #include <string.h>
  71 #include "SDL.h"
  72
  73 char*
  74 my_strdup (char *str)
  75 {
  76   char *new_str;
  77
  78   if (str)
  79     {
  80       new_str = (char *)malloc ((strlen (str) + 1) * sizeof(char));
  81       strcpy (new_str, str);
  82     }
  83   else
  84     new_str = NULL;
  85
  86   return new_str;
  87 }
  88
  89 int main (int argc, char *argv[])
  90 {
  91   int major, minor, micro;
  92   char *tmp_version;
  93
  94   /* This hangs on some systems (?)
  95   system ("touch conf.sdltest");
  96   */
  97   { FILE *fp = fopen("conf.sdltest", "a"); if ( fp ) fclose(fp); }
  98
  99   /* HP/UX 9 (%@#!) writes to sscanf strings */
 100   tmp_version = my_strdup("$min_sdl_version");
 101   if (sscanf(tmp_version, "%d.%d.%d", &major, &minor, &micro) != 3) {
 102      printf("%s, bad version string\n", "$min_sdl_version");
 103      exit(1);
 104    }
 105
 106    if (($sdl_major_version > major) ||
 107       (($sdl_major_version == major) && ($sdl_minor_version > minor)) ||
 108       (($sdl_major_version == major) && ($sdl_minor_version == minor) && ($sdl_micro_version >= micro)))
 109     {
 110       return 0;
 111     }
 112   else
 113     {
 114       printf("\n*** 'sdl-config --version' returned %d.%d.%d, but the minimum version\n", $sdl_major_version, $sdl_minor_version, $sdl_micro_version);
 115       printf("*** of SDL required is %d.%d.%d. If sdl-config is correct, then it is\n", major, minor, micro);
 116       printf("*** best to upgrade to the required version.\n");
 117       printf("*** If sdl-config was wrong, set the environment variable SDL_CONFIG\n");
 118       printf("*** to point to the correct copy of sdl-config, and remove the file\n");
 119       printf("*** config.cache before re-running configure\n");
 120       return 1;
 121     }
 122 }
 123
 124 ]])],[],[no_sdl=yes],[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 125        CFLAGS="$ac_save_CFLAGS"
 126        CXXFLAGS="$ac_save_CXXFLAGS"
 127        LIBS="$ac_save_LIBS"
 128      fi
 129   fi
 130   if test "x$no_sdl" = x ; then
 131      AC_MSG_RESULT(yes)
 132      ifelse([$2], , :, [$2])
 133   else
 134      AC_MSG_RESULT(no)
 135      if test "$SDL_CONFIG" = "no" ; then
 136        echo "*** The sdl-config script installed by SDL could not be found"
 137        echo "*** If SDL was installed in PREFIX, make sure PREFIX/bin is in"
 138        echo "*** your path, or set the SDL_CONFIG environment variable to the"
 139        echo "*** full path to sdl-config."
 140      else
 141        if test -f conf.sdltest ; then
 142         :
 143        else
 144           echo "*** Could not run SDL test program, checking why..."
 145           CFLAGS="$CFLAGS $SDL_CFLAGS"
 146           CXXFLAGS="$CXXFLAGS $SDL_CFLAGS"
 147           LIBS="$LIBS $SDL_LIBS"
 148           AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 149 #include <stdio.h>
 150 #include "SDL.h"
 151
 152 int main(int argc, char *argv[])
 153 { return 0; }
 154 #undef  main
 155 #define main K_and_R_C_main
 156 ]], [[ return 0; ]])],[ echo "*** The test program compiled, but did not run. This usually means"
 157           echo "*** that the run-time linker is not finding SDL or finding the wrong"
 158           echo "*** version of SDL. If it is not finding SDL, you'll need to set your"
 159           echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
 160           echo "*** to the installed location  Also, make sure you have run ldconfig if that"
 161           echo "*** is required on your system"
 162           echo "***"
 163           echo "*** If you have an old version installed, it is best to remove it, although"
 164           echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH"],[ echo "*** The test program failed to compile or link. See the file config.log for the"
 165           echo "*** exact error that occured. This usually means SDL was incorrectly installed"
 166           echo "*** or that you have moved SDL since it was installed. In the latter case, you"
 167           echo "*** may want to edit the sdl-config script: $SDL_CONFIG" ])
 168           CFLAGS="$ac_save_CFLAGS"
 169           CXXFLAGS="$ac_save_CXXFLAGS"
 170           LIBS="$ac_save_LIBS"
 171        fi
 172      fi
 173      SDL_CFLAGS=""
 174      SDL_LIBS=""
 175      ifelse([$3], , :, [$3])
 176   fi
 177   AC_SUBST(SDL_CFLAGS)
 178   AC_SUBST(SDL_LIBS)
 179   rm -f conf.sdltest
 180 ])