dev-ruby/actiontext/actiontext-7.0.8.4.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5 USE_RUBY="ruby31 ruby32"
   6
   7 RUBY_FAKEGEM_RECIPE_DOC="none"
   8 RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
   9
  10 RUBY_FAKEGEM_GEMSPEC="actiontext.gemspec"
  11
  12 RUBY_FAKEGEM_BINWRAP=""
  13 RUBY_FAKEGEM_EXTRAINSTALL="app db package.json"
  14
  15 inherit ruby-fakegem
  16
  17 DESCRIPTION="Edit and display rich text in Rails applications"
  18 HOMEPAGE="https://github.com/rails/rails"
  19 SRC_URI="https://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"
  20
  21 LICENSE="MIT"
  22 SLOT="$(ver_cut 1-2)"
  23 KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
  24 IUSE="test"
  25
  26 RUBY_S="rails-${PV}/${PN}"
  27
  28 ruby_add_rdepend "
  29         ~dev-ruby/actionpack-${PV}
  30         ~dev-ruby/activerecord-${PV}
  31         ~dev-ruby/activestorage-${PV}
  32         ~dev-ruby/activesupport-${PV}
  33         >=dev-ruby/globalid-0.6.0
  34         >=dev-ruby/nokogiri-1.8.5
  35 "
  36
  37 ruby_add_bdepend "test? (
  38         dev-ruby/bundler
  39         dev-ruby/minitest:5.15
  40         dev-ruby/mocha
  41         dev-ruby/propshaft
  42         >=dev-ruby/sqlite3-1.4.0
  43 )"
  44
  45 all_ruby_prepare() {
  46         # Remove items from the common Gemfile that we don't need for this
  47         # test run. This also requires handling some gemspecs.
  48         sed -e "/\(system_timer\|sdoc\|w3c_validators\|pg\|execjs\|jquery-rails\|mysql2\|journey\|ruby-prof\|stackprof\|benchmark-ips\|kindlerb\|turbolinks\|coffee-rails\|sass-rails\|debugger\|sprockets-rails\|redcarpet\|bcrypt\|uglifier\|sprockets\|stackprof\|websocket-client-simple\|libxml-ruby\|redis\|blade\|aws-sdk\|google-cloud\|azure-storage\|selenium\|webpacker\|webrick\|webmock\|webdrivers\|minitest-bisect\|minitest-retry\|minitest-reporters\|listen\|rack-cache\|rack-test\|bootsnap\|capybara\|dalli\|connection_pool\|terser\|cookiejar\|cgi\)/ s:^:#:" \
  49                 -e '/stimulus-rails/,/tailwindcss-rails/ s:^:#:' \
  50                 -e '/:job/,/end/ s:^:#:' \
  51                 -e '/group :\(cable\|doc\|rubocop\|storage\|test\)/,/^end/ s:^:#:' \
  52                 -e '/sqlite/ s/1.6.4/99/' \
  53                 -i ../Gemfile || die
  54         rm ../Gemfile.lock || die
  55 }
  56
  57 each_ruby_prepare() {
  58         sed -i -e 's:ruby:'${RUBY}':' test/dummy/bin/* || die
  59 }