configure.ac

   1 dnl                                                      -*-Autoconf-*-
   2 dnl Process this file with autoconf to generate configure.
   3 dnl
   4 dnl The AX_* macros are defined in files in the top-level m4
   5 dnl directory.
   6
   7 #####################################################################
   8 # Set up configuration system
   9 #####################################################################
  10
  11 AC_INIT([gEDA/gaf], [1.7.1], [geda-bug@seul.org], [geda-gaf])
  12 AC_PREREQ([2.60])
  13
  14 AC_CONFIG_SRCDIR([libgeda/src/libgeda.c])
  15 AC_CONFIG_AUX_DIR([build-tools])
  16 AC_CONFIG_MACRO_DIR([m4])
  17 AC_CONFIG_HEADER([config.h])
  18
  19 AM_INIT_AUTOMAKE
  20
  21 AC_GNU_SOURCE # FIXME for some reason this is needed?
  22
  23 #####################################################################
  24 # Do version number magic
  25 #####################################################################
  26
  27 AX_GIT_VERSION([20110619])
  28
  29 # This is used for keeping the ChangeLog files up-to-date
  30 AC_SUBST([CHANGELOG_BASE], [1.0-20070526])
  31
  32 #####################################################################
  33 # Windows/MinGW/Cygwin support
  34 #####################################################################
  35
  36 AX_WINDOWS_FLAGS
  37
  38 #####################################################################
  39 # Check for compiling & linking tools
  40 #####################################################################
  41
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44
  45 AC_LIBTOOL_WIN32_DLL
  46 AC_DISABLE_STATIC
  47 AC_PROG_LIBTOOL
  48
  49 AM_PROG_CC_C_O
  50 AX_GCC_FLAGS([-Wall])
  51
  52 AC_PROG_MKDIR_P
  53 AM_PROG_LEX
  54 AX_PROG_AWK
  55 AX_PROG_GROFF
  56 AC_PATH_PROGS([M4], [gm4 m4], [m4])
  57
  58 #####################################################################
  59 # Internationalisation
  60 #####################################################################
  61
  62 AM_NLS
  63 AM_GNU_GETTEXT
  64 AM_GNU_GETTEXT_VERSION([0.16])
  65 AX_DESKTOP_I18N
  66
  67 #####################################################################
  68 # Check for libraries that use pkg-config
  69 #####################################################################
  70
  71 PKG_PROG_PKG_CONFIG
  72
  73 AX_CHECK_GUILE([1.8.0])
  74
  75 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0], ,
  76   AC_MSG_ERROR([GLib 2.12.0 or later is required.]))
  77
  78 PKG_CHECK_MODULES(GTK, [gtk+-2.0 >= 2.10.0], ,
  79   AC_MSG_ERROR([GTK+ 2.10.0 or later is required.]))
  80
  81 PKG_CHECK_MODULES(GDK_PIXBUF, [gdk-pixbuf-2.0 >= 0.15.0], ,
  82   AC_MSG_ERROR([GDK_PIXBUF 0.15.0 or later is required.]))
  83
  84 PKG_CHECK_MODULES(CAIRO, [cairo >= 1.2.0], ,
  85   AC_MSG_ERROR([CAIRO 1.2.0 or later is required.]))
  86
  87 #####################################################################
  88 # Header files & particular functions
  89 #####################################################################
  90
  91 AC_HEADER_SYS_WAIT
  92
  93 # FIXME these checks are obsolete, because every plausible platform
  94 # provides what they check for.
  95 AC_HEADER_STDC
  96
  97 # FIXME these checks may be pointless for one of three reasons: every
  98 # even vaguely sane libc implementation provides them; we don't use
  99 # any of their functions in favour of GLib alternatives; or we don't
 100 # provide an alternative, so the build will fail anyway.
 101 AC_CHECK_HEADERS([stdlib.h string.h unistd.h])
 102
 103 # FIXME since we don't have a sensible alternative, if these headers
 104 # are missing we should fail. Also need to remove HAVE_ERRNO_H tests
 105 # in the C source code, since if we *don't* have it the build will
 106 # fail anyway.
 107 AC_CHECK_HEADERS([errno.h fcntl.h])
 108
 109 # FIXME On a system without locale.h, the user may have just disabled NLS
 110 # to be able to build.  But are there known systems with working NLS but
 111 # without a locale.h?  We do need to include locale.h on some systems
 112 # to be able to build gschem/src/gschem.c
 113 AC_CHECK_HEADERS([locale.h])
 114
 115 # Check for lrint in math library.
 116 AC_CHECK_LIB([m], [lrint],
 117              AC_DEFINE([HAVE_LRINT], 1,
 118                        [If your math library has lrint in it, define this]))
 119
 120 AC_CHECK_LIB([m], [atan2])
 121
 122 AC_CHECK_FUNCS([chown getlogin])
 123
 124 # Check if the getopt header is present
 125 AC_CHECK_HEADERS([getopt.h])
 126 # Check for getopt_long
 127 # On FreeBSD the 'gnugetopt' library is needed.
 128 AC_SEARCH_LIBS([getopt_long], [gnugetopt],
 129                AC_DEFINE([HAVE_GETOPT_LONG], 1,
 130                          [Define to 1 if you have the `getopt_long' function.]))
 131
 132 # Check for misc features of awk
 133 AX_AWK_FEATURES
 134
 135 #####################################################################
 136 # Optional things
 137 #####################################################################
 138
 139 # Assertions
 140 AX_OPTION_ASSERT
 141 # API documentation
 142 AX_OPTION_DOXYGEN
 143 # XDG desktop files
 144 AX_OPTION_XDG_DATA
 145 # KDE 3 desktop files
 146 AX_OPTION_KDE3_DATA
 147 # XDG database updates
 148 AX_OPTION_XDG_DB
 149 # libstroke support
 150 AX_OPTION_STROKE
 151 # gattrib
 152 AX_OPTION_GATTRIB
 153
 154 #####################################################################
 155 # Tool-specific setup
 156 #####################################################################
 157
 158 # Where should data files be installed/searched for?
 159 AX_DATA_DIRS
 160 # Where should PCB footprints be searched for?
 161 AX_PCB_DIRS
 162 # Set up libgeda with the correct ld version number
 163 AX_LIBGEDA([40:0:0])
 164
 165 #####################################################################
 166 # Generate output
 167 #####################################################################
 168
 169 AC_CONFIG_FILES([Makefile
 170                  intl/Makefile
 171
 172                  libgeda/Makefile
 173                  libgeda/libgeda.pc
 174                  libgeda/po/domain.mak
 175                  libgeda/po/Makefile.in
 176                  libgeda/shell/Makefile
 177                  libgeda/data/Makefile
 178                  libgeda/docs/Makefile
 179                  libgeda/docs/images/Makefile
 180                  libgeda/include/Makefile
 181                  libgeda/lib/Makefile
 182                  libgeda/scheme/Makefile
 183                  libgeda/share/Makefile
 184                  libgeda/src/Makefile
 185
 186                  gschem/Makefile
 187                  gschem/po/Makefile.in
 188                  gschem/docs/Makefile
 189                  gschem/include/Makefile
 190                  gschem/scripts/Makefile
 191                  gschem/src/Makefile
 192                  gschem/examples/Makefile
 193                  gschem/lib/Makefile
 194                  gschem/data/Makefile
 195                  gschem/bitmap/Makefile
 196                  gschem/tests/Makefile
 197                  gschem/scheme/Makefile
 198
 199                  gattrib/Makefile
 200                  gattrib/po/Makefile.in
 201                  gattrib/design/Makefile
 202                  gattrib/docs/Makefile
 203                  gattrib/include/Makefile
 204                  gattrib/lib/Makefile
 205                  gattrib/lib/system-gattribrc
 206                  gattrib/src/Makefile
 207                  gattrib/data/Makefile
 208
 209                  gsymcheck/docs/Makefile
 210                  gsymcheck/include/Makefile
 211                  gsymcheck/lib/Makefile
 212                  gsymcheck/lib/system-gsymcheckrc
 213                  gsymcheck/src/Makefile
 214                  gsymcheck/tests/Makefile
 215                  gsymcheck/Makefile
 216
 217                  gnetlist/Makefile
 218                  gnetlist/src/Makefile
 219                  gnetlist/include/Makefile
 220                  gnetlist/scheme/Makefile
 221                  gnetlist/examples/Makefile
 222                  gnetlist/tests/Makefile
 223                  gnetlist/tests/hierarchy/Makefile
 224                  gnetlist/tests/hierarchy2/Makefile
 225                  gnetlist/tests/drc2/Makefile
 226                  gnetlist/tests/common/Makefile
 227                  gnetlist/docs/Makefile
 228                  gnetlist/docs/vams/Makefile
 229                  gnetlist/examples/vams/Makefile
 230                  gnetlist/examples/vams/vhdl/Makefile
 231                  gnetlist/examples/vams/vhdl/basic-vhdl/Makefile
 232                  gnetlist/examples/vams/vhdl/new-vhdl/Makefile
 233                  gnetlist/examples/switcap/Makefile
 234                  gnetlist/lib/Makefile
 235                  gnetlist/utils/Makefile
 236                  gnetlist/scripts/Makefile
 237                  gnetlist/scripts/annotate.sh
 238                  gnetlist/scripts/bom_xref.sh
 239                  gnetlist/scripts/bompp.sh
 240                  gnetlist/scripts/sw2asc
 241                  gnetlist/lib/system-gnetlistrc
 242
 243                  utils/Makefile
 244                  utils/docs/Makefile
 245                  utils/examples/Makefile
 246                  utils/examples/gmk_sym/Makefile
 247                  utils/examples/gsch2pcb/Makefile
 248                  utils/examples/tragesym/Makefile
 249                  utils/gschlas/Makefile
 250                  utils/gxyrs/Makefile
 251                  utils/include/Makefile
 252                  utils/lib/Makefile
 253                  utils/lib/system-gschlasrc
 254                  utils/scripts/Makefile
 255                  utils/src/Makefile
 256                  utils/tests/Makefile
 257                  utils/tests/gxyrs/Makefile
 258                  utils/tests/gxyrs/inputs/Makefile
 259                  utils/tests/gxyrs/outputs/Makefile
 260                  utils/tests/refdes_renum/Makefile
 261                  utils/tests/refdes_renum/inputs/Makefile
 262                  utils/tests/refdes_renum/outputs/Makefile
 263
 264                  symbols/Makefile
 265                  symbols/documentation/Makefile
 266
 267                  docs/Makefile
 268                  docs/scheme-api/Makefile
 269                  docs/scripts/Makefile
 270                  docs/toplevel/Makefile
 271                  docs/toplevel/gedadocs.html
 272                  docs/wiki/Makefile
 273                  docs/wiki/images/smileys/Makefile
 274                  docs/wiki/images/Makefile
 275                  docs/wiki/images/interwiki/Makefile
 276                  docs/wiki/media/geda/Makefile
 277                  docs/wiki/media/wiki/Makefile
 278                  docs/wiki/media/tragesym/tragesym/Makefile
 279                  docs/wiki/media/tragesym/Makefile
 280                  docs/wiki/media/Makefile
 281                  docs/wiki/media/devel_tips/Makefile
 282
 283                  examples/Makefile
 284                  examples/RF_Amp/Makefile
 285                  examples/RF_Amp/model/Makefile
 286                  examples/RF_Amp/sym/Makefile
 287                  examples/TwoStageAmp/Makefile
 288                  examples/gTAG/Makefile
 289                  examples/lightning_detector/Makefile
 290 ])
 291 AC_OUTPUT