net-print/cnijfilter2/cnijfilter2-6.70.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit autotools
   7
   8 MY_P="${PN}-source-${PV}-1"
   9
  10 DESCRIPTION="IJ Printer Driver"
  11 HOMEPAGE="https://www.usa.canon.com/support/p/pixma-g4270#idReference%3Dsoftware-drivers"
  12 SRC_URI="https://gdlp01.c-wss.com/gds/7/0100012137/01/${PN}-source-${PV}-1.tar.gz"
  13
  14 S="${WORKDIR}"/${MY_P}
  15
  16 LICENSE="Canon-IJ"
  17 SLOT="0"
  18 KEYWORDS="~amd64 ~x86"
  19
  20 DEPEND="virtual/libusb:1
  21         dev-libs/libxml2
  22         net-print/cups"
  23 RDEPEND="${DEPEND}"
  24
  25 PATCHES=(
  26         "${FILESDIR}"/${PN}-6.50-gentoo.patch
  27         "${FILESDIR}"/${PN}-5.80-cflags.patch
  28         "${FILESDIR}"/${PN}-5.80-fno-common.patch
  29         "${FILESDIR}"/${PN}-6.60-c99.patch
  30         "${FILESDIR}"/${P}-c23.patch
  31 )
  32
  33 pkg_setup()  {
  34         QA_PREBUILT="
  35                 /usr/$(get_libdir)/libcnbpnet30.so.1.0.0
  36                 /usr/$(get_libdir)/libcnbpcnclapicom2.so.5.0.0
  37                 /usr/$(get_libdir)/libcnnet2.so.1.2.5
  38                 /usr/$(get_libdir)/libcnbpnet20.so.1.0.0
  39                 /usr/bin/cnijlgmon3
  40         "
  41 }
  42
  43 src_prepare() {
  44         default
  45         DIRS="cmdtocanonij2 cmdtocanonij3 cnijbe2 lgmon3 rastertocanonij tocanonij tocnpwg"
  46         LIBDIR=com/libs_bin$(usex amd64 _x86_64 _i686)
  47         for d in ${DIRS}; do
  48                 mv "${d}"/configure.{in,ac} || die
  49         done
  50         echo "AC_INIT([${PN}], [${PV}])" >> configure.ac
  51         echo "AM_INIT_AUTOMAKE" >> configure.ac
  52         echo "AC_CONFIG_SUBDIRS([${DIRS}])" >> configure.ac
  53         echo "AC_CONFIG_FILES([Makefile])" >> configure.ac
  54         echo "AC_OUTPUT()" >> configure.ac
  55         echo "SUBDIRS= ${DIRS}" >> Makefile.am
  56         sed -i \
  57                 -e "/^CFLAGS/d" \
  58                 */configure.ac \
  59                 cnijbe2/src/Makefile.am || die
  60         eautoreconf
  61         cd ${LIBDIR}
  62         rm libcn*.so || die
  63         ln -sf libcnbpcnclapicom2.so.5.0.0 libcnbpcnclapicom2.so || die
  64         ln -sf libcnbpnet20.so.1.0.0 libcnbpnet20.so || die
  65         ln -sf libcnbpnet30.so.1.0.0 libcnbpnet30.so || die
  66         ln -sf libcnnet2.so.1.2.5 libcnnet2.so || die
  67
  68         cd -
  69 }
  70
  71 src_configure() {
  72         econf --enable-progpath="${EPREFIX}/usr/bin" LDFLAGS="-L${S}/${LIBDIR} ${LDFLAGS}"
  73 }
  74
  75 src_install() {
  76         default
  77         insinto /usr/share/ppd/cupsfilters
  78         doins ppd/*ppd
  79         dolib.so ${LIBDIR}/*
  80 }