libcc1/configure.ac

   1 dnl   Copyright (C) 2014-2024 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GCC.
   4 dnl
   5 dnl GCC is free software; you can redistribute it and/or modify it under
   6 dnl the terms of the GNU General Public License as published by the Free
   7 dnl Software Foundation; either version 3, or (at your option) any later
   8 dnl version.
   9 dnl
  10 dnl GCC is distributed in the hope that it will be useful, but WITHOUT ANY
  11 dnl WARRANTY; without even the implied warranty of MERCHANTABILITY or
  12 dnl FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  13 dnl for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GCC; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18
  19 AC_INIT([libcc1], [version-unused])
  20 AC_CONFIG_SRCDIR([libcc1.cc])
  21 AC_CONFIG_HEADER(cc1plugin-config.h)
  22
  23 AC_CANONICAL_SYSTEM
  24 AC_USE_SYSTEM_EXTENSIONS
  25 # Determine the noncanonical target name, for directory use.
  26 ACX_NONCANONICAL_TARGET
  27 GCC_TOPLEV_SUBDIRS
  28
  29 # 1.11.1: Require that version of automake.
  30 # foreign: Don't require README, INSTALL, NEWS, etc.
  31 # no-define: Don't define PACKAGE and VERSION.
  32 # -Wall: Issue all automake warnings.
  33 # -Wno-portability: Don't warn about constructs supported by GNU make.
  34 #    (because GCC requires GNU make anyhow).
  35 AM_INIT_AUTOMAKE([1.11.1 foreign no-dist no-define -Wall -Wno-portability])
  36 AM_MAINTAINER_MODE
  37
  38 LT_INIT([disable-static])
  39 AM_PROG_LIBTOOL
  40 AC_PROG_CXX
  41
  42 visibility=
  43 if test "$GXX" = yes; then
  44   visibility=-fvisibility=hidden
  45 fi
  46 AC_SUBST(visibility)
  47
  48 GCC_CET_HOST_FLAGS(CET_HOST_FLAGS)
  49 AC_SUBST(CET_HOST_FLAGS)
  50
  51 AC_CHECK_DECLS([basename])
  52
  53 GCC_BASE_VER
  54
  55 if test x$with_gcc_major_version_only = xyes ; then
  56   changequote(,)dnl
  57   gcc_version=`sed -e 's/^\([0-9]*\).*$/\1/' $srcdir/../gcc/BASE-VER`
  58   changequote([,])dnl
  59 else
  60   gcc_version=`cat $srcdir/../gcc/BASE-VER`
  61 fi
  62 AC_SUBST(gcc_version)
  63 AC_SUBST([CONFIG_STATUS_DEPENDENCIES], ['$(top_srcdir)/../gcc/BASE-VER'])
  64
  65 ACX_PROG_CC_WARNING_OPTS([-W -Wall], [WARN_FLAGS])
  66 AC_SUBST(WARN_FLAGS)
  67 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual])
  68
  69 AC_ARG_VAR(GMPINC,[How to find GMP include files])
  70
  71 libsuffix=
  72 if test "$GXX" = yes; then
  73   libsuffix=`$CXX -print-multi-os-directory`
  74 fi
  75 AC_SUBST(libsuffix)
  76
  77 dnl Test for -lsocket and -lnsl.  Copied from libgo/configure.ac.
  78 AC_CACHE_CHECK([for socket libraries], libcc1_cv_lib_sockets,
  79   [libcc1_cv_lib_sockets=
  80    libcc1_check_both=no
  81    AC_CHECK_FUNC(connect, libcc1_check_socket=no, libcc1_check_socket=yes)
  82    if test "$libcc1_check_socket" = "yes"; then
  83      unset ac_cv_func_connect
  84      AC_CHECK_LIB(socket, main, libcc1_cv_lib_sockets="-lsocket",
  85                   libcc1_check_both=yes)
  86    fi
  87    if test "$libcc1_check_both" = "yes"; then
  88      libcc1_old_libs=$LIBS
  89      LIBS="$LIBS -lsocket -lnsl"
  90      unset ac_cv_func_accept
  91      AC_CHECK_FUNC(accept,
  92                    [libcc1_check_nsl=no
  93                     libcc1_cv_lib_sockets="-lsocket -lnsl"])
  94      unset ac_cv_func_accept
  95      LIBS=$libcc1_old_libs
  96    fi
  97    unset ac_cv_func_gethostbyname
  98    libcc1_old_libs="$LIBS"
  99    AC_CHECK_FUNC(gethostbyname, ,
 100                  [AC_CHECK_LIB(nsl, main,
 101                         [libcc1_cv_lib_sockets="$libcc1_cv_lib_sockets -lnsl"])])
 102    unset ac_cv_func_gethostbyname
 103    LIBS=$libcc1_old_libs
 104 ])
 105 LIBS="$LIBS $libcc1_cv_lib_sockets"
 106
 107 case "$host" in
 108   *-*-darwin*) darwin_dynamic_lookup=yes ;;
 109   *) darwin_dynamic_lookup=no ;;
 110 esac
 111 AM_CONDITIONAL(DARWIN_DYNAMIC_LOOKUP, test $darwin_dynamic_lookup = yes)
 112
 113 # If any of these functions are missing, simply don't bother building
 114 # this plugin.
 115 GCC_ENABLE_PLUGINS
 116 AC_CHECK_FUNC(socketpair, , enable_plugin=no)
 117 AC_CHECK_FUNC(select, , enable_plugin=no)
 118 AC_CHECK_FUNC(fork, , enable_plugin=no)
 119 AM_CONDITIONAL(ENABLE_PLUGIN, test $enable_plugin = yes)
 120
 121 AC_CONFIG_FILES([Makefile])
 122 AC_OUTPUT