x11-misc/picom-jonaburg/picom-jonaburg-8.ebuild

   1 # Copyright 1999-2021 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{9..11} )
   7 inherit meson python-any-r1 virtualx xdg
   8
   9 DESCRIPTION="jonaburg's picom fork with dual_kawase blur and rounded corners"
  10 HOMEPAGE="https://github.com/jonaburg/picom"
  11 SRC_URI="https://github.com/jonaburg/picom/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  12
  13 LICENSE="MPL-2.0 MIT"
  14 SLOT="0"
  15 KEYWORDS="~amd64"
  16 IUSE="+config-file dbus +doc +drm opengl pcre test"
  17
  18 REQUIRED_USE="test? ( dbus )" # avoid "DBus support not compiled in!"
  19 RESTRICT="test" # but tests require dbus_next
  20
  21 RDEPEND="
  22         dev-libs/libev
  23         dev-libs/uthash
  24         x11-libs/libX11
  25         x11-libs/libxcb
  26         x11-libs/libXext
  27         x11-libs/pixman
  28         x11-libs/xcb-util-image
  29         x11-libs/xcb-util-renderutil
  30         config-file? (
  31                 dev-libs/libconfig:=
  32                 dev-libs/libxdg-basedir
  33         )
  34         dbus? ( sys-apps/dbus )
  35         drm? ( x11-libs/libdrm )
  36         opengl? ( virtual/opengl )
  37         pcre? ( dev-libs/libpcre )
  38         !x11-misc/compton
  39         !x11-misc/picom"
  40 DEPEND="${RDEPEND}
  41         x11-base/xorg-proto"
  42 BDEPEND="virtual/pkgconfig
  43         doc? ( app-text/asciidoc )
  44         test? ( $(python_gen_any_dep 'dev-python/xcffib[${PYTHON_USEDEP}]') )
  45 "
  46
  47 DOCS=( README.md picom.sample.conf )
  48
  49 S="${WORKDIR}/picom-${PV}"
  50
  51 src_configure() {
  52         local emesonargs=(
  53                 $(meson_use config-file config_file)
  54                 $(meson_use dbus)
  55                 $(meson_use doc with_docs)
  56                 $(meson_use opengl)
  57                 $(meson_use pcre regex)
  58         )
  59
  60         meson_src_configure
  61 }
  62
  63 src_test() {
  64         virtx "${S}/tests/run_tests.sh" "${BUILD_DIR}/src/${PN}"
  65 }