games-arcade/amphetamine/amphetamine-0.8.10-r3.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5 inherit desktop
   6
   7 DESCRIPTION="A cool Jump'n Run game offering some unique visual effects"
   8 HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
   9 SRC_URI="
  10         mirror://gentoo/${P}.tar.bz2
  11         mirror://debian/pool/main/a/amphetamine-data/amphetamine-data_0.8.7.orig.tar.gz
  12         https://dev.gentoo.org/~pacho/${PN}/${PN}.png
  13 "
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18
  19 RDEPEND="
  20         media-libs/libsdl[sound,video]
  21         x11-libs/libXpm
  22 "
  23 DEPEND="${RDEPEND}"
  24
  25 PATCHES=(
  26         "${FILESDIR}"/${P}-build.patch
  27         "${FILESDIR}"/${P}-64bit.patch
  28
  29         # From Debian:
  30         "${FILESDIR}"/${P}-no-lxt.patch
  31         "${FILESDIR}"/${P}-bugs.patch
  32         "${FILESDIR}"/${P}-missing-headers.patch
  33         "${FILESDIR}"/${P}-newline.patch
  34         "${FILESDIR}"/${P}-format-string.patch
  35
  36         # From OpenBSD:
  37         "${FILESDIR}"/${P}-SDL-conversions.patch
  38         "${FILESDIR}"/${P}-clang.patch
  39
  40         "${FILESDIR}"/${P}-drop-register-keyword.patch
  41 )
  42
  43 src_prepare() {
  44         default
  45         sed -i -e '55d' src/ObjInfo.cpp || die
  46 }
  47
  48 src_compile() {
  49         emake INSTALL_DIR=/usr/share/${PN}
  50 }
  51
  52 src_install() {
  53         newbin amph ${PN}
  54         insinto /usr/share/${PN}
  55         doins -r ../amph/*
  56         doicon "${DISTDIR}/${PN}.png"
  57         make_desktop_entry "${PN} -fs" Amphetamine ${PN}
  58         einstalldocs
  59 }