app-i18n/libime/libime-9999.ebuild

   1 # Copyright 1999-2023 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit cmake git-r3
   7
   8 EGIT_REPO_URI="https://github.com/fcitx/libime.git"
   9 EGIT_SUBMODULES=( 'src/libime/kenlm' )
  10 SRC_URI="
  11         https://download.fcitx-im.org/data/lm_sc.arpa-20230712.tar.xz -> ${PN}-lm_sc.arpa-20230712.tar.xz
  12         https://download.fcitx-im.org/data/dict-20230412.tar.xz -> ${PN}-dict-20230412.tar.xz
  13         https://download.fcitx-im.org/data/table.tar.gz -> ${PN}-table.tar.gz
  14 "
  15 DESCRIPTION="Fcitx5 Next generation of fcitx "
  16 HOMEPAGE="https://fcitx-im.org/"
  17 LICENSE="LGPL-2+"
  18 SLOT="5"
  19 IUSE="doc test"
  20 RESTRICT="!test? ( test )"
  21
  22 RDEPEND="
  23         >=app-i18n/fcitx-5.1.5:5
  24         app-arch/zstd:=
  25         dev-libs/boost:=
  26 "
  27 DEPEND="${RDEPEND}"
  28 BDEPEND="
  29         kde-frameworks/extra-cmake-modules:0
  30         virtual/pkgconfig
  31         doc? (
  32                 app-text/doxygen
  33                 media-gfx/graphviz[svg]
  34         )
  35 "
  36
  37 src_prepare() {
  38         ln -sv "${DISTDIR}/${PN}-lm_sc.arpa-20230712.tar.xz" "${S}/data/lm_sc.arpa-20230712.tar.xz" || die
  39         ln -sv "${DISTDIR}/${PN}-dict-20230412.tar.xz" "${S}/data/dict-20230412.tar.xz" || die
  40         ln -sv "${DISTDIR}/${PN}-table.tar.gz" "${S}/data/table.tar.gz" || die
  41         default
  42 }
  43
  44 src_configure() {
  45         local mycmakeargs=(
  46                 -DENABLE_DOC=$(usex doc)
  47                 -DENABLE_TEST=$(usex test)
  48         )
  49         cmake_src_configure
  50 }
  51
  52 src_compile() {
  53         cmake_src_compile
  54         use doc && cmake_src_compile doc
  55 }
  56
  57 src_install() {
  58         cmake_src_install
  59         use doc && dodoc -r "${BUILD_DIR}"/doc/*
  60 }