plugins/meson.build

   1 plugin_inc = [include_directories('..', '../src', '../src/tagmanager')]
   2 plugin_inc += iscintilla
   3
   4 plugins = [
   5         'Demoplugin',
   6         'Demoproxy',
   7         'Classbuilder',
   8         'HTMLChars',
   9         'Export',
  10         'SaveActions',
  11         'FileBrowser',
  12         'SplitWindow'
  13 ]
  14
  15 foreach plugin : plugins
  16         id = plugin.to_lower()
  17         skip_install = id.startswith('demo')
  18         shared_module(id,
  19                 id + '.c',
  20                 name_prefix: '', # "lib" seems to be the default prefix
  21                 link_with: libgeany,
  22                 include_directories: plugin_inc,
  23                 c_args: [def_cflags, '-DG_LOG_DOMAIN="'+plugin+'"'],
  24                 dependencies: [deps, dep_libgeany],
  25                 install_dir: join_paths(prefix, get_option('libdir'), 'geany'),
  26                 install: not skip_install
  27         )
  28 endforeach