dev-cpp/msgpack-cxx/msgpack-cxx-5.0.0.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit cmake
   7
   8 DESCRIPTION="MessagePack for C++"
   9 HOMEPAGE="https://msgpack.org/ https://github.com/msgpack/msgpack-c/"
  10 SRC_URI="https://github.com/msgpack/msgpack-c/releases/download/cpp-${PV}/${P}.tar.gz"
  11
  12 LICENSE="Boost-1.0"
  13 SLOT="0"
  14 KEYWORDS="amd64 ~arm arm64 ~riscv x86 ~amd64-linux ~x86-linux ~x64-macos"
  15 IUSE="+boost doc examples test"
  16
  17 REQUIRED_USE="test? ( boost )"
  18
  19 RESTRICT="!test? ( test )"
  20
  21 RDEPEND="boost? ( dev-libs/boost[context] )
  22         !<dev-libs/msgpack-5.0.0"
  23 DEPEND="${RDEPEND}"
  24 BDEPEND="doc? ( app-text/doxygen[dot] )
  25         test? ( sys-libs/zlib )"
  26
  27 src_configure() {
  28         local mycmakeargs=(
  29                 -DMSGPACK_BUILD_EXAMPLES=OFF
  30                 -DMSGPACK_CXX17=ON
  31                 -DMSGPACK_BUILD_TESTS="$(usex test)"
  32                 -DMSGPACK_USE_BOOST="$(usex boost)"
  33                 -DMSGPACK_USE_X3_PARSE="$(usex boost)"
  34         )
  35
  36         cmake_src_configure
  37 }
  38
  39 src_compile() {
  40         cmake_src_compile
  41
  42         if use doc; then
  43                 cmake_build doxygen
  44         fi
  45 }
  46
  47 src_install() {
  48         if use doc; then
  49                 local HTML_DOCS=( "${BUILD_DIR}"/doc_cpp/html/. )
  50         fi
  51
  52         if use examples; then
  53                 docinto examples
  54                 dodoc -r example/.
  55                 docompress -x /usr/share/doc/${PF}/examples
  56         fi
  57
  58         cmake_src_install
  59 }