games-strategy/lgeneral/lgeneral-1.4.4.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit readme.gentoo-r1 toolchain-funcs xdg
   7
   8 DESCRIPTION="Turn-based strategy game heavily inspired by the classic Panzer General"
   9 HOMEPAGE="https://lgames.sourceforge.io/LGeneral/"
  10 SRC_URI="
  11         https://downloads.sourceforge.net/lgeneral/${P}.tar.gz
  12         https://downloads.sourceforge.net/lgeneral/kukgen-data-1.1.tar.gz"
  13
  14 LICENSE="GPL-2+ CC-BY-SA-3.0"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86"
  17
  18 RDEPEND="
  19         media-libs/libsdl[sound,video]
  20         media-libs/sdl-mixer
  21         virtual/libintl"
  22 DEPEND="${RDEPEND}"
  23 BDEPEND="sys-devel/gettext"
  24
  25 PATCHES=(
  26         "${FILESDIR}"/${PN}-1.4.3-fix-utf8.patch
  27 )
  28
  29 src_compile() {
  30         emake AR="$(tc-getAR)"
  31 }
  32
  33 src_install() {
  34         default
  35
  36         keepdir /usr/share/${PN}/{ai_modules,music,terrain}
  37
  38         # Install the free kukgen WW1 campaign
  39         cd ../${PN}-data-* || die
  40
  41         dodoc docs/README.kukgen
  42         newdoc docs/MANUAL MANUAL.kukgen
  43
  44         insinto /usr/share/${PN}
  45         doins -r {campaigns,gfx,maps,nations,scenarios,sounds,units}
  46
  47         local DISABLE_AUTOFORMATTING=yes
  48         local DOC_CONTENTS=\
  49 "Only the free kukgen WWI campaign has been installed.
  50
  51 If you wish to play the Panzer General (PG) WWII campaign, you need
  52 to convert the original CD-ROM game data by (for example) running:
  53
  54         SDL_VIDEODRIVER=dummy \\
  55                 lgc-pg -s /path/to/cdrom/DAT -d ${EPREFIX}/usr/share/${PN}
  56
  57 See ${EPREFIX}/usr/share/doc/${PF}/README.lgc-pg* for details."
  58         readme.gentoo_create_doc
  59 }
  60
  61 pkg_postinst() {
  62         xdg_pkg_postinst
  63
  64         # README is redundant with what `make install` says but ensures visibility
  65         readme.gentoo_print_elog
  66 }