configure.in

   1 AC_INIT(fuse, 2.9.2)
   2
   3 AC_PREREQ(2.59d)
   4 AC_CONFIG_MACRO_DIR([m4])
   5 AC_CANONICAL_TARGET
   6 AM_INIT_AUTOMAKE
   7 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES(yes)])
   8 AM_CONFIG_HEADER(include/config.h)
   9
  10 AC_PROG_LIBTOOL
  11 AC_PROG_CC
  12 AC_PROG_MKDIR_P
  13 AM_PROG_CC_C_O
  14
  15 case $target_os in
  16      *linux*)   arch=linux;;
  17      *netbsd*)  arch=netbsd;;
  18      *bsd*)     arch=bsd;;
  19      *)         arch=unknown;;
  20 esac
  21
  22 if test "$ac_env_CFLAGS_set" != set; then
  23         CFLAGS="-Wall -W -Wno-sign-compare -Wstrict-prototypes -Wmissing-declarations -Wwrite-strings -g -O2 -fno-strict-aliasing"
  24 fi
  25
  26 AC_ARG_ENABLE(lib,
  27         [  --enable-lib            Compile with library ])
  28 AC_ARG_ENABLE(util,
  29         [  --enable-util           Compile with util ])
  30 AC_ARG_ENABLE(example,
  31         [  --enable-example        Compile with examples ])
  32 AC_ARG_ENABLE(mtab,
  33         [  --disable-mtab          Disable and ignore usage of /etc/mtab ])
  34
  35 AC_ARG_WITH(pkgconfigdir,
  36             [  --with-pkgconfigdir=DIR      pkgconfig file in DIR @<:@LIBDIR/pkgconfig@:>@],
  37             [pkgconfigdir=$withval],
  38             [pkgconfigdir='${libdir}/pkgconfig'])
  39 AC_SUBST(pkgconfigdir)
  40
  41 subdirs2="include"
  42
  43 if test "$enable_lib" != "no"; then
  44         subdirs2="$subdirs2 lib";
  45 fi
  46 if test "$arch" = linux -a "$enable_util" != "no"; then
  47         subdirs2="$subdirs2 util";
  48 fi
  49 if test "$enable_example" != "no"; then
  50         subdirs2="$subdirs2 example";
  51 fi
  52 if test "$enable_mtab" = "no"; then
  53         AC_DEFINE(IGNORE_MTAB, 1, [Don't update /etc/mtab])
  54 fi
  55
  56 AC_CHECK_FUNCS([fork setxattr fdatasync splice vmsplice utimensat])
  57 AC_CHECK_FUNCS([posix_fallocate])
  58 AC_CHECK_MEMBERS([struct stat.st_atim])
  59 AC_CHECK_MEMBERS([struct stat.st_atimespec])
  60
  61 LIBS=
  62 AC_SEARCH_LIBS(dlopen, [dl])
  63 AC_SEARCH_LIBS(clock_gettime, [rt])
  64 libfuse_libs=$LIBS
  65 LIBS=
  66 AC_ARG_WITH([libiconv-prefix],
  67 [  --with-libiconv-prefix=DIR  search for libiconv in DIR/include and DIR/lib], [
  68     for dir in `echo "$withval" | tr : ' '`; do
  69       if test -d $dir/include; then CPPFLAGS="$CPPFLAGS -I$dir/include"; fi
  70       if test -d $dir/lib; then LDFLAGS="$LDFLAGS -L$dir/lib"; fi
  71     done
  72    ])
  73 AM_ICONV
  74 libfuse_libs="$libfuse_libs $LTLIBICONV"
  75 AM_CONDITIONAL(ICONV, test "$am_cv_func_iconv" = yes)
  76 AC_SUBST(libfuse_libs)
  77
  78 if test -z "$MOUNT_FUSE_PATH"; then
  79         MOUNT_FUSE_PATH=/sbin
  80 fi
  81 AC_SUBST(MOUNT_FUSE_PATH)
  82 if test -z "$UDEV_RULES_PATH"; then
  83         UDEV_RULES_PATH=/etc/udev/rules.d
  84 fi
  85 AC_SUBST(UDEV_RULES_PATH)
  86 if test -z "$INIT_D_PATH"; then
  87         INIT_D_PATH=/etc/init.d
  88 fi
  89 AC_SUBST(INIT_D_PATH)
  90
  91 AC_SUBST(subdirs2)
  92
  93 AM_CONDITIONAL(LINUX, test "$arch" = linux)
  94 AM_CONDITIONAL(NETBSD, test "$arch" = netbsd)
  95 AM_CONDITIONAL(BSD, test "$arch" = bsd)
  96
  97 util_linux_ok=yes
  98 if test "$arch" = linux -a "$cross_compiling" != "yes"; then
  99         AC_MSG_CHECKING([if umount supports --fake --no-canonicalize])
 100         # exit code of umount is 1 if option is unrecognised, 2 otherwise
 101         umount --fake --no-canonicalize > /dev/null 2>&1
 102         if test $? != 1; then
 103                 AC_MSG_RESULT([yes])
 104         else
 105                 firstline=`umount --fake --no-canonicalize 2>&1 | head -1`
 106                 if test "$firstline" = 'umount: only root can use "--fake" option'; then
 107                         AC_MSG_RESULT([yes])
 108                 else
 109                         AC_MSG_RESULT([$firstline])
 110                         util_linux_ok=no
 111                 fi
 112         fi
 113 fi
 114
 115 AC_CONFIG_FILES([fuse.pc Makefile lib/Makefile util/Makefile example/Makefile include/Makefile doc/Makefile])
 116 AC_OUTPUT
 117
 118 if test "$util_linux_ok" = no; then
 119         AC_MSG_WARN([
 120 ******************************************************************
 121 * Please install util-linux version 2.18 or later which supports *
 122 * --fake and --no-canonicalize options in mount and umount       *
 123 ******************************************************************])
 124 fi