app-office/wps-office/wps-office-11.1.0.10976-r1.ebuild

   1 # Copyright 1999-2023 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit unpacker xdg
   7
   8 MY_PV="$(ver_cut 4)"
   9
  10 DESCRIPTION="WPS Office is an office productivity suite, Here is the Chinese version"
  11 HOMEPAGE="http://www.wps.cn/product/wpslinux/ http://wps-community.org/"
  12
  13 KEYWORDS="~amd64 ~arm64 ~mips"
  14
  15 SRC_URI="
  16         amd64?  ( https://wps-linux-personal.wpscdn.cn/wps/download/ep/Linux2019/${MY_PV}/${PN}_${PV}_amd64.deb )
  17         arm64?  ( https://wps-linux-personal.wpscdn.cn/wps/download/ep/Linux2019/${MY_PV}/${PN}_${PV}_arm64.deb )
  18         loong?  ( https://wps-linux-personal.wpscdn.cn/wps/download/ep/Linux2019/${MY_PV}/${PN}_${PV}_loongarch64.deb )
  19         mips?   ( https://wps-linux-personal.wpscdn.cn/wps/download/ep/Linux2019/${MY_PV}/${PN}_${PV}_mips64el.deb )
  20 "
  21
  22 SLOT="0"
  23 RESTRICT="strip mirror bindist" # mirror as explained at bug #547372
  24 LICENSE="WPS-EULA"
  25 IUSE="big-endian systemd"
  26 REQUIRED_USE="mips? ( !big-endian )"
  27
  28 # Deps got from this (listed in order):
  29 # rpm -qpR wps-office-10.1.0.5707-1.a21.x86_64.rpm
  30 # ldd /opt/kingsoft/wps-office/office6/wps
  31 # ldd /opt/kingsoft/wps-office/office6/wpp
  32 RDEPEND="
  33         app-arch/bzip2:0
  34         app-arch/lz4
  35         app-arch/xz-utils
  36         dev-libs/expat
  37         dev-libs/glib:2
  38         dev-libs/libbsd
  39         dev-libs/libffi
  40         dev-libs/libgcrypt:0
  41         dev-libs/libgpg-error
  42         dev-libs/libpcre:3
  43         media-libs/flac
  44         media-libs/fontconfig:1.0
  45         media-libs/freetype:2
  46         media-libs/libogg
  47         media-libs/libsndfile
  48         media-libs/libvorbis
  49         media-libs/tiff-compat:4
  50         media-sound/pulseaudio
  51         net-libs/libasyncns
  52         net-print/cups
  53         sys-apps/attr
  54         sys-apps/dbus
  55         sys-apps/tcp-wrappers
  56         sys-apps/util-linux
  57         sys-libs/libcap
  58         sys-libs/zlib:0
  59         virtual/glu
  60         x11-libs/gtk+:2
  61         x11-libs/libICE
  62         x11-libs/libSM
  63         x11-libs/libX11
  64         x11-libs/libXau
  65         x11-libs/libxcb
  66         x11-libs/libXdmcp
  67         x11-libs/libXext
  68         x11-libs/libXrender
  69         x11-libs/libXtst
  70 "
  71 DEPEND=""
  72 BDEPEND=""
  73
  74 S="${WORKDIR}"
  75
  76 src_install() {
  77         exeinto /usr/bin
  78         exeopts -m0755
  79         doexe "${S}"/usr/bin/*
  80
  81         insinto /usr/share
  82         doins -r "${S}"/usr/share/{applications,desktop-directories,icons,mime,templates}
  83
  84         insinto /opt/kingsoft/wps-office
  85         use systemd || { rm "${S}"/opt/kingsoft/wps-office/office6/libdbus-1.so* || die ; }
  86         rm "${S}"/opt/kingsoft/wps-office/office6/libstdc++.so* || die
  87         doins -r "${S}"/opt/kingsoft/wps-office/{office6,templates}
  88
  89         fperms 0755 /opt/kingsoft/wps-office/office6/{wps,wpp,et,wpspdf,wpsoffice,promecefpluginhost,transerr,ksolaunch,wpscloudsvr}
  90 }