net-print/epson-inkjet-printer-escpr/epson-inkjet-printer-escpr-1.8.6.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit autotools edos2unix
   7
   8 DESCRIPTION="Epson Inkjet Printer Driver (ESC/P-R)"
   9 HOMEPAGE="https://download.ebz.epson.net/dsc/search/01/search/?OSC=LX"
  10
  11 # https://support.epson.net/linux/Printer/LSB_distribution_pages/en/escpr.php
  12 # Use the "source package for arm CPU" to get a tarball instead of an srpm.
  13 SRC_URI="https://download3.ebz.epson.net/dsc/f/03/00/16/21/81/74d098a47c3a616713079c9cd5904b468bb33dea/${P}-1.tar.gz"
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS="amd64 ppc64"
  18
  19 DEPEND="net-print/cups"
  20 RDEPEND="${DEPEND}"
  21
  22 PATCHES=(
  23         "${FILESDIR}/${PV}-warnings.patch"
  24         "${FILESDIR}/${PN}-1.7.7-fnocommon.patch"
  25         "${FILESDIR}/${PN}-1.8-missing-include.patch"
  26 )
  27
  28 src_prepare() {
  29         local f
  30         for f in $(find ./ -type f || die); do
  31                 edos2unix "${f}"
  32         done
  33
  34         eautoreconf
  35         default
  36 }
  37
  38 src_configure() {
  39         econf --disable-shared
  40
  41         # Makefile calls ls to generate a file list which is included in Makefile.am
  42         # Set the collation to C to avoid automake being called automatically
  43         unset LC_ALL
  44         export LC_COLLATE=C
  45 }
  46
  47 src_install() {
  48         emake -C ppd DESTDIR="${D}" install
  49         emake -C src DESTDIR="${D}" install
  50         einstalldocs
  51 }