app-admin/enpass/enpass-6.10.1.1661.ebuild

   1 # Copyright 2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit desktop unpacker xdg
   7
   8 DESCRIPTION="A cross-platform, complete password management solution."
   9 HOMEPAGE="https://www.enpass.io"
  10 SRC_URI="https://apt.enpass.io/pool/main/e/${PN}/${PN}_${PV}_amd64.deb"
  11
  12 S="${WORKDIR}"
  13
  14 LICENSE="SINEW-EULA"
  15 SLOT="0"
  16 KEYWORDS="~amd64"
  17
  18 RESTRICT="bindist mirror strip"
  19
  20 # Dependencies
  21 #
  22 # objdump -p ./Enpass | grep NEEDED | awk '{print $2}' | xargs equery b | sort | uniq
  23
  24 RDEPEND="
  25         app-arch/xz-utils
  26         dev-libs/glib:2
  27         media-libs/fontconfig
  28         media-libs/freetype:2
  29         media-libs/libglvnd
  30         net-print/cups
  31         sys-apps/dbus
  32         sys-apps/util-linux
  33         sys-libs/zlib
  34         x11-libs/gtk+:3
  35         x11-libs/libICE
  36         x11-libs/libSM
  37         x11-libs/libX11
  38         x11-libs/libXScrnSaver
  39         x11-libs/libxcb
  40         x11-libs/libxkbcommon
  41         x11-libs/pango
  42         x11-libs/xcb-util-image
  43         x11-libs/xcb-util-keysyms
  44         x11-libs/xcb-util-renderutil
  45         x11-libs/xcb-util-wm"
  46
  47 QA_PREBUILT="opt/enpass/*"
  48
  49 src_prepare() {
  50         default
  51         gzip -d "${S}"/usr/share/doc/enpass/changelog.gz || die
  52 }
  53
  54 src_install() {
  55         domenu "${S}"/usr/share/applications/enpass.desktop
  56         dodoc "${S}"/usr/share/doc/enpass/changelog
  57
  58         insinto /opt/enpass
  59         doins -r "${S}"/opt/enpass/.
  60         fperms +x /opt/enpass/{Enpass,importer_enpass,wifisyncserver_bin}
  61
  62         insinto /usr/share/mime/packages
  63         doins "${S}"/usr/share/mime/packages/application-enpass.xml
  64
  65         local size
  66         for size in 16 22 24 32 48; do
  67                 doicon -c status -s ${size} "${S}"/usr/share/icons/hicolor/${size}x${size}/status/enpass-status.png
  68                 doicon -c status -s ${size} "${S}"/usr/share/icons/hicolor/${size}x${size}/status/enpass-status-dark.png
  69         done
  70
  71         for size in 16 24 32 48 64 96 128 256; do
  72                 doicon -s ${size} "${S}"/usr/share/icons/hicolor/${size}x${size}/apps/enpass.png
  73         done
  74 }