dev-build/gyp/gyp-99999999999999.ebuild

   1 # Copyright 2017-2023 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="8"
   5 PYTHON_COMPAT=( python3_{10..12} )
   6 DISTUTILS_SINGLE_IMPL="1"
   7 DISTUTILS_USE_PEP517=setuptools
   8
   9 inherit distutils-r1
  10
  11 DESCRIPTION="GYP (Generate Your Projects) meta-build system"
  12 HOMEPAGE="https://gyp.gsrc.io/ https://chromium.googlesource.com/external/gyp"
  13
  14 if [[ "${PV}" == "99999999999999" ]]; then
  15         inherit git-r3
  16         EGIT_REPO_URI="https://chromium.googlesource.com/external/gyp"
  17 fi
  18
  19 LICENSE="BSD"
  20 SLOT="0"
  21
  22 RDEPEND="$(python_gen_cond_dep 'dev-python/six[${PYTHON_USEDEP}]')"
  23
  24 python_prepare_all() {
  25         distutils-r1_python_prepare_all
  26
  27         sed -e "s/'  Linux %s' % ' '\.join(platform.linux_distribution())/'  Linux'/" -i gyptest.py || die
  28         sed -e "s/the_dict_key is 'variables'/the_dict_key == 'variables'/" -i pylib/gyp/input.py || die
  29         sed \
  30                 -e "s/os\.environ\['PRESERVE'\] is not ''/os.environ['PRESERVE'] != ''/" \
  31                 -e "s/conditions is ()/conditions == ()/" \
  32                 -i test/lib/TestCmd.py || die
  33 }
  34
  35 python_test() {
  36         # More errors with DeprecationWarnings enabled.
  37         local -x PYTHONWARNINGS=""
  38
  39         "${PYTHON}" gyptest.py --all --verbose
  40 }