lxqt-base/lxqt-panel/lxqt-panel-2.0.1.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit cmake
   7
   8 DESCRIPTION="LXQt desktop panel and plugins"
   9 HOMEPAGE="https://lxqt-project.org/"
  10
  11 MY_PV="$(ver_cut 1-2)"
  12
  13 if [[ ${PV} == 9999 ]]; then
  14         inherit git-r3
  15         EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
  16 else
  17         SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
  18         KEYWORDS="amd64 arm64 ~ppc64 ~riscv ~x86"
  19 fi
  20
  21 LICENSE="LGPL-2.1 LGPL-2.1+"
  22 SLOT="0"
  23 IUSE="
  24         +alsa colorpicker cpuload +desktopswitch +directorymenu dom +kbindicator
  25         +mainmenu +mount networkmonitor pulseaudio +quicklaunch lm-sensors +showdesktop
  26         +spacer +statusnotifier sysstat +taskbar tray +volume +worldclock
  27 "
  28
  29 # Work around a missing header issue: https://bugs.gentoo.org/666278
  30 REQUIRED_USE="
  31         || ( desktopswitch mainmenu showdesktop taskbar )
  32         volume? ( || ( alsa pulseaudio ) )
  33 "
  34
  35 BDEPEND="
  36         >=dev-qt/qttools-6.6:6[linguist]
  37         >=dev-util/lxqt-build-tools-2.0.0
  38         virtual/pkgconfig
  39 "
  40 DEPEND="
  41         >=dev-libs/libqtxdg-4.0.0
  42         >=dev-qt/qtbase-6.6:6[dbus,gui,widgets,xml]
  43         >=dev-qt/qtsvg-6.6:6
  44         kde-frameworks/kwindowsystem:6[X]
  45         kde-plasma/layer-shell-qt:6
  46         >=lxde-base/menu-cache-1.1.0
  47         =lxqt-base/liblxqt-${MY_PV}*:=
  48         =lxqt-base/lxqt-globalkeys-${MY_PV}*
  49         =lxqt-base/lxqt-menu-data-${MY_PV}*
  50         x11-libs/libX11
  51         cpuload? ( sys-libs/libstatgrab )
  52         kbindicator? ( x11-libs/libxkbcommon )
  53         lm-sensors? ( sys-apps/lm-sensors:= )
  54         mount? ( kde-frameworks/solid:6 )
  55         networkmonitor? ( sys-libs/libstatgrab )
  56         statusnotifier? (
  57                 dev-libs/libdbusmenu-lxqt
  58                 >=dev-qt/qtbase-6.6:6[concurrent]
  59         )
  60         sysstat? ( >=lxqt-base/libsysstat-1.0.0 )
  61         tray? (
  62                 x11-libs/libxcb:=
  63                 x11-libs/libXcomposite
  64                 x11-libs/libXdamage
  65                 x11-libs/libXrender
  66                 x11-libs/libXtst
  67                 x11-libs/xcb-util
  68                 x11-libs/xcb-util-image
  69         )
  70         volume? (
  71                 alsa? ( media-libs/alsa-lib )
  72                 pulseaudio? (
  73                         media-libs/libpulse
  74                         media-sound/pavucontrol-qt
  75                 )
  76         )
  77 "
  78 RDEPEND="${DEPEND}"
  79
  80 src_configure() {
  81         local mycmakeargs=(
  82                 # Plugins
  83                 -DCOLORPICKER_PLUGIN=$(usex colorpicker)
  84                 -DCPULOAD_PLUGIN=$(usex cpuload)
  85                 -DDESKTOPSWITCH_PLUGIN=$(usex desktopswitch)
  86                 -DDIRECTORYMENU_PLUGIN=$(usex directorymenu)
  87                 -DDOM_PLUGIN=$(usex dom)
  88                 -DKBINDICATOR_PLUGIN=$(usex kbindicator)
  89                 -DMAINMENU_PLUGIN=$(usex mainmenu)
  90                 -DMOUNT_PLUGIN=$(usex mount)
  91                 -DNETWORKMONITOR_PLUGIN=$(usex networkmonitor)
  92                 -DQUICKLAUNCH_PLUGIN=$(usex quicklaunch)
  93                 -DSENSORS_PLUGIN=$(usex lm-sensors)
  94                 -DSHOWDESKTOP_PLUGIN=$(usex showdesktop)
  95                 -DSPACER_PLUGIN=$(usex spacer)
  96                 -DSTATUSNOTIFIER_PLUGIN=$(usex statusnotifier)
  97                 -DSYSSTAT_PLUGIN=$(usex sysstat)
  98                 -DTASKBAR_PLUGIN=$(usex taskbar)
  99                 -DTRAY_PLUGIN=$(usex tray)
 100                 -DVOLUME_PLUGIN=$(usex volume)
 101                 -DWORLDCLOCK_PLUGIN=$(usex worldclock)
 102         )
 103
 104         if use volume; then
 105                 mycmakeargs+=(
 106                         -DVOLUME_USE_ALSA=$(usex alsa)
 107                         -DVOLUME_USE_PULSEAUDIO=$(usex pulseaudio)
 108                 )
 109         fi
 110
 111         cmake_src_configure
 112 }
 113
 114 src_install() {
 115         cmake_src_install
 116         doman panel/man/*.1
 117 }