dev-cpp/glibmm/glibmm-2.78.1.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5 PYTHON_COMPAT=( python3_{10..13} )
   6 inherit gnome.org meson-multilib python-any-r1
   7
   8 DESCRIPTION="C++ interface for glib2"
   9 HOMEPAGE="https://www.gtkmm.org https://gitlab.gnome.org/GNOME/glibmm"
  10
  11 LICENSE="LGPL-2.1+"
  12 SLOT="2.68"
  13 KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
  14 IUSE="gtk-doc debug test"
  15 RESTRICT="!test? ( test )"
  16
  17 RDEPEND="
  18         >=dev-libs/glib-2.77.0:2[${MULTILIB_USEDEP}]
  19         dev-libs/libsigc++:3[gtk-doc?,${MULTILIB_USEDEP}]
  20 "
  21 DEPEND="${RDEPEND}"
  22 BDEPEND="
  23         ${PYTHON_DEPS}
  24         virtual/pkgconfig
  25         gtk-doc? (
  26                 app-text/doxygen[dot]
  27                 dev-lang/perl
  28                 dev-libs/libxslt
  29         )
  30 "
  31
  32 PATCHES=( "${FILESDIR}"/${P}-libcxx-fix.patch )
  33
  34 src_prepare() {
  35         default
  36
  37         # giomm_tls_client requires FEATURES=-network-sandbox and glib-networking rdep
  38         sed -i -e '/giomm_tls_client/d' tests/meson.build || die
  39
  40         if ! use test; then
  41                 sed -i -e "/^subdir('tests')/d" meson.build || die
  42         fi
  43 }
  44
  45 multilib_src_configure() {
  46         local emesonargs=(
  47                 -Dwarnings=min
  48                 -Dbuild-deprecated-api=true
  49                 $(meson_native_use_bool gtk-doc build-documentation)
  50                 $(meson_use debug debug-refcounting)
  51                 -Dbuild-examples=false
  52         )
  53         meson_src_configure
  54 }