icons/meson.build

   1 icon_dirs = [ '16x16', '24x24', '32x32', '48x48', 'scalable' ]
   2
   3 # in all resolutions
   4 app_icon = 'geany'
   5
   6 # in all resolutions
   7 action_icons = [
   8         'geany-build',
   9         'geany-close-all',
  10         'geany-save-all'
  11 ]
  12
  13 icons_dir = join_paths(get_option('datadir'), 'icons', 'hicolor')
  14 tango_dir = join_paths(get_option('datadir'), 'icons', 'Tango')
  15
  16 foreach dir : icon_dirs
  17     ext = dir == 'scalable' ? '.svg' : '.png'
  18     install_data(join_paths(dir, app_icon+ext), install_dir: join_paths(icons_dir, dir, 'apps'))
  19     foreach icon : action_icons
  20         install_data(join_paths(dir, icon+ext), install_dir: join_paths(icons_dir, dir, 'actions'))
  21     endforeach
  22     install_data(join_paths('tango', dir, 'geany-save-all'+ext), install_dir: join_paths(tango_dir, dir, 'actions'))
  23 endforeach
  24
  25 # classviewer icons only in 16x16
  26 class_icons = [
  27         'classviewer-class.png',
  28         'classviewer-macro.png',
  29         'classviewer-member.png',
  30         'classviewer-method.png',
  31         'classviewer-namespace.png',
  32         'classviewer-other.png',
  33         'classviewer-struct.png',
  34         'classviewer-var.png'
  35 ]
  36
  37 foreach icon : class_icons
  38     install_data(join_paths('16x16', icon), install_dir: join_paths(icons_dir, '16x16', 'apps'))
  39 endforeach
  40
  41 if meson.version().version_compare('>=0.57.0')
  42     gnome.post_install(gtk_update_icon_cache: true)
  43 else
  44     warning('You may need to run `gtk-update-icon-cache` yourself after installing')
  45     warning('E.g. gtk-update-icon-cache -f -t ' + join_paths(prefix, icons_dir))
  46 endif