www-apps/follow-bin/follow-bin-0.2.8_beta0.ebuild

   1 # Copyright 2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit desktop xdg
   7
   8 MY_PV=$(ver_cut 1-3)-$(ver_cut 4).$(ver_cut 5)
   9
  10 DESCRIPTION="Next generation information browser"
  11 HOMEPAGE="
  12         https://follow.is/
  13         https://github.com/RSSNext/Follow
  14 "
  15 SRC_URI="
  16         https://github.com/RSSNext/Follow/releases/download/v${MY_PV}/Follow-${MY_PV}-linux-x64.AppImage -> ${P}.AppImage
  17 "
  18
  19 S="${WORKDIR}"
  20 LICENSE="GPL-3"
  21 SLOT="0"
  22 KEYWORDS="~amd64"
  23
  24 RDEPEND="
  25         dev-libs/nss
  26         media-libs/alsa-lib
  27         media-libs/mesa
  28         x11-libs/gtk+:3[X,cups]
  29         x11-libs/libxkbcommon
  30 "
  31
  32 src_unpack() {
  33         mkdir -p "${S}" || die
  34         cp "${DISTDIR}/${P}.AppImage" "${S}" || die
  35
  36         cd "${S}" || die         # "appimage-extract" unpacks to current directory.
  37         chmod +x "${S}/${P}.AppImage" || die
  38         "${S}/${P}.AppImage" --appimage-extract || die
  39 }
  40
  41 src_install() {
  42         cd "${S}/squashfs-root" || die
  43
  44         domenu Follow.desktop
  45         doicon -s 256 usr/share/icons/hicolor/256x256/apps/Follow.png
  46
  47         local toremove=(
  48                 .DirIcon
  49                 Follow.desktop
  50                 Follow.png
  51                 AppRun
  52                 LICENSES.chromium.html
  53                 usr
  54         )
  55         rm -f -r "${toremove[@]}" || die
  56
  57         local apphome="/opt/${PN}"
  58         insinto "${apphome}"
  59         doins -r .
  60
  61         fperms +x "${apphome}/Follow"
  62         dosym -r "${apphome}/Follow" "/opt/bin/Follow"
  63 }