dev-lang/quickjs/quickjs-2024.01.13.ebuild

   1 # Copyright 2023-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit toolchain-funcs
   7
   8 MY_P="${PN}-${PV//./-}"
   9
  10 DESCRIPTION="Small embeddable Javascript engine"
  11 HOMEPAGE="https://bellard.org/quickjs/"
  12 SRC_URI="https://bellard.org/quickjs/${MY_P}.tar.xz"
  13 S="${WORKDIR}/${MY_P}"
  14
  15 LICENSE="MIT"
  16 SLOT="0"
  17 KEYWORDS="~amd64"
  18 IUSE="lto"
  19
  20 PATCHES=(
  21         "${FILESDIR}/${PN}-2020.11.08_Remove-TTY-check-in-test.patch"
  22         "${FILESDIR}/${PN}-2021-03-27-respect-env.patch"
  23 )
  24
  25 src_prepare() {
  26         sed -i \
  27                 -e 's;prefix=/usr/local;prefix=/usr;' \
  28                 -e '/$(STRIP) .*/d' \
  29                 Makefile || die "Failed setting prefix"
  30
  31         sed -Ei '/^\s*(CC|AR)=/d' Makefile \
  32                 || die "Failed to remove hard-coded tools."
  33
  34         sed -Ei 's/(^\s*(C|LD)FLAGS)=/\1\+=/' Makefile \
  35                 || die "Failed to change build flag assignment into addition."
  36
  37         export CC="$(tc-getCC)"
  38         export AR="$(tc-getAR)"
  39
  40         default
  41 }
  42
  43 src_compile() {
  44         if use lto; then
  45                 CONFIG_LTO=$(use lto) emake
  46         else
  47                 emake
  48         fi
  49 }
  50
  51 src_install() {
  52         emake DESTDIR="${ED}" PREFIX=/usr install
  53 }