games-arcade/cdogs-sdl/cdogs-sdl-2.2.0.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit cmake flag-o-matic xdg
   7
   8 DESCRIPTION="Classic overhead run-and-gun game"
   9 HOMEPAGE="https://cxong.github.io/cdogs-sdl/"
  10 SRC_URI="
  11         https://github.com/cxong/cdogs-sdl/archive/refs/tags/${PV}.tar.gz
  12                 -> ${P}.tar.gz
  13 "
  14
  15 LICENSE="
  16         GPL-2+
  17         BSD-2 CC-BY-3.0 CC-BY-4.0 CC-BY-SA-3.0 CC0-1.0 WTFPL-2 XMAME public-domain
  18 "
  19 SLOT="0"
  20 KEYWORDS="~amd64 ~x86"
  21
  22 RDEPEND="
  23         media-libs/libsdl2[haptic,opengl]
  24         media-libs/sdl2-image[png]
  25         media-libs/sdl2-mixer[mp3,vorbis,wav]
  26         net-libs/enet:1.3=
  27 "
  28 DEPEND="${RDEPEND}"
  29
  30 PATCHES=(
  31         "${FILESDIR}"/${PN}-1.1.1-cmake.patch
  32 )
  33
  34 src_configure() {
  35         filter-lto #858527
  36
  37         local mycmakeargs=(
  38                 -DCDOGS_DATA_DIR="${EPREFIX}"/usr/share/${PN}/ # trailing / is needed
  39                 -DBUILD_EDITOR=OFF
  40                 -DUSE_SHARED_ENET=ON
  41         )
  42
  43         cmake_src_configure
  44 }
  45
  46 src_install() {
  47         cmake_src_install
  48
  49         dodoc doc/{AUTHORS,original_readme.txt}
  50
  51         # CREDITS is used at runtime, rest is licenses or duplicates
  52         find "${ED}"/usr/share/${PN}/doc -type f ! -name CREDITS -delete || die
  53 }