modules/freetype2/meson.build

   1 #
   2 # Meson project file for FreeType 2
   3 #
   4
   5 # Copyright (C) 2020-2024 by
   6 # David Turner, Robert Wilhelm, and Werner Lemberg.
   7 #
   8 # This file is part of the FreeType project, and may only be used, modified,
   9 # and distributed under the terms of the FreeType project license,
  10 # LICENSE.TXT.  By continuing to use, modify, or distribute this file you
  11 # indicate that you have read the license and understand and accept it
  12 # fully.
  13
  14 #
  15 # Say
  16 #
  17 #   meson configure
  18 #
  19 # to see all configuration options and their default values.  For example,
  20 # to build only a shared version of FreeType, override the default value
  21 # with
  22 #
  23 #   meson setup -Ddefault_library=shared
  24 #
  25
  26 project('freetype2', 'c',
  27   meson_version: '>= 0.55.0',
  28   version: run_command('builds/meson/extract_freetype_version.py',
  29                        'include/freetype/freetype.h',
  30                        check: true).stdout().strip(),
  31 )
  32
  33
  34 # Only meson >= 0.57 can read a file and assign its contents to a
  35 # variable; we thus use an external command to have this functionality
  36 # with older versions, too.
  37
  38 python_exe = find_program('python3')
  39
  40 ft2_so_version = run_command(python_exe,
  41   files('builds/meson/extract_libtool_version.py'),
  42   '--soversion',
  43   files('builds/unix/configure.raw'),
  44   check: true).stdout().strip()
  45
  46 ft2_pkgconfig_version = run_command(python_exe,
  47   files('builds/meson/extract_libtool_version.py'),
  48   files('builds/unix/configure.raw'),
  49   check: true).stdout().strip()
  50
  51 ft2_includes = include_directories('include')
  52
  53 freetype_includedir = join_paths(get_option('includedir'), 'freetype2')
  54
  55 ft2_defines = []
  56
  57 freetype_aclocaldir = join_paths(get_option('datadir'), 'aclocal')
  58
  59
  60 # Generate a custom `ftmodule.h` version based on the content of
  61 # `modules.cfg`.
  62
  63 ftmodule_h = custom_target('ftmodule.h',
  64   output: 'ftmodule.h',
  65   input: 'modules.cfg',
  66   command: [python_exe, files('builds/meson/parse_modules_cfg.py'),
  67             '--format=ftmodule.h', '@INPUT@', '--output', '@OUTPUT@'],
  68   install: true,
  69   install_dir: join_paths(freetype_includedir, 'freetype/config'),
  70 )
  71 ft2_sources = [ftmodule_h]
  72 ft2_defines += ['-DFT_CONFIG_MODULES_H=<ftmodule.h>']
  73
  74
  75 # FreeType 2 modules.
  76
  77 ft_main_modules = run_command(python_exe,
  78   files('builds/meson/parse_modules_cfg.py'),
  79   '--format=main-modules',
  80   files('modules.cfg'),
  81   check: true).stdout().strip().split()
  82
  83 ft2_sources += files([
  84   'src/base/ftbase.c',
  85   'src/base/ftinit.c',
  86 ])
  87
  88 foreach mod: ft_main_modules
  89   source = mod
  90   if mod == 'winfonts'
  91     source = 'winfnt'
  92   elif mod == 'cid'
  93     source = 'type1cid'
  94   endif
  95   ft2_sources += 'src/@0@/@1@.c'.format(mod, source)
  96 endforeach
  97
  98 # NOTE: The `bzip2` aux module is handled through options.
  99 ft_aux_modules = run_command(python_exe,
 100   files('builds/meson/parse_modules_cfg.py'),
 101   '--format=aux-modules',
 102   files('modules.cfg'),
 103   check: true).stdout().strip().split()
 104
 105 foreach auxmod: ft_aux_modules
 106   source = auxmod
 107   # Most sources are named `src/<module>/<module>.c`, but there are a few
 108   # exceptions handled here.
 109   if auxmod == 'cache'
 110     source = 'ftcache'
 111   elif auxmod == 'lzw'
 112     source = 'ftlzw'
 113   elif auxmod == 'gzip'
 114     source = 'ftgzip'
 115   elif auxmod == 'bzip2'
 116     # Handled through options instead, see below.
 117     continue
 118   endif
 119   ft2_sources += 'src/@0@/@1@.c'.format(auxmod, source)
 120 endforeach
 121
 122
 123 # FreeType 2 base extensions.
 124 # To be configured in `modules.cfg`.
 125
 126 base_extensions = run_command(python_exe,
 127   files('builds/meson/parse_modules_cfg.py'),
 128   '--format=base-extensions-list',
 129   files('modules.cfg'),
 130   check: true).stdout().split()
 131
 132 foreach ext: base_extensions
 133   ft2_sources += files('src/base/' + ext)
 134 endforeach
 135
 136
 137 # Header files.
 138
 139 ft2_public_headers = files([
 140   'include/freetype/freetype.h',
 141   'include/freetype/ftadvanc.h',
 142   'include/freetype/ftbbox.h',
 143   'include/freetype/ftbdf.h',
 144   'include/freetype/ftbitmap.h',
 145   'include/freetype/ftbzip2.h',
 146   'include/freetype/ftcache.h',
 147   'include/freetype/ftchapters.h',
 148   'include/freetype/ftcid.h',
 149   'include/freetype/ftcolor.h',
 150   'include/freetype/ftdriver.h',
 151   'include/freetype/fterrdef.h',
 152   'include/freetype/fterrors.h',
 153   'include/freetype/ftfntfmt.h',
 154   'include/freetype/ftgasp.h',
 155   'include/freetype/ftglyph.h',
 156   'include/freetype/ftgxval.h',
 157   'include/freetype/ftgzip.h',
 158   'include/freetype/ftimage.h',
 159   'include/freetype/ftincrem.h',
 160   'include/freetype/ftlcdfil.h',
 161   'include/freetype/ftlist.h',
 162   'include/freetype/ftlzw.h',
 163   'include/freetype/ftmac.h',
 164   'include/freetype/ftmm.h',
 165   'include/freetype/ftmodapi.h',
 166   'include/freetype/ftmoderr.h',
 167   'include/freetype/ftotval.h',
 168   'include/freetype/ftoutln.h',
 169   'include/freetype/ftparams.h',
 170   'include/freetype/ftpfr.h',
 171   'include/freetype/ftrender.h',
 172   'include/freetype/ftsizes.h',
 173   'include/freetype/ftsnames.h',
 174   'include/freetype/ftstroke.h',
 175   'include/freetype/ftsynth.h',
 176   'include/freetype/ftsystem.h',
 177   'include/freetype/fttrigon.h',
 178   'include/freetype/fttypes.h',
 179   'include/freetype/ftwinfnt.h',
 180   'include/freetype/otsvg.h',
 181   'include/freetype/t1tables.h',
 182   'include/freetype/ttnameid.h',
 183   'include/freetype/tttables.h',
 184   'include/freetype/tttags.h',
 185 ])
 186
 187 ft2_config_headers = files([
 188   'include/freetype/config/ftconfig.h',
 189   'include/freetype/config/ftheader.h',
 190   'include/freetype/config/ftstdlib.h',
 191   'include/freetype/config/integer-types.h',
 192   'include/freetype/config/mac-support.h',
 193   'include/freetype/config/public-macros.h',
 194 ])
 195
 196 ft2_defines += ['-DFT2_BUILD_LIBRARY=1']
 197
 198
 199 # System support file.
 200
 201 cc = meson.get_compiler('c')
 202
 203 # NOTE: msys2 on Windows has `unistd.h` and `fcntl.h` but not `sys/mman.h`!
 204 has_unistd_h = cc.has_header('unistd.h')
 205 has_fcntl_h = cc.has_header('fcntl.h')
 206 has_sys_mman_h = cc.has_header('sys/mman.h')
 207
 208 mmap_option = get_option('mmap')
 209
 210 use_unix_ftsystem_c = false
 211 if mmap_option.disabled()
 212   ft2_sources += files(['src/base/ftsystem.c',])
 213 elif host_machine.system() == 'windows'
 214   ft2_sources += files(['builds/windows/ftsystem.c',])
 215 else
 216   if has_unistd_h and has_fcntl_h and has_sys_mman_h
 217     # This version of `ftsystem.c` uses `mmap` to read input font files.
 218     ft2_sources += files(['builds/unix/ftsystem.c',])
 219     use_unix_ftsystem_c = true
 220   elif mmap_option.enabled()
 221     error('mmap was enabled via options but is not available,'
 222           + ' required headers were not found!')
 223   else
 224     ft2_sources += files(['src/base/ftsystem.c',])
 225   endif
 226 endif
 227
 228
 229 # Debug support file
 230 #
 231 # NOTE: Some specialized versions exist for other platforms not supported by
 232 # Meson.  Most implementation differences are extremely minor, i.e., in the
 233 # implementation of `FT_Message` and `FT_Panic`, and getting the `FT2_DEBUG`
 234 # value from the environment, when this is supported.  A smaller refactor
 235 # might make these platform-specific files much smaller, and could be moved
 236 # into `ftsystem.c` as well.
 237
 238 if host_machine.system() == 'windows'
 239   winmod = import('windows')
 240   ft2_sources += [
 241     'builds/windows/ftdebug.c',
 242     winmod.compile_resources('src/base/ftver.rc'),
 243   ]
 244 else
 245   ft2_sources += 'src/base/ftdebug.c'
 246 endif
 247
 248
 249 ft2_deps = []
 250 common_ldflags = []
 251
 252
 253 # Correct compatibility version for OS x.
 254 #
 255 # OSX sets the compatibility_version (aka libtools version) differently from
 256 # the library name.
 257
 258 if host_machine.system() == 'darwin'
 259   # maintain compatibility with autotools on macOS
 260   common_ldflags = [
 261     '-compatibility_version', ft2_pkgconfig_version.split('.')[0],
 262     '-current_version', ft2_pkgconfig_version
 263   ]
 264 endif
 265
 266
 267 # Generate `ftoption.h` based on available dependencies.
 268
 269 process_header_command = [python_exe,
 270   files('builds/meson/process_ftoption_h.py'),
 271   '@INPUT@', '--output=@OUTPUT@']
 272
 273 ftoption_command = process_header_command
 274
 275 # External GZip support.
 276 zlib_option = get_option('zlib')
 277
 278 # Backward-compatible aliases.
 279 if zlib_option == 'disabled'
 280   zlib_option = 'none'
 281 elif zlib_option == 'enabled'
 282   zlib_option = 'auto'
 283 endif
 284
 285 if zlib_option == 'auto'
 286   # First try to find a system installation, otherwise fall back to
 287   # the subproject.
 288   zlib_dep = dependency('zlib',
 289     required: false)
 290   if zlib_dep.found()
 291     zlib_option = 'system'
 292   else
 293     zlib_option = 'external'
 294   endif
 295 endif
 296
 297 if zlib_option == 'none'
 298   ftoption_command += [ '--disable=FT_CONFIG_OPTION_USE_ZLIB' ]
 299 elif zlib_option == 'internal'
 300   ftoption_command += [ '--enable=FT_CONFIG_OPTION_USE_ZLIB' ]
 301 elif zlib_option == 'external'
 302   ftoption_command += [ '--enable=FT_CONFIG_OPTION_USE_ZLIB' ]
 303   zlib_project = subproject('zlib',
 304     required: true,
 305     default_options: 'default_library=static')
 306   zlib_dep = zlib_project.get_variable('zlib_dep')
 307   ft2_deps += [zlib_dep]
 308 elif zlib_option == 'system'
 309   zlib_dep = dependency('zlib',
 310     required: true)
 311   assert(zlib_dep.found(), 'Could not find system zlib installation!')
 312   ftoption_command += [
 313     '--enable=FT_CONFIG_OPTION_USE_ZLIB',
 314     '--enable=FT_CONFIG_OPTION_SYSTEM_ZLIB',
 315   ]
 316   ft2_deps += [zlib_dep]
 317 else
 318   assert(false, 'Invalid zlib option ' + zlib_option)
 319 endif
 320
 321 # BZip2 support.
 322 bzip2_dep = dependency('bzip2', required: false)
 323 if not bzip2_dep.found()
 324   bzip2_dep = cc.find_library('bz2',
 325     has_headers: ['bzlib.h'],
 326     required: get_option('bzip2'))
 327 endif
 328
 329 if bzip2_dep.found()
 330   ftoption_command += ['--enable=FT_CONFIG_OPTION_USE_BZIP2']
 331   ft2_sources += files(['src/bzip2/ftbzip2.c',])
 332   ft2_deps += [bzip2_dep]
 333 endif
 334
 335 # PNG support.
 336 libpng_dep = dependency('libpng',
 337   required: get_option('png'),
 338   fallback: 'libpng')
 339
 340 if libpng_dep.found()
 341   ftoption_command += ['--enable=FT_CONFIG_OPTION_USE_PNG']
 342   ft2_deps += [libpng_dep]
 343 endif
 344
 345 # Harfbuzz support.
 346 harfbuzz_dep = dependency('harfbuzz',
 347   version: '>= 2.0.0',
 348   required: get_option('harfbuzz'),
 349   default_options: ['freetype=disabled'])
 350
 351 if harfbuzz_dep.found()
 352   ftoption_command += ['--enable=FT_CONFIG_OPTION_USE_HARFBUZZ']
 353   ft2_deps += [harfbuzz_dep]
 354 endif
 355
 356 # Brotli decompression support.
 357 brotli_dep = dependency('libbrotlidec',
 358   required: get_option('brotli'))
 359
 360 if brotli_dep.found()
 361   ftoption_command += ['--enable=FT_CONFIG_OPTION_USE_BROTLI']
 362   ft2_deps += [brotli_dep]
 363 endif
 364
 365 # We can now generate `ftoption.h`.
 366 ftoption_h = custom_target('ftoption.h',
 367   input: 'include/freetype/config/ftoption.h',
 368   output: 'ftoption.h',
 369   command: ftoption_command,
 370   install: true,
 371   install_dir: join_paths(freetype_includedir, 'freetype/config'),
 372 )
 373 ft2_sources += ftoption_h
 374 ft2_defines += ['-DFT_CONFIG_OPTIONS_H=<ftoption.h>']
 375
 376 if host_machine.system() == 'windows'
 377   ft2_defines += ['-DDLL_EXPORT=1']
 378 endif
 379
 380
 381 # Generate `ftconfig.h`.
 382
 383 ftconfig_command = process_header_command
 384
 385 if has_unistd_h
 386   ftconfig_command += '--enable=HAVE_UNISTD_H'
 387 endif
 388 if has_fcntl_h
 389   ftconfig_command += '--enable=HAVE_FCNTL_H'
 390 endif
 391
 392 if use_unix_ftsystem_c
 393   ftconfig_h_in = files('builds/unix/ftconfig.h.in')
 394   ftconfig_h = custom_target('ftconfig.h',
 395     input: ftconfig_h_in,
 396     output: 'ftconfig.h',
 397     command: ftconfig_command,
 398     install: true,
 399     install_dir: join_paths(freetype_includedir, 'freetype/config'),
 400   )
 401   ft2_sources += ftconfig_h
 402   ft2_defines += ['-DFT_CONFIG_CONFIG_H=<ftconfig.h>']
 403 endif
 404
 405
 406 ft2_lib = library('freetype',
 407   sources: ft2_sources + [ftmodule_h],
 408   c_args: ft2_defines,
 409   gnu_symbol_visibility: 'hidden',
 410   include_directories: ft2_includes,
 411   dependencies: ft2_deps,
 412   install: true,
 413   version: ft2_so_version,
 414   link_args: common_ldflags,
 415 )
 416
 417
 418 # To be used by other projects including this one via `subproject`.
 419
 420 freetype_dep = declare_dependency(
 421   include_directories: ft2_includes,
 422   link_with: ft2_lib,
 423   version: ft2_pkgconfig_version)
 424
 425 meson.override_dependency('freetype2', freetype_dep)
 426
 427
 428 # NOTE: Using both `install_dir` and `subdir` doesn't seem to work
 429 # below, i.e., the `subdir` value seems to be ignored, contrary to
 430 # examples in the Meson documentation.
 431 install_headers('include/ft2build.h',
 432   install_dir: freetype_includedir)
 433 install_headers(ft2_public_headers,
 434   install_dir: join_paths(freetype_includedir, 'freetype'))
 435 install_headers(ft2_config_headers,
 436   install_dir: join_paths(freetype_includedir, 'freetype/config'))
 437
 438
 439 install_data('builds/unix/freetype2.m4',
 440   install_dir: freetype_aclocaldir)
 441
 442
 443 pkgconfig = import('pkgconfig')
 444
 445 pkgconfig.generate(ft2_lib,
 446   filebase: 'freetype2',
 447   name: 'FreeType 2',
 448   description: 'A free, high-quality, and portable font engine.',
 449   url: 'https://freetype.org',
 450   subdirs: 'freetype2',
 451   version: ft2_pkgconfig_version,
 452 )
 453
 454 if get_option('tests').enabled()
 455   subdir('tests')
 456 endif
 457
 458
 459 # NOTE: Unlike the old `make refdoc` command, this generates the
 460 # documentation under `$BUILD/docs/` since Meson doesn't support modifying
 461 # the source root directory (which is a good thing).
 462
 463 gen_docs = custom_target('freetype2 reference documentation',
 464   output: 'docs',
 465   input: ft2_public_headers + ft2_config_headers,
 466   command: [python_exe,
 467     files('builds/meson/generate_reference_docs.py'),
 468     '--version=' + meson.project_version(),
 469     '--input-dir=' + meson.current_source_dir(),
 470     '--output-dir=@OUTPUT@'
 471   ],
 472 )
 473
 474
 475 summary({'OS': host_machine.system(),
 476         }, section: 'Operating System')
 477
 478 summary({'Zlib': zlib_option,
 479          'Bzip2': bzip2_dep.found() ? 'yes' : 'no',
 480          'Png': libpng_dep.found() ? 'yes' : 'no',
 481          'Harfbuzz': harfbuzz_dep.found() ? 'yes' : 'no',
 482          'Brotli': brotli_dep.found() ? 'yes' : 'no',
 483         }, section: 'Used Libraries')
 484
 485 # EOF