gui-wm/swayfx/swayfx-0.3.2.ebuild

   1 # Copyright 1999-2022 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit meson optfeature
   7
   8 DESCRIPTION="SwayFX: Sway, but with eye candy!"
   9 HOMEPAGE="https://github.com/WillPower3309/swayfx"
  10 SRC_URI="https://github.com/WillPower3309/swayfx/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="MIT"
  13 SLOT="0"
  14 KEYWORDS="~amd64"
  15 IUSE="grimshot +man +swaybar +swaynag tray wallpapers X"
  16
  17 DEPEND="
  18         >=dev-libs/json-c-0.13:0=
  19         >=dev-libs/libinput-1.21.0:0=
  20         sys-auth/seatd:=
  21         dev-libs/libpcre
  22         >=dev-libs/wayland-1.20.0
  23         x11-libs/cairo
  24         x11-libs/libxkbcommon
  25         x11-libs/pango
  26         x11-libs/pixman
  27         media-libs/mesa[gles2,libglvnd(+)]
  28         swaybar? ( x11-libs/gdk-pixbuf:2 )
  29         tray? ( || (
  30                 sys-apps/systemd
  31                 sys-auth/elogind
  32                 sys-libs/basu
  33         ) )
  34         wallpapers? ( gui-apps/swaybg[gdk-pixbuf(+)] )
  35         X? ( x11-libs/libxcb:0= )
  36 "
  37 DEPEND+="
  38         >=gui-libs/wlroots-0.16:=[X?]
  39         <gui-libs/wlroots-0.17:=[X?]
  40 "
  41 RDEPEND="
  42         x11-misc/xkeyboard-config
  43         grimshot? (
  44                 app-misc/jq
  45                 gui-apps/grim
  46                 gui-apps/slurp
  47                 gui-apps/wl-clipboard
  48                 x11-libs/libnotify
  49         )
  50         !!gui-wm/sway
  51         ${DEPEND}
  52 "
  53 BDEPEND="
  54         >=dev-libs/wayland-protocols-1.24
  55         >=dev-build/meson-0.60.0
  56         virtual/pkgconfig
  57 "
  58 BDEPEND+="man? ( >=app-text/scdoc-1.9.3 )"
  59 REQUIRED_USE="tray? ( swaybar )"
  60
  61 src_prepare() {
  62         eapply "${FILESDIR}/${P}-im.patch"
  63         default
  64 }
  65
  66 src_configure() {
  67         local emesonargs=(
  68                 $(meson_feature man man-pages)
  69                 $(meson_feature tray)
  70                 $(meson_feature X xwayland)
  71                 $(meson_feature swaybar gdk-pixbuf)
  72                 $(meson_use swaynag)
  73                 $(meson_use swaybar)
  74                 $(meson_use wallpapers default-wallpaper)
  75                 -Dfish-completions=true
  76                 -Dzsh-completions=true
  77                 -Dbash-completions=true
  78         )
  79
  80         meson_src_configure
  81 }
  82
  83 src_install() {
  84         meson_src_install
  85
  86         if use grimshot; then
  87                 doman contrib/grimshot.1
  88                 dobin contrib/grimshot
  89         fi
  90 }
  91
  92 pkg_postinst() {
  93         optfeature_header "There are several packages that may be useful with swayfx:"
  94         optfeature "wallpaper utility" gui-apps/swaybg
  95         optfeature "idle management utility" gui-apps/swayidle
  96         optfeature "simple screen locker" gui-apps/swaylock
  97         optfeature "lightweight notification daemon" gui-apps/mako
  98         echo
  99         einfo "For a list of additional addons and tools usable with sway please"
 100         einfo "visit the offical wiki at:"
 101         einfo "https://github.com/swaywm/sway/wiki/Useful-add-ons-for-sway"
 102         einfo "Please note that some of them might not (yet) available on gentoo"
 103 }