app-i18n/mozc/mozc-2.26.4220_p20201212102434_p20201219202429.ebuild

   1 # Copyright 2010-2022 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="8"
   5 PYTHON_COMPAT=( python3_{8..10} )
   6
   7 inherit elisp-common multiprocessing python-any-r1 toolchain-funcs desktop xdg
   8
   9 if [[ "${PV}" == "9999" ]]; then
  10         inherit git-r3
  11
  12         EGIT_REPO_URI="https://github.com/google/mozc"
  13         EGIT_SUBMODULES=(src/third_party/japanese_usage_dictionary)
  14 else
  15         MOZC_GIT_REVISION="9ba59b64d53365c1fe93c1c245b4ec3e35bdadf0"
  16         MOZC_DATE="${PV#*_p}"
  17         MOZC_DATE="${MOZC_DATE%%_p*}"
  18
  19         FCITX_MOZC_GIT_REVISION="1ea089debc31ff216473369ad71c08318384ee06"
  20         FCITX_MOZC_DATE="${PV#*_p}"
  21         FCITX_MOZC_DATE="${FCITX_MOZC_DATE#*_p}"
  22         FCITX_MOZC_DATE="${FCITX_MOZC_DATE%%_p*}"
  23
  24         JAPANESE_USAGE_DICTIONARY_GIT_REVISION="a4a66772e33746b91e99caceecced9a28507e925"
  25         JAPANESE_USAGE_DICTIONARY_DATE="20180701040110"
  26 fi
  27
  28 DESCRIPTION="Mozc - Japanese input method editor"
  29 HOMEPAGE="https://github.com/google/mozc"
  30 if [[ "${PV}" == "9999" ]]; then
  31         SRC_URI=""
  32 else
  33         SRC_URI="https://github.com/google/${PN}/archive/${MOZC_GIT_REVISION}.tar.gz -> ${PN}-${PV%%_p*}-${MOZC_DATE}.tar.gz
  34                 https://github.com/hiroyuki-komatsu/japanese-usage-dictionary/archive/${JAPANESE_USAGE_DICTIONARY_GIT_REVISION}.tar.gz -> japanese-usage-dictionary-${JAPANESE_USAGE_DICTIONARY_DATE}.tar.gz
  35                 https://github.com/fcitx/${PN}/archive/${FCITX_MOZC_GIT_REVISION}.tar.gz -> fcitx-${PN}-${PV%%_p*}-${FCITX_MOZC_DATE}.tar.gz"
  36 fi
  37
  38 # Mozc: BSD
  39 # src/data/dictionary_oss: ipadic, public-domain
  40 # src/data/unicode: unicode
  41 # japanese-usage-dictionary: BSD-2
  42 LICENSE="BSD BSD-2 ipadic public-domain unicode"
  43 SLOT="0"
  44 #KEYWORDS="~amd64 ~arm64 ~ppc64 x86"
  45 KEYWORDS="~amd64 ~x86"
  46 IUSE="debug emacs fcitx4 fcitx5 +gui ibus renderer test"
  47 REQUIRED_USE="|| ( emacs fcitx4 fcitx5 ibus )"
  48 RESTRICT="!test? ( test )"
  49
  50 BDEPEND="$(python_gen_any_dep 'dev-python/six[${PYTHON_USEDEP}]')
  51         >=dev-libs/protobuf-3.0.0
  52         dev-util/gyp
  53         dev-util/ninja
  54         virtual/pkgconfig
  55         emacs? ( app-editors/emacs:* )
  56         fcitx4? ( sys-devel/gettext )
  57         fcitx5? ( sys-devel/gettext )"
  58 DEPEND="=dev-cpp/abseil-cpp-20200923*[cxx17(+)]
  59         >=dev-libs/protobuf-3.0.0:=
  60         fcitx4? (
  61                 app-i18n/fcitx:4
  62                 virtual/libintl
  63         )
  64         fcitx5? (
  65                 app-i18n/fcitx:5
  66                 app-i18n/libime
  67                 sys-devel/gettext
  68                 virtual/libintl
  69         )
  70         gui? (
  71                 dev-qt/qtcore:5
  72                 dev-qt/qtgui:5
  73                 dev-qt/qtwidgets:5
  74         )
  75         ibus? (
  76                 >=app-i18n/ibus-1.4.1
  77                 dev-libs/glib:2
  78                 x11-libs/libxcb
  79         )
  80         renderer? (
  81                 dev-libs/glib:2
  82                 x11-libs/cairo
  83                 x11-libs/gtk+:2
  84                 x11-libs/pango
  85         )
  86         test? (
  87                 >=dev-cpp/gtest-1.8.0
  88                 dev-libs/jsoncpp
  89         )"
  90 RDEPEND="=dev-cpp/abseil-cpp-20200923*[cxx17(+)]
  91         >=dev-libs/protobuf-3.0.0:=
  92         emacs? ( app-editors/emacs:* )
  93         fcitx4? (
  94                 app-i18n/fcitx:4
  95                 virtual/libintl
  96         )
  97         fcitx5? (
  98                 app-i18n/fcitx:5
  99                 app-i18n/libime
 100                 sys-devel/gettext
 101                 virtual/libintl
 102         )
 103         gui? (
 104                 dev-qt/qtcore:5
 105                 dev-qt/qtgui:5
 106                 dev-qt/qtwidgets:5
 107         )
 108         ibus? (
 109                 >=app-i18n/ibus-1.4.1
 110                 dev-libs/glib:2
 111                 x11-libs/libxcb
 112         )
 113         renderer? (
 114                 dev-libs/glib:2
 115                 x11-libs/cairo
 116                 x11-libs/gtk+:2
 117                 x11-libs/pango
 118         )"
 119
 120 S="${WORKDIR}/${P}/src"
 121
 122 SITEFILE="50${PN}-gentoo.el"
 123
 124 execute() {
 125         einfo "$@"
 126         "$@"
 127 }
 128
 129 python_check_deps() {
 130         has_version -b "dev-python/six[${PYTHON_USEDEP}]"
 131 }
 132
 133 src_unpack() {
 134         if [[ "${PV}" == "9999" ]]; then
 135                 git-r3_src_unpack
 136
 137                 if use fcitx4 || use fcitx5; then
 138                         local EGIT_SUBMODULES=()
 139                         git-r3_fetch https://github.com/fcitx/mozc refs/heads/fcitx
 140                         git-r3_checkout https://github.com/fcitx/mozc "${WORKDIR}/fcitx-mozc"
 141                 fi
 142                 if use fcitx5; then
 143                         cp -pr "${WORKDIR}"/fcitx{,5}-mozc
 144                 fi
 145         else
 146                 unpack ${PN}-${PV%%_p*}-${MOZC_DATE}.tar.gz
 147                 mv mozc-${MOZC_GIT_REVISION} ${P} || die
 148
 149                 unpack japanese-usage-dictionary-${JAPANESE_USAGE_DICTIONARY_DATE}.tar.gz
 150                 cp -p japanese-usage-dictionary-${JAPANESE_USAGE_DICTIONARY_GIT_REVISION}/usage_dict.txt ${P}/src/third_party/japanese_usage_dictionary || die
 151
 152                 unpack fcitx-${PN}-${PV%%_p*}-${FCITX_MOZC_DATE}.tar.gz
 153                 if use fcitx4; then
 154                         cp -pr mozc-${FCITX_MOZC_GIT_REVISION} fcitx-${PN} || die
 155                 fi
 156                 if use fcitx5; then
 157                         cp -pr mozc-${FCITX_MOZC_GIT_REVISION} fcitx5-${PN} || die
 158                 fi
 159         fi
 160 }
 161
 162 src_prepare() {
 163         if use fcitx4; then
 164                 cp -pr "${WORKDIR}/fcitx-mozc/src/unix/fcitx" unix || die
 165         fi
 166         if use fcitx5; then
 167                 cp -pr "${WORKDIR}/fcitx5-mozc/src/unix/fcitx5" unix || die
 168         fi
 169
 170         pushd "${WORKDIR}/${P}" > /dev/null || die
 171
 172         eapply "${FILESDIR}/${PN}-2.26.4220-system_abseil-cpp.patch"
 173         eapply "${FILESDIR}/${PN}-2.26.4220-system_gtest.patch"
 174         eapply "${FILESDIR}/${PN}-2.26.4220-system_jsoncpp.patch"
 175         eapply "${FILESDIR}/${PN}-2.26.4220-environmental_variables.patch"
 176         eapply "${FILESDIR}/${PN}-2.26.4220-server_path_check.patch"
 177
 178         eapply_user
 179
 180         popd > /dev/null || die
 181
 182         sed \
 183                 -e "s/def GypMain(options, unused_args):/def GypMain(options, gyp_args):/" \
 184                 -e "s/RunOrDie(gyp_command + gyp_options)/RunOrDie(gyp_command + gyp_options + gyp_args)/" \
 185                 -e "s/RunOrDie(\[ninja/&, '-j$(makeopts_jobs "${MAKEOPTS}" 999)', '-l$(makeopts_loadavg "${MAKEOPTS}" 0)', '-v'/" \
 186                 -i build_mozc.py || die
 187
 188         local ar=($(tc-getAR))
 189         local cc=($(tc-getCC))
 190         local cxx=($(tc-getCXX))
 191         local ld=($(tc-getLD))
 192         local nm=($(tc-getNM))
 193         local readelf=($(tc-getREADELF))
 194
 195         # Use absolute paths. Non-absolute paths are mishandled by GYP.
 196         ar[0]=$(type -P ${ar[0]})
 197         cc[0]=$(type -P ${cc[0]})
 198         cxx[0]=$(type -P ${cxx[0]})
 199         ld[0]=$(type -P ${ld[0]})
 200         nm[0]=$(type -P ${nm[0]})
 201         readelf[0]=$(type -P ${readelf[0]})
 202
 203         sed \
 204                 -e "s:<!(which ar):${ar[@]}:" \
 205                 -e "s:<!(which clang):${cc[@]}:" \
 206                 -e "s:<!(which clang++):${cxx[@]}:" \
 207                 -e "s:<!(which ld):${ld[@]}:" \
 208                 -e "s:<!(which nm):${nm[@]}:" \
 209                 -e "s:<!(which readelf):${readelf[@]}:" \
 210                 -i gyp/common.gypi || die
 211
 212         # https://github.com/google/mozc/issues/489
 213         sed \
 214                 -e "/'-lc++'/d" \
 215                 -e "/'-stdlib=libc++'/d" \
 216                 -i gyp/common.gypi || die
 217 }
 218
 219 src_configure() {
 220         if use debug; then
 221                 BUILD_TYPE="Debug"
 222         else
 223                 BUILD_TYPE="Release"
 224         fi
 225
 226         local gyp_arguments=()
 227
 228         if tc-is-gcc; then
 229                 gyp_arguments+=(-D compiler_host=gcc -D compiler_target=gcc)
 230         elif tc-is-clang; then
 231                 gyp_arguments+=(-D compiler_host=clang -D compiler_target=clang)
 232         else
 233                 gyp_arguments+=(-D compiler_host=unknown -D compiler_target=unknown)
 234         fi
 235
 236         gyp_arguments+=(-D debug_extra_cflags=)
 237         gyp_arguments+=(-D release_extra_cflags=)
 238
 239         gyp_arguments+=(-D use_fcitx=$(usex fcitx4 YES NO))
 240         gyp_arguments+=(-D use_fcitx5=$(usex fcitx5 YES NO))
 241         gyp_arguments+=(-D use_libibus=$(usex ibus 1 0))
 242         gyp_arguments+=(-D use_libprotobuf=1)
 243         gyp_arguments+=(-D use_system_abseil_cpp=1)
 244         gyp_arguments+=(-D use_system_gtest=$(usex test 1 0))
 245         gyp_arguments+=(-D use_system_jsoncpp=$(usex test 1 0))
 246         gyp_arguments+=(-D enable_gtk_renderer=$(usex renderer 1 0))
 247
 248         gyp_arguments+=(-D server_dir="${EPREFIX}/usr/libexec/mozc")
 249         gyp_arguments+=(-D document_dir="${EPREFIX}/usr/libexec/mozc/documents")
 250
 251         if use ibus; then
 252                 gyp_arguments+=(-D ibus_mozc_path="${EPREFIX}/usr/libexec/ibus-engine-mozc")
 253                 gyp_arguments+=(-D ibus_mozc_icon_path="${EPREFIX}/usr/share/ibus-mozc/product_icon.png")
 254         fi
 255
 256         unset AR CC CXX LD NM READELF
 257
 258         execute "${PYTHON}" build_mozc.py gyp \
 259                 --gypdir="${EPREFIX}/usr/bin" \
 260                 --server_dir="${EPREFIX}/usr/libexec/mozc" \
 261                 --verbose \
 262                 $(usex gui "" --noqt) \
 263                 -- "${gyp_arguments[@]}" || die "Configuration failed"
 264 }
 265
 266 src_compile() {
 267         local targets=(server/server.gyp:mozc_server)
 268         if use emacs; then
 269                 targets+=(unix/emacs/emacs.gyp:mozc_emacs_helper)
 270         fi
 271         if use fcitx4; then
 272                 targets+=(unix/fcitx/fcitx.gyp:fcitx-mozc)
 273         fi
 274         if use fcitx5; then
 275                 targets+=(unix/fcitx5/fcitx5.gyp:fcitx5-mozc)
 276         fi
 277         if use gui; then
 278                 targets+=(gui/gui.gyp:mozc_tool)
 279         fi
 280         if use ibus; then
 281                 targets+=(unix/ibus/ibus.gyp:ibus_mozc)
 282         fi
 283         if use renderer; then
 284                 targets+=(renderer/renderer.gyp:mozc_renderer)
 285         fi
 286         if use test; then
 287                 targets+=(gyp/tests.gyp:unittests)
 288         fi
 289
 290         execute "${PYTHON}" build_mozc.py build -c ${BUILD_TYPE} -v "${targets[@]}" || die "Building failed"
 291
 292         if use emacs; then
 293                 elisp-compile unix/emacs/*.el
 294         fi
 295 }
 296
 297 src_test() {
 298         execute "${PYTHON}" build_mozc.py runtests -c ${BUILD_TYPE} --test_jobs 1 || die "Testing failed"
 299 }
 300
 301 src_install() {
 302         exeinto /usr/libexec/mozc
 303         doexe out_linux/${BUILD_TYPE}/mozc_server
 304
 305         if use gui; then
 306                 doexe out_linux/${BUILD_TYPE}/mozc_tool
 307         fi
 308
 309         if use renderer; then
 310                 doexe out_linux/${BUILD_TYPE}/mozc_renderer
 311         fi
 312
 313         insinto /usr/libexec/mozc/documents
 314         doins data/installer/credits_en.html
 315
 316         if use emacs; then
 317                 dobin out_linux/${BUILD_TYPE}/mozc_emacs_helper
 318                 elisp-install ${PN} unix/emacs/*.{el,elc}
 319                 elisp-site-file-install "${FILESDIR}/${SITEFILE}" ${PN}
 320         fi
 321
 322         if use fcitx4; then
 323                 exeinto /usr/$(get_libdir)/fcitx
 324                 doexe out_linux/${BUILD_TYPE}/fcitx-mozc.so
 325
 326                 insinto /usr/share/fcitx/addon
 327                 doins unix/fcitx/fcitx-mozc.conf
 328
 329                 insinto /usr/share/fcitx/inputmethod
 330                 doins unix/fcitx/mozc.conf
 331
 332                 insinto /usr/share/fcitx/mozc/icon
 333                 newins data/images/product_icon_32bpp-128.png mozc.png
 334                 local image
 335                 for image in ../../fcitx-${PN}/src/data/images/unix/ui-*.png; do
 336                         newins "${image}" "mozc-${image#../../fcitx-${PN}/src/data/images/unix/ui-}"
 337                 done
 338
 339                 local locale mo_file
 340                 for mo_file in out_linux/${BUILD_TYPE}/gen/unix/fcitx/po/*.mo; do
 341                         locale="${mo_file##*/}"
 342                         locale="${locale%.mo}"
 343                         insinto /usr/share/locale/${locale}/LC_MESSAGES
 344                         newins "${mo_file}" fcitx-mozc.mo
 345                 done
 346         fi
 347         if use fcitx5; then
 348                 exeinto /usr/$(get_libdir)/fcitx5
 349                 doexe out_linux/${BUILD_TYPE}/fcitx5-mozc.so
 350
 351                 insinto /usr/share/fcitx5/addon
 352                 newins unix/fcitx5/mozc-addon.conf mozc.conf
 353
 354                 insinto /usr/share/fcitx5/inputmethod
 355                 doins unix/fcitx5/mozc.conf
 356
 357                 local orgfcitx5="org.fcitx.Fcitx5.fcitx-mozc"
 358                 newicon -s 128 data/images/product_icon_32bpp-128.png ${orgfcitx5}.png
 359                 newicon -s 128 data/images/product_icon_32bpp-128.png fcitx-mozc.png
 360                 newicon -s 32 data/images/unix/ime_product_icon_opensource-32.png ${orgfcitx5}.png
 361                 newicon -s 32 data/images/unix/ime_product_icon_opensource-32.png fcitx-mozc.png
 362                 for uiimg in ../../fcitx5-mozc/scripts/icons/ui-*.png; do
 363                         dimg=${uiimg#*ui-}
 364                         newicon -s 48 ${uiimg} ${orgfcitx5}-${dimg/_/-}
 365                         newicon -s 48 ${uiimg} fcitx-mozc-${dimg/_/-}
 366                 done
 367
 368                 local locale mo_file
 369                 for mo_file in unix/fcitx5/po/*.po; do
 370                         locale="${mo_file##*/}"
 371                         locale="${locale%.po}"
 372                         msgfmt ${mo_file} -o ${mo_file/.po/.mo} || die
 373                         insinto /usr/share/locale/${locale}/LC_MESSAGES
 374                         newins "${mo_file/.po/.mo}" fcitx5-mozc.mo
 375                 done
 376         fi
 377
 378         if use ibus; then
 379                 exeinto /usr/libexec
 380                 newexe out_linux/${BUILD_TYPE}/ibus_mozc ibus-engine-mozc
 381
 382                 insinto /usr/share/ibus/component
 383                 doins out_linux/${BUILD_TYPE}/gen/unix/ibus/mozc.xml
 384
 385                 insinto /usr/share/ibus-mozc
 386                 newins data/images/unix/ime_product_icon_opensource-32.png product_icon.png
 387                 local image
 388                 for image in data/images/unix/ui-*.png; do
 389                         newins "${image}" "${image#data/images/unix/ui-}"
 390                 done
 391         fi
 392 }
 393
 394 pkg_postinst() {
 395         elog
 396         elog "ENVIRONMENTAL VARIABLES"
 397         elog
 398         elog "MOZC_SERVER_DIRECTORY"
 399         elog "  Mozc server directory"
 400         elog "  Value used by default: \"${EPREFIX}/usr/libexec/mozc\""
 401         elog "MOZC_DOCUMENTS_DIRECTORY"
 402         elog "  Mozc documents directory"
 403         elog "  Value used by default: \"${EPREFIX}/usr/libexec/mozc/documents\""
 404         elog "MOZC_CONFIGURATION_DIRECTORY"
 405         elog "  Mozc configuration directory"
 406         elog "  Value used by default: \"~/.mozc\""
 407         elog
 408         if use emacs; then
 409                 elog
 410                 elog "USAGE IN EMACS"
 411                 elog
 412                 elog "mozc-mode is minor mode to input Japanese text using Mozc server."
 413                 elog "mozc-mode can be used via LEIM (Library of Emacs Input Method)."
 414                 elog
 415                 elog "In order to use mozc-mode by default, the following settings should be added to"
 416                 elog "Emacs init file (~/.emacs.d/init.el or ~/.emacs):"
 417                 elog
 418                 elog "  (require 'mozc)"
 419                 elog "  (set-language-environment \"Japanese\")"
 420                 elog "  (setq default-input-method \"japanese-mozc\")"
 421                 elog
 422                 elog "With the above settings, typing C-\\ (which is bound to \"toggle-input-method\""
 423                 elog "by default) will enable mozc-mode."
 424                 elog
 425                 elog "Alternatively, at run time, after loading mozc.el, mozc-mode can be activated by"
 426                 elog "calling \"set-input-method\" and entering \"japanese-mozc\"."
 427                 elog
 428
 429                 elisp-site-regen
 430         fi
 431         xdg_pkg_postinst
 432 }
 433
 434 pkg_postrm() {
 435         if use emacs; then
 436                 elisp-site-regen
 437         fi
 438         xdg_pkg_postrm
 439 }