configure.in

   1 AC_INIT(fuse, 2.9.0-pre0)
   2 AC_CONFIG_MACRO_DIR([m4])
   3 AC_CANONICAL_TARGET
   4 AM_INIT_AUTOMAKE
   5 AM_CONFIG_HEADER(include/config.h)
   6
   7 AC_PROG_LIBTOOL
   8 AC_PROG_CC
   9 AM_PROG_CC_C_O
  10
  11 # compatibility for automake < 1.8
  12 if test -z "$mkdir_p"; then
  13         mkdir_p="../mkinstalldirs"
  14         AC_SUBST(mkdir_p)
  15 fi
  16
  17 case $target_os in
  18      *linux*)   arch=linux;;
  19      *netbsd*)  arch=netbsd;;
  20      *bsd*)     arch=bsd;;
  21      *)         arch=unknown;;
  22 esac
  23
  24 if test "$ac_env_CFLAGS_set" != set; then
  25         CFLAGS="-Wall -W -Wno-sign-compare -Wstrict-prototypes -Wmissing-declarations -Wwrite-strings -g -O2 -fno-strict-aliasing"
  26 fi
  27
  28 AC_ARG_ENABLE(lib,
  29         [  --enable-lib            Compile with library ])
  30 AC_ARG_ENABLE(util,
  31         [  --enable-util           Compile with util ])
  32 AC_ARG_ENABLE(example,
  33         [  --enable-example        Compile with examples ])
  34 AC_ARG_ENABLE(mtab,
  35         [  --disable-mtab          Disable and ignore usage of /etc/mtab ])
  36 AC_ARG_ENABLE(legacy-umount,
  37         [  --disable-legacy-umount If umount(8) is util-linux-ng >= 2.18 ])
  38
  39 AC_ARG_WITH(pkgconfigdir,
  40             [  --with-pkgconfigdir=DIR      pkgconfig file in DIR @<:@LIBDIR/pkgconfig@:>@],
  41             [pkgconfigdir=$withval],
  42             [pkgconfigdir='${libdir}/pkgconfig'])
  43 AC_SUBST(pkgconfigdir)
  44
  45 subdirs2="include"
  46
  47 if test "$enable_lib" != "no"; then
  48         subdirs2="$subdirs2 lib";
  49 fi
  50 if test "$arch" = linux -a "$enable_util" != "no"; then
  51         subdirs2="$subdirs2 util";
  52 fi
  53 if test "$enable_example" != "no"; then
  54         subdirs2="$subdirs2 example";
  55 fi
  56 if test "$enable_mtab" = "no"; then
  57         AC_DEFINE(IGNORE_MTAB, 1, [Don't update /etc/mtab])
  58 fi
  59
  60 if test "$enable_legacy_umount" != "no"; then
  61         AC_DEFINE(LEGACY_UMOUNT, 1, [Enable legacy umount support])
  62 fi
  63
  64 AC_CHECK_FUNCS([fork setxattr fdatasync])
  65 AC_CHECK_MEMBERS([struct stat.st_atim])
  66 AC_CHECK_MEMBERS([struct stat.st_atimespec])
  67
  68 libfuse_libs="-pthread"
  69 LIBS=
  70 AC_SEARCH_LIBS(dlopen, [dl])
  71 AC_SEARCH_LIBS(clock_gettime, [rt])
  72 libfuse_libs="$libfuse_libs $LIBS"
  73 LIBS=
  74 AC_ARG_WITH([libiconv-prefix],
  75 [  --with-libiconv-prefix=DIR  search for libiconv in DIR/include and DIR/lib], [
  76     for dir in `echo "$withval" | tr : ' '`; do
  77       if test -d $dir/include; then CPPFLAGS="$CPPFLAGS -I$dir/include"; fi
  78       if test -d $dir/lib; then LDFLAGS="$LDFLAGS -L$dir/lib"; fi
  79     done
  80    ])
  81 AM_ICONV
  82 libfuse_libs="$libfuse_libs $LTLIBICONV"
  83 AM_CONDITIONAL(ICONV, test "$am_cv_func_iconv" = yes)
  84 AC_SUBST(libfuse_libs)
  85
  86 if test -z "$MOUNT_FUSE_PATH"; then
  87         MOUNT_FUSE_PATH=/sbin
  88 fi
  89 AC_SUBST(MOUNT_FUSE_PATH)
  90 if test -z "$UDEV_RULES_PATH"; then
  91         UDEV_RULES_PATH=/etc/udev/rules.d
  92 fi
  93 AC_SUBST(UDEV_RULES_PATH)
  94 if test -z "$INIT_D_PATH"; then
  95         INIT_D_PATH=/etc/init.d
  96 fi
  97 AC_SUBST(INIT_D_PATH)
  98
  99 AC_SUBST(subdirs2)
 100
 101 AM_CONDITIONAL(LINUX, test "$arch" = linux)
 102 AM_CONDITIONAL(NETBSD, test "$arch" = netbsd)
 103 AM_CONDITIONAL(BSD, test "$arch" = bsd)
 104
 105 AC_CONFIG_FILES([fuse.pc Makefile lib/Makefile util/Makefile example/Makefile include/Makefile])
 106 AC_OUTPUT