games-arcade/jazz2/jazz2-3.0.0-r1.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit cmake optfeature prefix xdg
   7
   8 DESCRIPTION="Open source reimplementation of Jazz Jackrabbit 2"
   9 HOMEPAGE="https://deat.tk/jazz2/"
  10 SRC_URI="https://github.com/deathkiller/jazz2-native/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
  11 S="${WORKDIR}/${PN}-native-${PV}"
  12
  13 LICENSE="GPL-3"
  14 SLOT="0"
  15 KEYWORDS="~amd64"
  16 IUSE="+openal sdl"
  17
  18 DEPEND="
  19         media-libs/libglvnd
  20         sys-libs/zlib:=
  21         openal? (
  22                 media-libs/libopenmpt
  23                 media-libs/openal
  24         )
  25         !sdl? ( media-libs/glfw )
  26         sdl? ( media-libs/libsdl2 )
  27 "
  28 RDEPEND="${DEPEND}"
  29
  30 PATCHES=(
  31         "${FILESDIR}"/${PN}-system-source.patch
  32 )
  33
  34 src_prepare() {
  35         cmake_src_prepare
  36         hprefixify Sources/Shared/Environment.cpp
  37
  38         # We need to install README.md to a different directory, default
  39         # src_install will handle that.
  40         sed -i '/README_INSTALL_DESTINATION/d' cmake/ncine_installation.cmake || die
  41 }
  42
  43 src_configure() {
  44         local mycmakeargs=(
  45                 -DNCINE_LINUX_PACKAGE="${PN}"
  46
  47                 -DNCINE_DOWNLOAD_DEPENDENCIES=OFF
  48                 -DNCINE_LINKTIME_OPTIMIZATION=OFF
  49                 -DNCINE_STRIP_BINARIES=OFF
  50                 -DNCINE_VERSION_FROM_GIT=OFF
  51                 -DNCINE_WITH_BACKWARD=OFF
  52
  53                 -DNCINE_WITH_GLEW=OFF
  54
  55                 -DNCINE_PREFERRED_BACKEND=$(usex sdl SDL2 GLFW)
  56
  57                 -DNCINE_WITH_AUDIO=$(usex openal)
  58         )
  59         cmake_src_configure
  60 }
  61
  62 pkg_postinst() {
  63         xdg_pkg_postinst
  64         optfeature "game data unless you want to install it manually" ${CATEGORY}/${PN}-data
  65 }