dev-cpp/fbthrift/fbthrift-2024.11.04.00-r1.ebuild

   1 # Copyright 2022-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 # These must be bumped together:
   7 # dev-cpp/edencommon
   8 # dev-cpp/fb303
   9 # dev-cpp/fbthrift
  10 # dev-cpp/fizz
  11 # dev-cpp/folly
  12 # dev-cpp/mvfst
  13 # dev-cpp/wangle
  14 # dev-util/watchman
  15
  16 inherit cmake
  17
  18 DESCRIPTION="Facebook's branch of Apache Thrift (C++ bindings)"
  19 HOMEPAGE="https://github.com/facebook/fbthrift"
  20 SRC_URI="https://github.com/facebook/fbthrift/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
  21
  22 LICENSE="Apache-2.0"
  23 SLOT="0/${PV}"
  24 KEYWORDS="~amd64 ~arm64"
  25 IUSE="test"
  26
  27 # See https://github.com/facebook/fbthrift/issues/628
  28 RESTRICT="test"
  29
  30 DEPEND="
  31         app-arch/zstd:=
  32         ~dev-cpp/fizz-${PV}:=
  33         ~dev-cpp/folly-${PV}:=
  34         dev-cpp/gflags:=
  35         dev-cpp/glog:=[gflags]
  36         ~dev-cpp/mvfst-${PV}:=
  37         ~dev-cpp/wangle-${PV}:=
  38         dev-libs/boost:=[nls(+)]
  39         dev-libs/libevent:=
  40         dev-libs/libfmt:=
  41         dev-libs/openssl:=
  42         dev-libs/xxhash:=
  43         sys-libs/zlib:=
  44 "
  45 RDEPEND="
  46         ${DEPEND}
  47         test? ( dev-cpp/gtest )
  48 "
  49
  50 src_configure() {
  51         local mycmakeargs=(
  52                 -DCMAKE_INSTALL_DIR="$(get_libdir)/cmake/${PN}"
  53                 -DLIB_INSTALL_DIR="$(get_libdir)"
  54                 -Denable_tests=$(usex test 'ON' 'OFF')
  55                 -Wno-dev
  56         )
  57         cmake_src_configure
  58 }