x11-terms/wezterm-bin/wezterm-bin-20240203.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit xdg
   7
   8 MY_R="110809-5046fc22"
   9 MY_PV="${PV}-${MY_R}"
  10 MY_PN="${PN/-bin/}"
  11 MY_P="${MY_PN}-${MY_PV}"
  12
  13 DESCRIPTION="A terminal emulator and multiplexer implemented in Rust"
  14 HOMEPAGE="https://wezfurlong.org/wezterm"
  15
  16 SRC_URI="https://github.com/wez/wezterm/releases/download/${MY_PV}/${MY_PN}-${MY_PV}.Ubuntu20.04.tar.xz"
  17
  18 LICENSE="MIT"
  19 SLOT="0"
  20 KEYWORDS="-* ~amd64"
  21
  22 IUSE="wayland +X"
  23 REQUIRED_USE="|| ( wayland X )"
  24
  25 RDEPEND="
  26         sys-apps/dbus
  27         >=media-libs/fontconfig-2.12
  28         >=dev-libs/openssl-1.1
  29         wayland? (
  30                 dev-libs/wayland
  31                 dev-libs/wayland-protocols
  32         )
  33         X? (
  34                 >=x11-libs/libX11-1.7.5
  35                 >=x11-libs/libxcb-1.8
  36                 >=x11-libs/xcb-util-0.4
  37                 >=x11-libs/xcb-util-wm-0.4.1
  38                 >=x11-libs/xcb-util-image-0.2.1
  39                 >=x11-libs/xcb-util-keysyms-0.4
  40                 x11-libs/libxkbcommon[X]
  41         )
  42         x11-themes/hicolor-icon-theme
  43 "
  44
  45 QA_PREBUILT="*"
  46 S="${WORKDIR}/${MY_PN}"
  47
  48 src_install() {
  49         insinto /
  50         doins -r etc usr
  51
  52         fperms 0755 /usr/bin/{open-wezterm-here,strip-ansi-escapes,wezterm,wezterm-gui,wezterm-mux-server}
  53         fperms 0755 /etc/profile.d/${MY_PN}.sh
  54 }