media-libs/phonon-mpv/phonon-mpv-0.1.0.ebuild

   1 # Copyright 2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit cmake multibuild
   7
   8 DESCRIPTION="Phonon Backend using MPV Player(libmpv)"
   9 HOMEPAGE="https://github.com/OpenProgger/phonon-mpv"
  10 SRC_URI="
  11         https://github.com/OpenProgger/phonon-mpv/archive/refs/tags/v${PV}.tar.gz
  12                 -> ${P}.tar.gz
  13 "
  14
  15 LICENSE="LGPL-2.1+"
  16 SLOT="0"
  17 KEYWORDS="~amd64"
  18
  19 IUSE="+qt5 qt6"
  20 REQUIRED_USE="|| ( qt5 qt6 )"
  21
  22 DEPEND="
  23         >=media-libs/phonon-4.12.0[qt5=,qt6=]
  24         >=media-video/mpv-0.29.0:=
  25         qt5? (
  26                 dev-qt/qtcore:5
  27                 dev-qt/qtgui:5
  28                 dev-qt/qtwidgets:5
  29                 dev-qt/qtx11extras:5
  30         )
  31         qt6? (
  32                 dev-qt/qtbase:6[gui,opengl,widgets,X]
  33         )
  34 "
  35 RDEPEND="${DEPEND}"
  36 BDEPEND="
  37         kde-frameworks/extra-cmake-modules
  38         virtual/pkgconfig
  39 "
  40
  41 pkg_setup() {
  42         MULTIBUILD_VARIANTS=( $(usev qt5) $(usev qt6) )
  43 }
  44
  45 src_configure() {
  46         myconfigure() {
  47                 local mycmakeargs=(
  48                         -DQT_MAJOR_VERSION=${MULTIBUILD_VARIANT/qt/}
  49                         -DPHONON_BUILD_${MULTIBUILD_VARIANT^^}=ON
  50                 )
  51                 if [[ ${MULTIBUILD_VARIANT} == qt6 ]]; then
  52                         mycmakeargs+=( -DPHONON_BUILD_QT5=OFF )
  53                 else
  54                         mycmakeargs+=( -DPHONON_BUILD_QT6=OFF )
  55                 fi
  56                 cmake_src_configure
  57         }
  58         multibuild_foreach_variant myconfigure
  59 }
  60
  61 src_compile() {
  62         multibuild_foreach_variant cmake_src_compile
  63 }
  64
  65 src_install() {
  66         multibuild_foreach_variant cmake_src_install
  67 }