games-arcade/frozen-bubble/frozen-bubble-2.2.1_beta1-r2.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit desktop perl-module toolchain-funcs xdg
   7
   8 MY_P="${P/_/-}"
   9
  10 DESCRIPTION="A Puzzle Bubble clone written in perl (now with network support)"
  11 HOMEPAGE="http://www.frozen-bubble.org/"
  12 SRC_URI="http://www.frozen-bubble.org/data/${MY_P}.tar.bz2"
  13 S="${WORKDIR}/${MY_P}"
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18
  19 RDEPEND="
  20         dev-lang/perl
  21         dev-libs/glib:2
  22         >=dev-perl/Alien-SDL-1.413
  23         dev-perl/Compress-Bzip2
  24         dev-perl/File-ShareDir
  25         dev-perl/File-Slurp
  26         dev-perl/File-Which
  27         dev-perl/IPC-System-Simple
  28         >=dev-perl/SDL-2.511
  29         media-libs/sdl-image[gif,png]
  30         media-libs/sdl-mixer[vorbis]
  31         media-libs/sdl-pango
  32         media-libs/sdl-ttf
  33         virtual/libiconv
  34         virtual/perl-Getopt-Long
  35         virtual/perl-IO"
  36 DEPEND="${RDEPEND}"
  37 BDEPEND="
  38         dev-perl/Locale-Maketext-Lexicon
  39         dev-perl/Module-Build
  40         virtual/perl-ExtUtils-CBuilder
  41         virtual/perl-ExtUtils-ParseXS
  42         virtual/pkgconfig"
  43
  44 PATCHES=(
  45         "${FILESDIR}"/${P}-Werror.patch
  46         "${FILESDIR}"/${P}-fix-buffer-size.patch
  47         "${FILESDIR}"/${P}-perl-5.40.patch
  48 )
  49
  50 src_configure() {
  51         LD="$(tc-getCC)" perl-module_src_configure
  52 }
  53
  54 src_compile() {
  55         LD="$(tc-getCC)" perl-module_src_compile
  56 }
  57
  58 src_install() {
  59         mydoc="AUTHORS Changes HISTORY README" perl-module_src_install
  60         newdoc server/README README.server
  61         newdoc server/init/README README.server.init
  62
  63         local res
  64         for res in 16 32 48 64; do
  65                 newicon -s ${res} share/icons/frozen-bubble-icon-${res}x${res}.png ${PN}.png
  66         done
  67
  68         make_desktop_entry ${PN} Frozen-Bubble
  69 }