CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.4.4)
   2 if(COMMAND cmake_policy)
   3       cmake_policy(SET CMP0003 NEW)
   4       cmake_policy(SET CMP0005 NEW)
   5 endif(COMMAND cmake_policy)
   6
   7 # If the user specifies -DCMAKE_BUILD_TYPE on the command line, take their definition
   8 # and dump it in the cache along with proper documentation, otherwise set CMAKE_BUILD_TYPE
   9 # to Release prior to calling PROJECT()
  10 IF(DEFINED CMAKE_BUILD_TYPE)
  11    SET(CMAKE_BUILD_TYPE ${CMAKE_BUILD_TYPE} CACHE STRING "Choose the type of build, options are: None(CMAKE_CXX_FLAGS or CMAKE_C_FLAGS used) Debug Release RelWithDebInfo MinSizeRel.")
  12 ELSE(DEFINED CMAKE_BUILD_TYPE)
  13    SET(CMAKE_BUILD_TYPE Release CACHE STRING "Choose the type of build, options are: None(CMAKE_CXX_FLAGS or CMAKE_C_FLAGS used) Debug Release RelWithDebInfo MinSizeRel.")
  14 ENDIF(DEFINED CMAKE_BUILD_TYPE)
  15
  16 PROJECT(gemrb)
  17 # try to extract the version from the source
  18 execute_process(
  19   COMMAND sed -n "s/\#define VERSION_GEMRB .\\([^\"]*\\).$/\\1/p" ${CMAKE_CURRENT_SOURCE_DIR}/gemrb/includes/globals.h
  20   OUTPUT_VARIABLE GEMRB_VERSION
  21   RESULT_VARIABLE RC
  22   OUTPUT_STRIP_TRAILING_WHITESPACE
  23 )
  24 if(${RC} GREATER 0) # lookup failed
  25   set(GEMRB_VERSION "unknown")
  26 endif(${RC} GREATER 0)
  27 message("Detected version: ${GEMRB_VERSION}")
  28
  29 IF(PREFIX)
  30   SET(PREFIX CACHE PATH "Abbreviation for CMAKE_INSTALL_PREFIX.")
  31   SET(CMAKE_INSTALL_PREFIX ${PREFIX})
  32 ENDIF(PREFIX)
  33
  34 if (NOT LAYOUT)
  35         if (WIN32)
  36                 set(LAYOUT "home")
  37         else (WIN32)
  38                 set(LAYOUT "fhs")
  39         endif (WIN32)
  40 endif (NOT LAYOUT)
  41
  42 SET(LAYOUT "${LAYOUT}" CACHE STRING "Directory layout.")
  43
  44 if (${LAYOUT} MATCHES "home")
  45         IF( NOT PLUGIN_DIR )
  46                 SET( PLUGIN_DIR ${CMAKE_INSTALL_PREFIX}/plugins )
  47         ENDIF( NOT PLUGIN_DIR )
  48         IF( NOT DATA_DIR )
  49                 SET( DATA_DIR ${CMAKE_INSTALL_PREFIX} )
  50         ENDIF( NOT DATA_DIR )
  51         IF( NOT MAN_DIR )
  52                 SET( MAN_DIR ${CMAKE_INSTALL_PREFIX}/man/man6 )
  53         ENDIF( NOT MAN_DIR )
  54         IF( NOT BIN_DIR )
  55                 SET( BIN_DIR ${CMAKE_INSTALL_PREFIX} )
  56         ENDIF( NOT BIN_DIR )
  57         IF( NOT SYSCONF_DIR )
  58                 SET( SYSCONF_DIR ${CMAKE_INSTALL_PREFIX} )
  59         ENDIF( NOT SYSCONF_DIR )
  60         IF( NOT LIB_DIR )
  61                 SET( LIB_DIR ${CMAKE_INSTALL_PREFIX} )
  62         ENDIF( NOT LIB_DIR )
  63         IF( NOT ICON_DIR )
  64                 SET( ICON_DIR ${CMAKE_INSTALL_PREFIX} )
  65         ENDIF( NOT ICON_DIR )
  66         IF( NOT MENU_DIR )
  67                 SET( MENU_DIR ${CMAKE_INSTALL_PREFIX} )
  68         ENDIF( NOT MENU_DIR )
  69 elseif (${LAYOUT} MATCHES "fhs")
  70         IF( NOT LIB_DIR )
  71                 SET( LIB_DIR ${CMAKE_INSTALL_PREFIX}/lib/gemrb )
  72         ENDIF( NOT LIB_DIR )
  73         IF( NOT PLUGIN_DIR )
  74                 SET( PLUGIN_DIR ${LIB_DIR}/plugins )
  75         ENDIF( NOT PLUGIN_DIR )
  76         IF( NOT DATA_DIR )
  77                 SET( DATA_DIR ${CMAKE_INSTALL_PREFIX}/share/gemrb )
  78         ENDIF( NOT DATA_DIR )
  79         IF( NOT MAN_DIR )
  80                 SET( MAN_DIR ${CMAKE_INSTALL_PREFIX}/share/man/man6 )
  81         ENDIF( NOT MAN_DIR )
  82         IF( NOT BIN_DIR )
  83                 SET( BIN_DIR ${CMAKE_INSTALL_PREFIX}/bin )
  84         ENDIF( NOT BIN_DIR )
  85         IF( NOT SYSCONF_DIR )
  86                 SET( SYSCONF_DIR ${CMAKE_INSTALL_PREFIX}/etc/gemrb )
  87         ENDIF( NOT SYSCONF_DIR )
  88         IF( NOT ICON_DIR )
  89                 SET( ICON_DIR ${CMAKE_INSTALL_PREFIX}/share/pixmaps )
  90         ENDIF( NOT ICON_DIR )
  91         IF( NOT MENU_DIR )
  92                 SET( MENU_DIR ${CMAKE_INSTALL_PREFIX}/share/applications )
  93         ENDIF( NOT MENU_DIR )
  94 else (${LAYOUT} MATCHES "opt")
  95         IF( NOT LIB_DIR )
  96                 SET( LIB_DIR ${CMAKE_INSTALL_PREFIX}/lib )
  97         ENDIF( NOT LIB_DIR )
  98         IF( NOT PLUGIN_DIR )
  99                 SET( PLUGIN_DIR ${LIB_DIR}/plugins )
 100         ENDIF( NOT PLUGIN_DIR )
 101         IF( NOT DATA_DIR )
 102                 SET( DATA_DIR ${CMAKE_INSTALL_PREFIX}/share/ )
 103         ENDIF( NOT DATA_DIR )
 104         IF( NOT MAN_DIR )
 105                 SET( MAN_DIR ${CMAKE_INSTALL_PREFIX}/man/man6 )
 106         ENDIF( NOT MAN_DIR )
 107         IF( NOT BIN_DIR )
 108                 SET( BIN_DIR ${CMAKE_INSTALL_PREFIX}/bin )
 109         ENDIF( NOT BIN_DIR )
 110         IF( NOT SYSCONF_DIR )
 111                 SET( SYSCONF_DIR ${CMAKE_INSTALL_PREFIX}/etc )
 112         ENDIF( NOT SYSCONF_DIR )
 113         IF( NOT ICON_DIR )
 114                 SET( ICON_DIR ${CMAKE_INSTALL_PREFIX}/share/pixmaps )
 115         ENDIF( NOT ICON_DIR )
 116         IF( NOT MENU_DIR )
 117                 SET( MENU_DIR ${CMAKE_INSTALL_PREFIX}/share/applications )
 118         ENDIF( NOT MENU_DIR )
 119 endif (${LAYOUT} MATCHES "home")
 120
 121
 122 IF(CMAKE_COMPILER_IS_GNUCXX)
 123         if ( NOT DISABLE_WERROR )
 124                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Werror")
 125         endif ( NOT DISABLE_WERROR )
 126         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -W -Wpointer-arith -Wcast-align")
 127         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pedantic -Wno-format-y2k -Wno-long-long -fno-strict-aliasing")
 128         # only export symbols explicitly marked to be exported.
 129         INCLUDE(CheckCXXCompilerFlag)
 130         CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" VISIBILITY_HIDDEN)
 131         IF (VISIBILITY_HIDDEN)
 132                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
 133         ENDIF (VISIBILITY_HIDDEN)
 134         # Ensure all plugin symbols exist.
 135         if (NOT APPLE)
 136                 set(CMAKE_MODULE_LINKER_FLAGS "-Wl,--no-undefined")
 137         endif (NOT APPLE)
 138 ENDIF(CMAKE_COMPILER_IS_GNUCXX)
 139
 140 MESSAGE(STATUS "Looking for Python libraries")
 141 INCLUDE(FindPythonLibs)
 142 IF(PYTHON_LIBRARY)
 143  MESSAGE(STATUS "Python Libraries Found")
 144 ELSE(PYTHON_LIBRARY)
 145  MESSAGE(FATAL_ERROR "Unable to find Python development libraries. Please get it from www.python.org")
 146 ENDIF(PYTHON_LIBRARY)
 147
 148 MESSAGE(STATUS "Looking for openAL libraries")
 149 INCLUDE(FindOpenAL)
 150 IF(OPENAL_FOUND)
 151  MESSAGE(STATUS "openal found")
 152 ELSE(OPENAL_FOUND)
 153  MESSAGE(ERROR "unable to find openal. please set OPENALDIR environment variable or get it from www.openal.org")
 154 ENDIF(OPENAL_FOUND)
 155
 156 MESSAGE(STATUS "Looking for SDL")
 157 INCLUDE(FindSDL)
 158 IF(SDL_FOUND)
 159  MESSAGE(STATUS "SDL found")
 160 ELSE(SDL_FOUND)
 161  MESSAGE(FATAL_ERROR "unable to find SDL. please get it from www.libsdl.org")
 162 ENDIF(SDL_FOUND)
 163
 164 MESSAGE( STATUS "Looking for Zlib" )
 165 #SET(ZLIB_FIND_REQUIRED TRUE)
 166 INCLUDE(FindZLIB)
 167
 168 MESSAGE( STATUS "Looking for libPNG" )
 169 INCLUDE(FindPNG)
 170 IF(PNG_FOUND)
 171  MESSAGE( STATUS "libPNG found" )
 172 ELSE(PNG_FOUND)
 173  MESSAGE( STATUS "WARNING : GemRB will be built without any PNG support. Get it from www.libpng.org" )
 174 ENDIF(PNG_FOUND)
 175
 176 IF(UNIX)
 177  MESSAGE(STATUS "Looking for dl library")
 178  FIND_LIBRARY(DLD_LIBRARY_PATH dl dld)
 179  IF(DLD_LIBRARY_PATH)
 180   MESSAGE(STATUS "dl library found")
 181  ELSE(DLD_LIBRARY_PATH)
 182   MESSAGE(FATAL_ERROR "dl library not found")
 183  ENDIF(DLD_LIBRARY_PATH)
 184 ENDIF(UNIX)
 185
 186 MESSAGE(STATUS "Looking for Ogg Vorbis support")
 187 FIND_LIBRARY(VORBIS_LIBRARY vorbisfile)
 188
 189 ADD_DEFINITIONS("-DHAVE_CONFIG_H")
 190
 191 INCLUDE_DIRECTORIES(${CMAKE_CURRENT_BINARY_DIR} gemrb/includes gemrb/core)
 192
 193 #Platform checks
 194 INCLUDE (CheckTypeSize)
 195 CHECK_TYPE_SIZE("int" SIZEOF_INT)
 196 CHECK_TYPE_SIZE("long int" SIZEOF_LONG_INT)
 197
 198 INCLUDE (CheckFunctionExists)
 199 CHECK_FUNCTION_EXISTS("snprintf" HAVE_SNPRINTF)
 200 CHECK_FUNCTION_EXISTS("strndup" HAVE_STRNDUP)
 201
 202 #Unneeded on windows
 203 IF(NOT WIN32)
 204 INCLUDE (CheckCXXSourceCompiles)
 205 CHECK_CXX_SOURCE_COMPILES("typedef void *(* voidvoid)(void);
 206
 207 void *object = 0;
 208 voidvoid function;
 209 function = (voidvoid) object;
 210 " PERMITS_OBJECT_TO_FUNCTION_CAST)
 211
 212 IF( NOT PERMITS_OBJECT_TO_FUNCTION_CAST )
 213  SET(HAVE_FORBIDDEN_OBJECT_TO_FUNCTION_CAST 1)
 214 ENDIF( NOT PERMITS_OBJECT_TO_FUNCTION_CAST )
 215 ENDIF(NOT WIN32)
 216
 217 IF(VORBIS_LIBRARY)
 218  SET(HAS_VORBIS_SUPPORT 1)
 219 ELSE(VORBIS_LIBRARY)
 220  SET(VORBIS_LIBRARY "")
 221 ENDIF(VORBIS_LIBRARY)
 222
 223 IF(APPLE)
 224  FIND_LIBRARY(SDL_MAIN_LIBRARY_PATH SDLmain)
 225  FIND_LIBRARY(COCOA_LIBRARY_PATH Cocoa)
 226 ENDIF(APPLE)
 227
 228 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/cmake_config.h.in
 229         ${CMAKE_CURRENT_BINARY_DIR}/config.h ESCAPE_QUOTES)
 230
 231 #Plugin addition macro
 232 MACRO(ADD_GEMRB_PLUGIN plugin_name)
 233         ADD_LIBRARY(${plugin_name} MODULE ${ARGN})
 234         SET_TARGET_PROPERTIES(${plugin_name} PROPERTIES PREFIX ""
 235                 INSTALL_RPATH ${LIB_DIR}
 236                 LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/gemrb/plugins)
 237         TARGET_LINK_LIBRARIES(${plugin_name} gemrb_core)
 238         INSTALL(TARGETS ${plugin_name} DESTINATION ${PLUGIN_DIR})
 239 ENDMACRO(ADD_GEMRB_PLUGIN)
 240
 241 #gemrb overrides macro
 242 MACRO(ADD_GEMRB_OVERRIDE game_name)
 243 FILE( GLOB FILES_TO_INSTALL *.2da *.bmp *.ini *.chu *.ids *.bcs *.vvc *.mos *.spl *.wav *.pro)
 244 INSTALL( FILES ${FILES_TO_INSTALL} DESTINATION ${DATA_DIR}/override/${game_name} )
 245 ENDMACRO(ADD_GEMRB_OVERRIDE )
 246
 247 ADD_SUBDIRECTORY( gemrb )
 248 INSTALL( FILES gemrb.6 DESTINATION ${MAN_DIR} )
 249 INSTALL( FILES gemrb-logo.png DESTINATION ${ICON_DIR} )
 250 INSTALL( FILES gemrb.desktop DESTINATION ${MENU_DIR} )
 251
 252 CONFIGURE_FILE(
 253   "${CMAKE_CURRENT_SOURCE_DIR}/cmake_uninstall.cmake.in"
 254   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 255   IMMEDIATE @ONLY
 256 )
 257
 258 # copy the variable, since the file uses @VERSION@
 259 set(VERSION ${GEMRB_VERSION})
 260 CONFIGURE_FILE(
 261   "${CMAKE_CURRENT_SOURCE_DIR}/gemrb.spec.in"
 262   "${CMAKE_CURRENT_BINARY_DIR}/gemrb.spec"
 263   IMMEDIATE @ONLY
 264 )
 265
 266 ADD_CUSTOM_TARGET( uninstall
 267   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake" )
 268
 269 # make dist for a gzipped tarball of current HEAD
 270 set(ARCHIVE_NAME ${CMAKE_PROJECT_NAME}-${GEMRB_VERSION})
 271 add_custom_target( dist
 272   COMMAND git archive --prefix=${ARCHIVE_NAME}/ HEAD
 273     | gzip --best > ${CMAKE_BINARY_DIR}/${ARCHIVE_NAME}.tar.gz
 274   WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 275 )