net-dns/ddns-go/ddns-go-6.7.7.ebuild

   1 # Copyright 2023-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit go-module systemd
   7
   8 DESCRIPTION="Automatically obtain your public IP address and set to your domain name service."
   9 HOMEPAGE="https://github.com/jeessy2/ddns-go"
  10 SRC_URI="https://github.com/jeessy2/ddns-go/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
  11         https://github.com/Puqns67/gentoo-deps/releases/download/${P}/${P}-vendor.tar.xz"
  12
  13 LICENSE="MIT BSD"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~riscv"
  16
  17 PATCHES=(
  18         "${FILESDIR}/${PN}-6.7.2-remove-update-support.patch"
  19         "${FILESDIR}/${PN}-6.6.2-remove-service-management-support.patch"
  20         "${FILESDIR}/${PN}-6.7.7-build-deps-tidy.patch"
  21 )
  22
  23 src_compile() {
  24         ego build \
  25                 -trimpath \
  26                 -ldflags="-s -w -linkmode external \
  27                         -X 'main.version=${PV} (Gentoo)' \
  28                         -X 'main.buildTime=$(date -u +"%Y-%m-%dT%H:%M:%SZ")'" \
  29                 -o "${PN}" \
  30                 .
  31 }
  32
  33 src_install() {
  34         dobin "${PN}"
  35         systemd_dounit "${FILESDIR}/${PN}.service"
  36         systemd_newunit "${FILESDIR}/${PN}_at.service" "${PN}@.service"
  37         systemd_dounit "${FILESDIR}/${PN}-web.service"
  38         keepdir "/etc/${PN}"
  39 }