dev-util/patchelf-liblol/patchelf-liblol-0.1.4.ebuild

   1 # Copyright 2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit autotools
   7
   8 PATCHELF_PN=patchelf
   9 PATCHELF_PV=0.18.0
  10 PATCHELF_P="${PATCHELF_PN}-${PATCHELF_PV}"
  11
  12 DESCRIPTION="patchelf patched for building libLoL only"
  13 HOMEPAGE="https://github.com/NixOS/patchelf https://liblol.aosc.io"
  14 SRC_URI="https://github.com/NixOS/${PATCHELF_PN}/archive/${PATCHELF_PV}.tar.gz -> ${PATCHELF_P}.tar.gz"
  15 S="${WORKDIR}/${PATCHELF_P}"
  16
  17 LICENSE="GPL-3"
  18 SLOT="0"
  19 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~x86 ~amd64-linux ~riscv-linux ~x86-linux"
  20
  21 PATCHES=(
  22         # "${FILESDIR}"/${PATCHELF_PN}-glibc-dt-mips-xhash.patch  # conflicts with liblol
  23         "${FILESDIR}"/${PATCHELF_PN}-0.18.0-alpha.patch
  24         "${FILESDIR}"/${PATCHELF_P}-liblol-${PV}.patch
  25 )
  26
  27 src_prepare() {
  28         # rm src/elf.h || die  # this file is touched by the liblol patch
  29         default
  30
  31         sed -i \
  32                 -e 's:-Werror::g' \
  33                 configure.ac || die
  34
  35         eautoreconf
  36 }
  37
  38 src_configure() {
  39         local myeconfargs=(
  40                 --program-suffix=-liblol
  41         )
  42         econf "${myeconfargs[@]}"
  43 }
  44
  45 src_install() {
  46         default
  47
  48         # prevent collision with the vanilla patchelf
  49         rm -rf "${D}/usr/share/zsh"
  50 }