dev-cpp/glog/glog-0.5.0.ebuild

   1 # Copyright 2011-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="8"
   5
   6 inherit cmake-multilib
   7
   8 if [[ "${PV}" == "9999" ]]; then
   9         inherit git-r3
  10
  11         EGIT_REPO_URI="https://github.com/google/glog"
  12 fi
  13
  14 DESCRIPTION="Google Logging library"
  15 HOMEPAGE="https://github.com/google/glog"
  16 if [[ "${PV}" == "9999" ]]; then
  17         SRC_URI=""
  18 else
  19         SRC_URI="https://github.com/google/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  20 fi
  21
  22 LICENSE="BSD"
  23 SLOT="0"
  24 KEYWORDS="amd64 arm arm64 ~hppa ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux"
  25 IUSE="gflags +libunwind llvm-libunwind test"
  26 RESTRICT="!test? ( test )"
  27
  28 RDEPEND="gflags? ( dev-cpp/gflags:0=[${MULTILIB_USEDEP}] )
  29         libunwind? (
  30                 llvm-libunwind? ( llvm-runtimes/libunwind:0=[${MULTILIB_USEDEP}] )
  31                 !llvm-libunwind? ( sys-libs/libunwind:0=[${MULTILIB_USEDEP}] )
  32         )"
  33 DEPEND="${RDEPEND}
  34         test? ( >=dev-cpp/gtest-1.8.0[${MULTILIB_USEDEP}] )"
  35
  36 PATCHES=(
  37         "${FILESDIR}/${P}-IsGoogleLoggingInitialized_public.patch"
  38         "${FILESDIR}/${P}-vmodule_levels_changeability.patch"
  39 )
  40
  41 src_configure() {
  42         local mycmakeargs=(
  43                 -DBUILD_TESTING=$(usex test ON OFF)
  44                 -DWITH_CUSTOM_PREFIX=ON
  45                 -DWITH_GFLAGS=$(usex gflags ON OFF)
  46                 -DWITH_GTEST=$(usex test ON OFF)
  47                 -DWITH_UNWIND=$(usex libunwind ON OFF)
  48         )
  49         if use libunwind; then
  50                 mycmakeargs+=(
  51                         -DUnwind_PLATFORM_LIBRARY="${ESYSROOT}/usr/$(get_libdir)/libunwind.so"
  52                 )
  53         fi
  54
  55         cmake-multilib_src_configure
  56 }
  57
  58 src_test() {
  59         # See bug #832355
  60         cmake-multilib_src_test -j1
  61 }