games-arcade/jumpnbump/jumpnbump-1.61_p20210421.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 PYTHON_COMPAT=( python3_{10..12} )
   7 inherit desktop python-single-r1 toolchain-funcs
   8
   9 MY_COMMIT="73c5fe86fd831dec45a22077e8d63dd2b6a6349e"
  10
  11 DESCRIPTION="Funny multiplayer game about cute little fluffy bunnies"
  12 HOMEPAGE="https://libregames.gitlab.io/jumpnbump"
  13 SRC_URI="https://gitlab.com/LibreGames/jumpnbump/-/archive/${MY_COMMIT}/${P}.tar.bz2"
  14 S=${WORKDIR}/${PN}-${MY_COMMIT}
  15
  16 LICENSE="GPL-2+"
  17 SLOT="0"
  18 KEYWORDS="~amd64 ~x86"
  19 IUSE="gui"
  20 REQUIRED_USE="gui? ( ${PYTHON_REQUIRED_USE} )"
  21
  22 DEPEND="
  23         app-arch/bzip2:=
  24         media-libs/libsdl2[joystick,sound,video]
  25         media-libs/sdl2-mixer[mod]
  26         media-libs/sdl2-net
  27         sys-libs/zlib:=
  28 "
  29 RDEPEND="
  30         ${DEPEND}
  31         gui? (
  32                 ${PYTHON_DEPS}
  33                 $(python_gen_cond_dep '
  34                         dev-python/pillow[${PYTHON_USEDEP}]
  35                         dev-python/pygobject[${PYTHON_USEDEP}]
  36                 ')
  37                 x11-libs/gdk-pixbuf:2[introspection]
  38                 x11-libs/gtk+:3[introspection]
  39         )"
  40 BDEPEND="gui? ( ${PYTHON_DEPS} )"
  41
  42 PATCHES=(
  43         "${FILESDIR}"/${PN}-1.61-ranlib.patch
  44 )
  45
  46 pkg_setup() {
  47         use gui && python-single-r1_pkg_setup
  48 }
  49
  50 src_compile() {
  51         tc-export AR CC RANLIB
  52
  53         emake PREFIX="${EPREFIX}"/usr
  54
  55         if use gui; then
  56                 emake PREFIX="${EPREFIX}"/usr jnbmenu
  57                 python_fix_shebang menu/jumpnbump_menu.py
  58         fi
  59 }
  60
  61 src_install() {
  62         emake PREFIX="${ED}"/usr install
  63
  64         use gui && emake -C menu PREFIX="${ED}"/usr install
  65
  66         doicon dist/${PN}.png
  67         rm -- "${ED}"/usr/share/icons/${PN}.png || die
  68
  69         einstalldocs
  70 }