sys-apps/aptly/aptly-1.5.0.ebuild

   1 # Copyright 1999-2023 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit bash-completion-r1 go-module systemd
   7
   8 DESCRIPTION="A swiss army knife for Debian repository management"
   9 HOMEPAGE="https://github.com/aptly-dev/aptly"
  10 SRC_URI="https://github.com/aptly-dev/aptly/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  11 SRC_URI+=" https://github.com/liuyujielol/gentoo-go-deps/releases/download/${P}/${P}-deps.tar.xz"
  12
  13 LICENSE="MIT"
  14 SLOT="0"
  15 KEYWORDS="~amd64"
  16 RESTRICT="test" # fails
  17
  18 RDEPEND="
  19         acct-group/aptly
  20         acct-user/aptly
  21 "
  22
  23 src_compile() {
  24         ego build -mod=readonly -o cmd/aptly -ldflags "-X main.Version=${PV}"
  25 }
  26
  27 src_test() {
  28         ego test -work ./...
  29 }
  30
  31 src_install() {
  32         einstalldocs
  33         dobin cmd/aptly
  34         doman man/aptly.1
  35         dobashcomp completion.d/aptly
  36         insinto /usr/share/zsh/site-functions
  37         doins completion.d/_aptly
  38         systemd_dounit aptly-api.service
  39         systemd_dounit aptly.service
  40         newinitd "${FILESDIR}"/aptly.initd aptly
  41         newconfd "${FILESDIR}"/aptly.confd aptly
  42         newinitd "${FILESDIR}"/aptly-api.initd aptly-api
  43         newconfd "${FILESDIR}"/aptly-api.confd aptly-api
  44
  45         diropts -o aptly -g aptly -m 0700
  46         keepdir /etc/aptly
  47         insopts -o aptly -g aptly -m 0644
  48         insinto /etc/aptly
  49         doins "${FILESDIR}"/aptly.conf
  50 }