configure.ac

   1 dnl                                                      -*-Autoconf-*-
   2 dnl Process this file with autoconf to generate configure.
   3 dnl
   4 dnl The AX_* macros are defined in files in the top-level m4
   5 dnl directory.
   6
   7 #####################################################################
   8 # Set up configuration system
   9 #####################################################################
  10
  11 AC_INIT([gEDA/gaf], [1.10.0], [https://bugs.launchpad.net/geda], [geda-gaf])
  12 AC_PREREQ([2.60])
  13
  14 AC_CONFIG_SRCDIR([libgeda/src/libgeda.c])
  15 AC_CONFIG_AUX_DIR([build-tools])
  16 AC_CONFIG_MACRO_DIR([m4])
  17 AC_CONFIG_HEADER([config.h])
  18
  19 AM_INIT_AUTOMAKE([parallel-tests color-tests tar-ustar])
  20 AM_SILENT_RULES
  21
  22 AC_GNU_SOURCE # FIXME for some reason this is needed?
  23
  24 #####################################################################
  25 # Do version number magic
  26 #####################################################################
  27
  28 AX_GIT_VERSION([20191008])
  29
  30 # This is used for keeping the ChangeLog files up-to-date
  31 AC_SUBST([CHANGELOG_BASE], [1.0-20070526])
  32
  33 #####################################################################
  34 # Windows/MinGW/Cygwin support
  35 #####################################################################
  36
  37 AX_WINDOWS_FLAGS
  38
  39 #####################################################################
  40 # Check for compiling & linking tools
  41 #####################################################################
  42
  43 AC_PROG_CC
  44 AC_PROG_CPP
  45 m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) dnl Workaround for Automake 1.11
  46
  47 AC_PROG_CC_STDC
  48 if test "X$ac_cv_prog_cc_stdc" = "Xno"; then
  49   AC_MSG_ERROR([C compiler cannot compile ISO Standard C])
  50 fi
  51
  52 AC_LIBTOOL_WIN32_DLL
  53 AC_DISABLE_STATIC
  54 AC_PROG_LIBTOOL
  55
  56 AM_PROG_CC_C_O
  57
  58 AX_PROG_CC_WARNING([maybe_uninitialized], [maybe-uninitialized])
  59 AX_PROG_CC_WARNING([misleading_indentation], [misleading-indentation])
  60
  61 AX_GCC_FLAGS([-Wall $Werror_maybe_uninitialized_IF_SUPPORTED])
  62
  63 AC_PROG_MKDIR_P
  64 AM_PROG_LEX
  65 AX_PROG_AWK
  66 AX_PROG_GROFF
  67 AC_PATH_PROGS([M4], [gm4 m4], [m4])
  68
  69 #####################################################################
  70 # Internationalisation
  71 #####################################################################
  72
  73 AM_NLS
  74 AM_GNU_GETTEXT([external])
  75 AM_GNU_GETTEXT_VERSION([0.18])
  76 AX_DESKTOP_I18N
  77
  78 #####################################################################
  79 # Check for libraries that use pkg-config
  80 #####################################################################
  81
  82 PKG_PROG_PKG_CONFIG
  83
  84 AX_CHECK_GUILE([2.0.10])
  85
  86 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.41.1], ,
  87   AC_MSG_ERROR([GLib 2.20.0 or later is required.]))
  88
  89 PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.20.0], ,
  90   AC_MSG_ERROR([GIO 2.20.0 or later is required.]))
  91
  92 PKG_CHECK_MODULES(GTK, [gtk+-2.0 >= 2.18.0], ,
  93   AC_MSG_ERROR([GTK+ 2.18.0 or later is required.]))
  94
  95 PKG_CHECK_MODULES(GDK, [gdk-2.0 >= 2.18.0], ,
  96   AC_MSG_ERROR([GDK 2.18.0 or later is required.]))
  97
  98 PKG_CHECK_MODULES(GDK_PIXBUF, [gdk-pixbuf-2.0 >= 2.18.0], ,
  99   AC_MSG_ERROR([GDK_PIXBUF 2.18.0 or later is required.]))
 100
 101 AX_CHECK_CAIRO
 102
 103 PKG_CHECK_MODULES(PANGOCAIRO, [pangocairo >= 0.26], ,
 104   AC_MSG_ERROR([PANGOCAIRO 0.26 or later is required.]))
 105
 106 PKG_CHECK_MODULES(PANGO, [pango >= 1.23.0], ,
 107   AC_MSG_ERROR([PANGO 1.23.0 or later is required.]))
 108
 109 #####################################################################
 110 # Header files & particular functions
 111 #####################################################################
 112
 113 AC_HEADER_SYS_WAIT
 114
 115 # FIXME these checks are obsolete, because every plausible platform
 116 # provides what they check for.
 117 AC_HEADER_STDC
 118
 119 # FIXME these checks may be pointless for one of three reasons: every
 120 # even vaguely sane libc implementation provides them; we don't use
 121 # any of their functions in favour of GLib alternatives; or we don't
 122 # provide an alternative, so the build will fail anyway.
 123 AC_CHECK_HEADERS([stdlib.h string.h unistd.h])
 124
 125 # FIXME since we don't have a sensible alternative, if these headers
 126 # are missing we should fail. Also need to remove HAVE_ERRNO_H tests
 127 # in the C source code, since if we *don't* have it the build will
 128 # fail anyway.
 129 AC_CHECK_HEADERS([errno.h fcntl.h])
 130
 131 # FIXME On a system without locale.h, the user may have just disabled NLS
 132 # to be able to build.  But are there known systems with working NLS but
 133 # without a locale.h?  We do need to include locale.h on some systems
 134 # to be able to build gschem/src/gschem.c
 135 AC_CHECK_HEADERS([locale.h])
 136
 137 # Check for lrint in math library.
 138 AC_CHECK_LIB([m], [lrint],
 139              AC_DEFINE([HAVE_LRINT], 1,
 140                        [If your math library has lrint in it, define this]))
 141
 142 AC_CHECK_LIB([m], [atan2])
 143
 144 AC_CHECK_FUNCS([chown getlogin])
 145
 146 # Check if the getopt header is present
 147 AC_CHECK_HEADERS([getopt.h])
 148 # Check for getopt_long
 149 # On FreeBSD the 'gnugetopt' library is needed.
 150 AC_SEARCH_LIBS([getopt_long], [gnugetopt],
 151                AC_DEFINE([HAVE_GETOPT_LONG], 1,
 152                          [Define to 1 if you have the `getopt_long' function.]))
 153
 154 # Check for misc features of awk
 155 AX_AWK_FEATURES
 156
 157 #####################################################################
 158 # Optional things
 159 #####################################################################
 160
 161 # Assertions
 162 AX_OPTION_ASSERT
 163 # Viewing documentation
 164 AX_OPTION_URI_VIEWER
 165 # API documentation
 166 AX_OPTION_DOXYGEN
 167 # XDG desktop files
 168 AX_OPTION_XDG_DATA
 169 # KDE 3 desktop files
 170 AX_OPTION_KDE3_DATA
 171 # XDG database updates
 172 AX_OPTION_XDG_DB
 173 # libfam support
 174 AX_OPTION_FAM
 175 # gattrib
 176 AX_OPTION_GATTRIB
 177
 178 #####################################################################
 179 # Tool-specific setup
 180 #####################################################################
 181
 182 # Where should data files be installed/searched for?
 183 AX_DATA_DIRS
 184 # Where should PCB footprints be searched for?
 185 AX_PCB_DIRS
 186 # Set up libgeda with the correct ld version number
 187 AX_LIBGEDA([46:0:0])
 188 # Set up libgedacairo with the correct ld version number
 189 AX_LIBGEDACAIRO([1:2:0])
 190
 191 #####################################################################
 192 # Recurse into Xorn configuration
 193 #####################################################################
 194
 195 export GEDADATADIR
 196 export GEDARCDIR
 197
 198 AC_CONFIG_SUBDIRS([xorn])
 199
 200 #####################################################################
 201 # Generate output
 202 #####################################################################
 203
 204 AC_CONFIG_FILES([Makefile
 205
 206                  libgeda/Makefile
 207                  libgeda/libgeda.pc
 208                  libgeda/po/domain.mak
 209                  libgeda/po/Makefile.in
 210                  libgeda/data/Makefile
 211                  libgeda/docs/Makefile
 212                  libgeda/docs/images/Makefile
 213                  libgeda/include/Makefile
 214                  libgeda/lib/Makefile
 215                  libgeda/scheme/Makefile
 216                  libgeda/src/Makefile
 217
 218                  libgedacairo/Makefile
 219                  libgedacairo/libgedacairo.pc
 220
 221                  gaf/Makefile
 222                  gaf/po/Makefile.in
 223
 224                  gschem/Makefile
 225                  gschem/po/Makefile.in
 226                  gschem/docs/Makefile
 227                  gschem/include/Makefile
 228                  gschem/scripts/Makefile
 229                  gschem/src/Makefile
 230                  gschem/examples/Makefile
 231                  gschem/lib/Makefile
 232                  gschem/data/Makefile
 233                  gschem/bitmap/Makefile
 234                  gschem/tests/Makefile
 235                  gschem/scheme/Makefile
 236
 237                  gattrib/Makefile
 238                  gattrib/po/Makefile.in
 239                  gattrib/design/Makefile
 240                  gattrib/docs/Makefile
 241                  gattrib/include/Makefile
 242                  gattrib/lib/Makefile
 243                  gattrib/lib/system-gattribrc
 244                  gattrib/src/Makefile
 245                  gattrib/data/Makefile
 246
 247                  gsymcheck/docs/Makefile
 248                  gsymcheck/include/Makefile
 249                  gsymcheck/lib/Makefile
 250                  gsymcheck/lib/system-gsymcheckrc
 251                  gsymcheck/po/Makefile.in
 252                  gsymcheck/src/Makefile
 253                  gsymcheck/tests/Makefile
 254                  gsymcheck/Makefile
 255
 256                  gnetlist-legacy/Makefile
 257                  gnetlist-legacy/po/Makefile.in
 258                  gnetlist-legacy/src/Makefile
 259                  gnetlist-legacy/include/Makefile
 260                  gnetlist-legacy/scheme/Makefile
 261                  gnetlist-legacy/examples/Makefile
 262                  gnetlist-legacy/tests/Makefile
 263                  gnetlist-legacy/docs/Makefile
 264                  gnetlist-legacy/docs/vams/Makefile
 265                  gnetlist-legacy/examples/vams/Makefile
 266                  gnetlist-legacy/examples/vams/vhdl/Makefile
 267                  gnetlist-legacy/examples/vams/vhdl/basic-vhdl/Makefile
 268                  gnetlist-legacy/examples/vams/vhdl/new-vhdl/Makefile
 269                  gnetlist-legacy/examples/switcap/Makefile
 270                  gnetlist-legacy/lib/Makefile
 271                  gnetlist-legacy/utils/Makefile
 272                  gnetlist-legacy/scripts/Makefile
 273                  gnetlist-legacy/scripts/annotate.sh
 274                  gnetlist-legacy/scripts/bom_xref.sh
 275                  gnetlist-legacy/scripts/bompp.sh
 276                  gnetlist-legacy/lib/system-gnetlistrc
 277
 278                  utils/Makefile
 279                  utils/docs/Makefile
 280                  utils/examples/Makefile
 281                  utils/examples/gmk_sym/Makefile
 282                  utils/examples/gsch2pcb/Makefile
 283                  utils/examples/tragesym/Makefile
 284                  utils/gschlas/Makefile
 285                  utils/gxyrs/Makefile
 286                  utils/include/Makefile
 287                  utils/lib/Makefile
 288                  utils/lib/system-gschlasrc
 289                  utils/scripts/Makefile
 290                  utils/src/Makefile
 291                  utils/tests/gxyrs/Makefile
 292                  utils/tests/refdes_renum/Makefile
 293
 294                  symbols/Makefile
 295                  symbols/documentation/Makefile
 296
 297                  docs/Makefile
 298                  docs/scheme-api/Makefile
 299                  docs/toplevel/Makefile
 300                  docs/toplevel/gedadocs.html
 301                  docs/wiki/Makefile
 302
 303                  examples/Makefile
 304                  examples/RF_Amp/Makefile
 305                  examples/RF_Amp/model/Makefile
 306                  examples/RF_Amp/sym/Makefile
 307                  examples/TwoStageAmp/Makefile
 308                  examples/gTAG/Makefile
 309                  examples/lightning_detector/Makefile
 310
 311                  contrib/Makefile
 312                  contrib/smash_megafile/Makefile
 313                  contrib/olib/Makefile
 314                  contrib/gmk_sym/Makefile
 315                  contrib/sarlacc_schem/Makefile
 316                  contrib/scripts/Makefile
 317                  contrib/scripts/sw2asc
 318 ])
 319 AC_OUTPUT