games-server/vintagestory-server/vintagestory-server-1.19.8.ebuild

   1 # Copyright 2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5 DOTNET_PKG_COMPAT=7.0
   6 inherit dotnet-pkg-base systemd
   7
   8 MY_PV="${PV/_rc/-rc.}"
   9 _CHANNEL="stable"
  10
  11 DESCRIPTION="Dedicated game server for Vintage Story"
  12 HOMEPAGE="https://www.vintagestory.at/"
  13 SRC_URI="https://cdn.vintagestory.at/gamefiles/${_CHANNEL}/vs_server_linux-x64_${MY_PV}.tar.gz"
  14 S="${WORKDIR}"
  15
  16 LICENSE="all-rights-reserved"
  17 SLOT="${PV}"
  18 KEYWORDS="-* ~amd64"
  19
  20 RDEPEND="
  21         acct-group/vintagestory
  22         acct-user/vintagestory
  23         app-misc/dtach
  24         net-misc/curl
  25         virtual/dotnet-sdk:${DOTNET_PKG_COMPAT}
  26 "
  27 BDEPEND="
  28         virtual/dotnet-sdk:${DOTNET_PKG_COMPAT}
  29 "
  30
  31 # Do NOT Distribute!
  32 RESTRICT="bindist mirror strip"
  33
  34 QA_PREBUILT="*"
  35 QA_PRESTRIPPED="*"
  36
  37 DOTNET_PKG_OUTPUT="${S}"
  38 INST_DIR="/opt/${PN}-${PV}"
  39
  40 src_prepare() {
  41         rm "${S}/server.sh" || die
  42
  43         envsubst < "${FILESDIR}/vintagestory-server.service" > "${S}/vintagestory-server-${PV}@.service" || die
  44         envsubst < "${FILESDIR}/vintagestory-server.initd" > "${S}/vintagestory-server-${PV}.initd" || die
  45
  46         default
  47 }
  48
  49 src_compile() {
  50         :
  51 }
  52
  53 src_install() {
  54         dotnet-pkg-base_install "${INST_DIR}"
  55         dotnet-pkg-base_dolauncher "${INST_DIR}/VintagestoryServer" "${P}"
  56
  57         newinitd "${S}/vintagestory-server-${PV}.initd" "vintagestory-server-${PV}"
  58         newconfd "${FILESDIR}"/vintagestory-server.confd "vintagestory-server-${PV}"
  59         systemd_dounit "${S}/vintagestory-server-${PV}@.service"
  60 }