app-i18n/zh-autoconvert/zh-autoconvert-0.3.16_p7.ebuild

   1 # Copyright 1999-2021 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit multilib
   7
   8 MY_PV="${PV/_p/-}"
   9
  10 DESCRIPTION="Chinese HZ/GB/BIG5/UNI/UTF7/UTF8 encodings auto-converter"
  11 HOMEPAGE="https://packages.debian.org/stable/source/zh-autoconvert"
  12 SRC_URI="https://salsa.debian.org/chinese-team/zh-autoconvert/-/archive/debian/${MY_PV}/zh-autoconvert-debian-${MY_PV}.tar.gz"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86"
  17 IUSE="static-libs"
  18
  19 S="${WORKDIR}/${PN}-debian-${MY_PV}"
  20
  21 PATCHES=(
  22 "${S}/debian/patches/001-build-static-library.patch"
  23 "${S}/debian/patches/002-chdir-before-symlink.patch"
  24 "${S}/debian/patches/003-strip-binaries.patch"
  25 "${S}/debian/patches/004-delete-empty-default-label-for-gcc-3.4.patch"
  26 "${S}/debian/patches/005-move-plugins-to-usr-lib.patch"
  27 "${S}/debian/patches/006-add-exit.patch"
  28 "${S}/debian/patches/007-migrate-xchat-plugins-to-gtk2.patch"
  29 "${S}/debian/patches/008-add-missing-includes.patch"
  30 "${S}/debian/patches/009-add-placeholder-README-for-lib.patch"
  31 "${S}/debian/patches/010-create-destination-directories-in-Makefile.patch"
  32 "${S}/debian/patches/011-do-not-strip-binaries.patch"
  33 "${S}/debian/patches/012-hardening.patch"
  34 "${S}/debian/patches/013-fix-xchat-plugin-compile-warnings.patch"
  35 "${S}/debian/patches/014-convert-comments-to-utf8.patch"
  36 "${S}/debian/patches/015-convert-docs-to-utf8.patch"
  37 "${S}/debian/patches/016-not-compile-xchat-plugin.patch"
  38 )
  39
  40 src_prepare() {
  41         default
  42
  43         # don't build xchat-plugins
  44         # so don't depend on gtk+-1.2 anymore
  45         sed -i -e 's/[ ]*xchat-plugins$//' Makefile
  46 }
  47
  48 src_compile() {
  49         emake -j1 || die "emake failed"
  50 }
  51
  52 src_install() {
  53         dobin autogb
  54         dosym autogb /usr/bin/autob5
  55
  56         if use static-libs; then
  57                 dolib.a lib/libhz.a
  58         fi
  59
  60         dolib.so lib/libhz.so.0.0
  61
  62         dosym libhz.so.0.0 /usr/$(get_libdir)/libhz.so.0
  63         dosym libhz.so.0 /usr/$(get_libdir)/libhz.so
  64
  65         insinto /usr/include
  66         doins include/*.h
  67 }