app-text/imewlconverter/imewlconverter-9999.ebuild

   1 # Copyright 2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 DOTNET_PKG_COMPAT="8.0"
   7 NUGETS="
   8         sharpziplib@1.4.2
   9         utf.unknown@2.5.1
  10 "
  11
  12 inherit dotnet-pkg
  13
  14 DESCRIPTION="An open source and free input method dictionary conversion program"
  15 HOMEPAGE="https://github.com/studyzy/imewlconverter"
  16
  17 if [[ "${PV}" == 9999 ]] ; then
  18         inherit git-r3
  19
  20         EGIT_REPO_URI="https://github.com/studyzy/imewlconverter.git"
  21 else
  22         SRC_URI="https://github.com/studyzy/imewlconverter/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  23
  24         KEYWORDS="~amd64"
  25 fi
  26
  27 SRC_URI+=" ${NUGET_URIS} "
  28
  29 LICENSE="GPL-3+"
  30 SLOT="0"
  31
  32 DOTNET_PKG_PROJECTS=( src/ImeWlConverterCmd/ImeWlConverterCmd.csproj )
  33
  34 src_unpack() {
  35         dotnet-pkg_src_unpack
  36
  37         if [[ "${PV}" == 9999 ]] ; then
  38                 git-r3_src_unpack
  39         fi
  40 }
  41
  42 src_prepare() {
  43         sed -i -E "s|<Version>.+</Version>|<Version>${PV}</Version>|" src/ImeWlConverterCmd/ImeWlConverterCmd.csproj
  44         sed -i -e 's/dotnet ImeWlConverterCmd.dll/ImeWlConverterCmd/g' src/ImeWlConverterCmd/Program.cs
  45
  46         dotnet-pkg_src_prepare
  47 }
  48
  49 src_install() {
  50         mv "${DOTNET_PKG_OUTPUT}/Readme.txt" CHANGELOG || die
  51
  52         dotnet-pkg-base_install
  53         dotnet-pkg-base_dolauncher "/usr/share/${P}/ImeWlConverterCmd"
  54
  55         einstalldocs
  56 }