net-proxy/v2ray/v2ray-5.22.0.ebuild

   1 # Copyright 2021-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit systemd go-module
   7
   8 DESCRIPTION="A platform for building proxies to bypass network restrictions."
   9 HOMEPAGE="https://www.v2fly.org/"
  10 SRC_URI="https://github.com/v2fly/v2ray-core/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
  11         https://github.com/Puqns67/gentoo-deps/releases/download/${P}/${P}-vendor.tar.xz"
  12
  13 S="${WORKDIR}/${PN}-core-${PV}"
  14
  15 LICENSE="MIT"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86"
  18
  19 DEPEND="app-alternatives/v2ray-geoip
  20         app-alternatives/v2ray-geosite"
  21 RDEPEND="!net-proxy/v2ray-bin
  22         ${DEPEND}"
  23 BDEPEND=">=dev-lang/go-1.21.4"
  24
  25 src_prepare() {
  26         sed -i 's|/usr/local/bin|/usr/bin|;s|/usr/local/etc|/etc|' release/config/systemd/system/*.service || die
  27         sed -i '/^User=/s/nobody/v2ray/;/^User=/aDynamicUser=true' release/config/systemd/system/*.service || die
  28         default
  29 }
  30
  31 src_compile() {
  32         ego build -o v2ray -trimpath -ldflags "-s -w" ./main
  33 }
  34
  35 src_install() {
  36         dobin v2ray
  37
  38         insinto /etc/v2ray
  39         newins release/config/config.json config.json.example
  40
  41         newinitd "${FILESDIR}/v2ray.initd-r1" v2ray
  42         systemd_dounit release/config/systemd/system/v2ray{,@}.service
  43 }