app-i18n/fcitx5-chinese-addons/fcitx5-chinese-addons-5.0.6-r1.ebuild

   1 # Copyright 1999-2021 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit cmake xdg
   7
   8 if [[ "${PV}" == 9999 ]]; then
   9         inherit git-r3
  10         EGIT_REPO_URI="https://github.com/fcitx/fcitx5-chinese-addons.git"
  11         KEYWORDS=""
  12 else
  13         SRC_URI="https://github.com/fcitx/fcitx5-chinese-addons/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
  14         KEYWORDS="~amd64 ~x86"
  15 fi
  16
  17 SRC_URI+="
  18 https://download.fcitx-im.org/data/py_stroke-20121124.tar.gz -> fcitx-data-py_stroke-20121124.tar.gz
  19 https://download.fcitx-im.org/data/py_table-20121124.tar.gz -> fcitx-data-py_table-20121124.tar.gz
  20 "
  21
  22 DESCRIPTION="Addons related to Chinese, including IME previous bundled inside fcitx4."
  23 HOMEPAGE="https://github.com/fcitx/fcitx5-chinese-addons"
  24
  25 LICENSE="BSD-1 GPL-2+ LGPL-2+ MIT"
  26 SLOT="5"
  27 IUSE="+opencc +gui browser test"
  28 REQUIRED_USE=""
  29
  30 RDEPEND="app-i18n/fcitx5
  31         app-i18n/libime
  32         opencc? ( app-i18n/opencc:= )
  33         gui? (
  34                 dev-qt/qtcore:5
  35                 dev-qt/qtdbus:5
  36                 dev-qt/qtconcurrent:5
  37                 app-i18n/fcitx5-qt[qt5,-only_plugin]
  38                 browser? (
  39                         dev-qt/qtwebengine:5
  40                 )
  41         )"
  42 DEPEND="${RDEPEND}
  43         kde-frameworks/extra-cmake-modules:5
  44         virtual/pkgconfig"
  45
  46 src_prepare() {
  47         ln -s "${DISTDIR}/fcitx-data-py_stroke-20121124.tar.gz" modules/pinyinhelper/py_stroke-20121124.tar.gz || die
  48         ln -s "${DISTDIR}/fcitx-data-py_table-20121124.tar.gz" modules/pinyinhelper/py_table-20121124.tar.gz || die
  49         cmake_src_prepare
  50 }
  51
  52 src_configure() {
  53         local mycmakeargs=(
  54                 -DCMAKE_INSTALL_LIBDIR="${EPREFIX}/usr/$(get_libdir)"
  55                 -DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}/etc"
  56                 -DENABLE_GUI=$(usex gui)
  57                 -DENABLE_OPENCC=$(usex opencc)
  58                 -DENABLE_BROWSER=$(usex browser)
  59                 -DUSE_WEBKIT=no
  60         )
  61         cmake_src_configure
  62 }