xorn/configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 # Copyright (C) 2013-2019 Roland Lutz
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software Foundation,
  16 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  17
  18 AC_PREREQ([2.61])
  19 LT_PREREQ([2.4.2])
  20
  21 AC_INIT([Xorn], [0.0], [bug-xorn@hedmen.org], [], [http://hedmen.org/xorn/])
  22 AC_CONFIG_SRCDIR([src/cpython/storage/module.c])
  23 AC_CONFIG_MACRO_DIR([m4])
  24
  25 AM_INIT_AUTOMAKE([-Wall -Werror silent-rules subdir-objects])
  26 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  27 LT_INIT([])
  28
  29 AC_PROG_CXX
  30
  31 AM_PATH_PYTHON([2.7])
  32 PKG_CHECK_MODULES([PYTHON], [python2 >= 2.7])
  33 PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.10])
  34
  35 AM_GNU_GETTEXT([external])
  36 AM_GNU_GETTEXT_VERSION([0.18.2])
  37
  38 # use location passed by main configure script
  39 AC_MSG_CHECKING([where to look for gEDA shared data])
  40 gedadatadir="$GEDADATADIR"
  41 AC_MSG_RESULT([$gedadatadir])
  42 AS_IF([test "x$gedadatadir" = "x"],
  43       [AC_MSG_ERROR([No gEDA shared data location given])])
  44 AC_SUBST([gedadatadir])
  45
  46 # use location passed by main configure script
  47 AC_MSG_CHECKING([where to look for gEDA rc files])
  48 gedasysconfdir="$GEDARCDIR"
  49 AC_MSG_RESULT([$gedasysconfdir])
  50 AC_SUBST([gedasysconfdir])
  51
  52 AC_CONFIG_HEADERS([config.h])
  53 AC_CONFIG_FILES([
  54         Makefile
  55         po/Makefile.in
  56         src/storage/Makefile
  57         src/cpython/storage/Makefile
  58         src/cpython/guile/Makefile
  59         src/python/Makefile
  60         src/gaf/Makefile
  61         src/command/Makefile
  62         src/backend/Makefile
  63         tests/Makefile
  64         tests/netlist/Makefile
  65 ])
  66 AC_OUTPUT